将 SAS 数据集中的观测值读入数组

这个问题与大型机上的 SAS 相关，尽管我相信在这种情况下没有什么区别。

我有以下 SAS 数据集：

Obs     DATO    T_ALLOC    T_FRESP

 1     19328      647        1804 
 2     19359      654        1797 
 3     19390      662        1789 
 4     19418      676        1774 
 5     19449      636        1815 
 6     19479      698        1753 

我的目标是将 3 个变量的所有 6 个观察值（我希望在这里使用正确的术语）放入单独的数组中。

我已经付出了很大的努力来阅读有关使用数组的信息，但由于某种原因，这个特定问题的解决方案一直困扰着我。

如果有人愿意提供帮助，我们将不胜感激。即使包含我正在寻找的答案的文档链接也会非常有帮助。

如果我的解释不清楚，请告诉我，我将提供任何必要的其他信息。

提前致谢。

编辑->

我的最终 CSV 应类似于以下内容：

Datoer,01/2013,02/2013,03/2013,04/2013,05/2013,06/2013,07/2013,08/2013,09/2013,10/2013
Freespace,800,1000,1243,1387,1457,1562,1620,1700,1800,1900
Allokeret,1000,1200,1456,1689,1784,1865,1930,2000,2100,2200

如果我正确理解您的需求，您可以借助 proc transpose 获得您想要的结果。

proc transpose data = datain out = dataout;
    var DATO T_ALLOC T_FRESP;
run;

proc export data=dataout
    outfile='xxxxx\tmp.csv'
    dbms=csv
    replace;
run;

这只是 SQL 的另一个想法。

proc sql noprint;
    select DATO into :dato separated by ',' from datain;
    select T_ALLOC into :talloc separated by ',' from datain;
    select T_FRESP into :tfresp separated by ',' from datain;
quit;

data _NULL_;
    file 'xxxxx\tmp.csv';
    put "var1,&dato";
    put "var2,&talloc";
    put "var3,&tfresp";
run;

另一种是数组。

data _NULL_;
    set datain nobs = nobs;
    array data DATO T_ALLOC T_FRESP;
    format t1-t3 $50.;
    retain t1-t3;
    array t[3] $;
    do i = 1 to dim(t);
        if _N_ = 1 then t[i] = put(data[i], 8.);
            else t[i] = compress(t[i] || ',' || put(data[i], 8.));
    end;
    if _N_ = nobs;
    file 'xxxxx\tmp.csv';
    put "var1," t1;
    put "var2," t2;
    put "var3," t3;
run;