一次在文件系统上执行多个操作的正确方法是什么？

假设我想知道一个文件是否存在，如果它是一个目录，则另外检索它的内容。我可能会这样走：

browseSimple :: FilePath -> IO (Either FilePath [FilePath])
browseSimple x = do
    isAvailable <- doesPathExist x
    if not isAvailable then error $ "File not found: " ++ x else do
        isFile <- doesFileExist x
        if isFile then return $ Left x else do
            isDirectory <- doesDirectoryExist x
            if not isDirectory then error $ "Unknown filesystem node: " ++ x else do
                listing <- listDirectory x
                return $ Right ((x </>) <$> listing)
-- ^
-- λ browseSimple  "."
-- Right [..."./Filesystem.hs"...]

——而且还挺管用的。但我想知道：如果节点一路上断开链接，比如在最后一个“do”块之前，会发生什么？

我不知道 C，但我的猜测是所有这些不确定性都将被 1（一）个 POSIX 系统调用所取代：opendir要么让我读取目录内容，要么返回一个我可以进行模式匹配的有意义的错误。不过，这只适用于 POSIX 兼容的系统。

在 Haskell 中做这样的事情的正确、惯用、专业的方法是什么？我可以用来自的东西来解决这个问题吗？System.Posix.Files？这方面的最新技术是什么？

后记

我本可以直接投射listDirectory，并且模式匹配了错误（根据@Ryan的建议），但我有点怀疑，因为它显然可以说NoSuchThing如果两者都有ENOENT and ENOTDIR。描述很少，行为没有详细说明，我不想在其中读到任何保证。

但我想知道：如果节点一路上断开链接，比如在最后一个“do”块之前，会发生什么？

你会得到一个例外，在这种情况下这没什么大不了的。您正在执行 IO 并且可以处理它。我认为您不会找到一个万无一失的平台无关解决方案。

您制作一个有用的包装器 monad 来保持代码可读怎么样？它可能比您喜欢的更多样板（在这种情况下，只需将整个函数调用包装起来catch）但对于较大部分的代码可能会非常好：

data MyErr = CaughtException SomeException
                             -- ^ You might want to just catch
                             --   specific types of exceptions here
          | MyErr String

type M = ExceptT MyErr IO

myErr :: String -> M a
myErr = throwE . MyErr

myIO :: IO a -> M a
myIO io = ExceptT (catch (Right <$> io) (pure . Left . CaughtException))

The Mmonad 允许您捕获所有丑陋的异常以及您的程序逻辑并将其捆绑到一个单一的Either结果。你可以这样使用它：

browseSimple :: FilePath -> IO (Either MyErr [FilePath])
browseSimple x = runExceptT $ do
    isAvailable <- myIO $ doesPathExist x
    when (not isAvailable) (myErr $ "File not found: " ++ x)
    isFile <- myIO $ doesFileExist x
    when isFile (myErr x)
    isDirectory <- myIO $ doesDirectoryExist x
    when (not isDirectory) (myErr $ "Unknown filesystem node: " ++ x)
    listing <- myIO $ listDirectory x
    return ((x </>) <$> listing)

你可以增强一些东西，比如提供myIO有了更多的信息，所以如果/当事情失败时，你可以将结果与你的操作中事情急剧下降的地方联系起来，但这通常是矫枉过正的。

我们可以使用whenM进一步清理事情（类型未测试）：

whenM io m = myIO io >>= \b -> when b m

browseSimple2 :: FilePath -> IO (Either MyErr [FilePath])
browseSimple2 x = runExceptT $ do
    whenM (not <$> doesPathExist x)
          (myErr $ "File not found: " ++ x)
    whenM (doesFileExist x)
          (myErr x)
    whenM (not <$> doesDirectoryExist x)
          (myErr $ "Unknown filesystem node: " ++ x)
    myIO $ (x </>) <$> listDirectory x