更改 XML 标签名称

我想转换一个我已经解析过的 XML 文档XmlSlurper。 （相同的）XML 标记名称应替换为id属性;所有其他属性都应该被删除。从这段代码开始：

def xml = """<tag id="root">
            |  <tag id="foo" other="blah" more="meh">
            |    <tag id="bar" other="huh"/>
            |  </tag>
            |</tag>""".stripMargin()

def root = new XmlSlurper().parseText(xml)

// Some magic here.

println groovy.xml.XmlUtil.serialize(root)

我想得到以下内容：

<root>
  <foo>
    <bar/>
  </foo>
</root>

（我在 XML 上编写测试断言，并希望简化它们的结构。）我已阅读使用 XmlSlurper 更新 XML http://groovy.codehaus.org/Updating+XML+with+XmlSlurper并四处搜寻，但找不到办法replaceNode() or replaceBody()交换节点同时保留其子节点。

将“魔法”添加到问题中的代码中给出：

def xml = """<tag id="root">
            |  <tag id="foo" other="blah" more="meh">
            |    <tag id="bar" other="huh"/>
            |  </tag>
            |</tag>""".stripMargin()

def root = new XmlSlurper().parseText(xml)

root.breadthFirst().each { n ->
  n.replaceNode { 
    "${n.@id}"( n.children() )
  }
}

println groovy.xml.XmlUtil.serialize(root)

哪个打印：

<?xml version="1.0" encoding="UTF-8"?><root>
  <foo>
    <bar/>
  </foo>
</root>

但是，这将删除节点中的所有内容。为了维护内容，我们可能需要使用递归和 XmlParser 从现有文档生成新文档......我会考虑一下

更通用的解决方案

我认为这更普遍：

import groovy.xml.*

def xml = """<tag id="root">
            |  <tag id="foo" other="blah" more="meh">
            |    <tag id="bar" other="huh">
            |      something
            |    </tag>
            |    <tag id="bar" other="huh">
            |      something else
            |    </tag>
            |    <noid>woo</noid>
            |  </tag>
            |</tag>""".stripMargin()

def root = new XmlParser().parseText( xml )

def munge( builder, node ) {
  if( node instanceof Node && node.children() ) {
    builder."${node.@id ?: node.name()}" {
      node.children().each {
        munge( builder, it )
      }
    }
  }
  else {
    if( node instanceof Node ) {
      "${node.@id ?: node.name()}"()
    }
    else {
      builder.mkp.yield node
    }
  }
}

def w = new StringWriter()
def builder = new MarkupBuilder( w )
munge( builder, root )

println XmlUtil.serialize( w.toString() )

并打印：

<?xml version="1.0" encoding="UTF-8"?><root>
  <foo>
    <bar>something</bar>
    <bar>something else</bar>
    <noid>woo</noid>
  </foo>
</root>

现在穿过没有（或空）的节点id属性