将 copts/defines 传播到目标的所有依赖项

我有一个项目，在一个相当复杂的构建系统中的单个工作空间中涉及多个构建文件。简而言之，我的目标：对于某些特定目标，我希望使用一组额外的属性来构建其所有递归依赖项（copts/defines）与以任​​何其他方式构建这些依赖项目标时相比。我还没有找到一种方法来干净地做到这一点。

例如，目标 G 通常是用copts = []。如果目标 P 取决于目标 G，并且我运行bazel build :P，我希望两个目标都用copts = ["-DMY_DEFINE"]，以及目标 G 的所有依赖项等。

The cc_binary.defines https://docs.bazel.build/versions/master/be/c-cpp.html#cc_binary.defines论证在opposite方向：依赖于某个目标 A 的所有目标都将接收目标 A 的所有目标defines.

限制：

• 更喜欢避免自定义命令行标志，我不控制人们如何调用bazel {build,test}
• 复制整个依赖目标树是不切实际的

似乎无法设置 a 的值config_setting从 BUILD 文件或目标中，所以看起来select基于的解决方案无法工作。

之前的工作：

• https://groups.google.com/g/bazel-discuss/c/rZps4nqYqt8/m/YS_pZD6oAQAJ https://groups.google.com/g/bazel-discuss/c/rZps4nqYqt8/m/YS_pZD6oAQAJ- 2017，推荐“并行树”或自定义宏（我们已经有很多，将它们包装在另一个中将具有挑战性）
• 将 copt 传播到 Bazel 中的所有依赖项 https://stackoverflow.com/questions/64186487/propagate-copts-to-all-dependencies-in-bazel- 我相信这些都依赖于自定义命令行标志

创建一个用户定义的构建设置 https://docs.bazel.build/versions/master/skylark/config.html#user-defined-build-settings不需要命令行标志。如果你设置flag = False，那么实际上无法在命令行上设置。您可以使用用户定义的转换 https://docs.bazel.build/versions/master/skylark/config.html#user-defined-transitions来设置它。

我认为这样的东西可以满足您的需求（将其保存在extra_copts.bzl):

def _extra_copts_impl(ctx):
    context = cc_common.create_compilation_context(
        defines = depset(ctx.build_setting_value)
    )
    return [CcInfo(compilation_context = context)]

extra_copts = rule(
    implementation = _extra_copts_impl,
    build_setting = config.string_list(flag = False),
)

def _use_extra_copts_implementation(ctx):
    return [ctx.attr._copts[CcInfo]]

use_extra_copts = rule(
    implementation = _use_extra_copts_implementation,
    attrs = "_copts": attr.label(default = "//:extra_copts")},
)

def _add_copts_impl(settings, attr):
    return {"//:extra_copts": ["MY_DEFINE"]}

_add_copts = transition(
    implementation = _add_copts_impl,
    inputs = [],
    outputs = ["//:extra_copts"],
)

def _with_extra_copts_implementation(ctx):
    infos = [d[CcInfo] for d in ctx.attr.deps]
    return [cc_common.merge_cc_infos(cc_infos = infos)]

with_extra_copts = rule(
    implementation = _with_extra_copts_implementation,
    attrs = {
        "deps": attr.label_list(cfg = _add_copts),
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist"
        )
    },
)

然后在BUILD file:

load("//:extra_copts.bzl", "extra_copts", "use_extra_copts", "with_extra_copts")

extra_copts(name = "extra_copts", build_setting_default = [])

use_extra_copts(name = "use_extra_copts")

cc_library(
    name = "G",
    deps = [":use_extra_copts"],
)

with_extra_copts(
    name = "P_deps",
    deps = [":G"],
)

cc_library(
    name = "P",
    deps = [":P_deps"],
)

extra_copts是构建设置。它返回一个CcInfo https://docs.bazel.build/versions/master/skylark/lib/CcInfo.html直接，这意味着使用相同的方法可以直接进行任何其他 C++ 库交换。它的默认值实际上是“空”CcInfo这不会对依赖它的库做任何事情。

with_extra_copts包装一组依赖项，配置为使用不同的CcInfo。这是实际更改值的规则，以创建具有不同标志的 G 的第二个版本。

_add_copts是一个过渡with_extra_copts用于改变的值extra_copts构建设置。它可以检查attr做一些比添加硬编码列表更复杂的事情。

use_extra_copts拉动CcInfo out of extra_copts so a cc_library可以使用它们。

为了避免重写内置的 C++ 规则，它使用包装器规则来拉出 copt 并进行转换。您可能想要创建宏来将包装器规则与相应的 cc_library 捆绑在一起。或者，您可以使用rules_cc 的 my_c_archive https://github.com/bazelbuild/rules_cc/blob/master/examples/my_c_archive/my_c_archive.bzl作为创建自定义规则的起点，这些规则重用内置 C++ 规则的核心实现，同时将构建设置的转换和使用集成到单个规则中。