是否可以从另一个 Promise 终止一个 Promise 的代码块？

我写了这个测试程序：

await Promise.anyof(
  Promise.allof((^5).map: {start { sleep 10; say "done $_" } }),
  Promise.in(5).then: { say 'ouch' }
);
sleep 10;

当第二个 Promise 超时时，它会打印“ouch”并且等待退出，但第一个 Promise 的代码块仍在运行。再过五秒，它的五个进程结束并打印“完成”：

$ ./test1.p6
ouch
done 0
done 1
done 2
done 3
done 4

我试图终止第一个承诺，将其分配给一个变量，然后调用.break第二个承诺中的方法，但它不起作用。

有没有办法杀死第一个承诺和它开始的其他五个子承诺？

您必须以某种方式告诉该过程它不必完成。

my $cancel = Cancellation.new;

await Promise.anyof(
  Promise.allof(
    (^5).map: {
      last if $cancel.cancelled;

      start {
        sleep 10;
        say "done $_" unless $cancel.cancelled
      }
    }
  ),
  Promise.in(5).then: {
    $cancel.cancel;
    say 'ouch'
  }
);

如果你想要类似的东西Promise.in()可以取消，让我们开始查看现有代码 https://github.com/rakudo/rakudo/blob/74687ae5cf13bad24eac515500dc670b143d602a/src/core/Promise.pm6#L252-L257.

method in(Promise:U: $seconds, :$scheduler = $*SCHEDULER) {
    my $p   := self.new(:$scheduler);
    my $vow := $p.vow;
    $scheduler.cue({ $vow.keep(True) }, :in($seconds));
    $p
}

请注意，结果为$scheduler.cue是取消。

为了简单起见，我只是将 Promise 和 Cancellation 包装在一个类中。
（我不想重新实现每个方法）。

class Cancellable-Timer {
    has Promise      $.Promise;
    has              $!vow;
    has Cancellation $!cancel;

    method !SET-SELF ( $!promise, $!vow, $!cancel ){
        self
    }

    method in (::?CLASS:U: $seconds, :$scheduler = $*SCHEDULER) {
        my $p   := Promise.new(:$scheduler);
        my $vow := $p.vow;
        my $cancel = $scheduler.cue({ $vow.keep(True) }, :in($seconds));
        self.bless!SET-SELF($p,$vow,$cancel);
    }

    method cancel ( --> Nil ) {
        # potential concurrency problem
        if $!Promise.status == Planned {
            $!cancel.cancel;          # cancel the timer
            $!vow.break("cancelled"); # break the Promise
        }
    }

    method cancelled () {
        # Ignore any concurrency problems by using the Promise
        # as the sole source of truth.
        $!Promise.status ~~ PromiseStatus::Broken
    }
}

my $timer = Cancellable-Timer.in(1);
my $say = $timer.Promise.then: *.say;
Promise.in(0.1).then: {$timer.cancel};
await $say;

请注意，上面的课程只是一个粗略的初稿。