Elixir：修改模块属性值

是否有可能实现以下行为，其中尝试更改模块属性的值以改变模块方法的行为？

defmodule Adder do
  @num_to_add 10
  def addTo(input), do: input + @num_to_add
end

IO.inspect Adder.addTo(5)  # Prints 15

Adder.num_to_add = 20

IO.inspect Adder.addTo(5)  # Expect it to print 25

它抛出以下错误

** (CompileError) hello.exs:8: cannot invoke remote function Adder.num_to_add/0 inside match
    (elixir) src/elixir_clauses.erl:26: :elixir_clauses.match/3

如果这是不可能的（因为 Elixir 中的所有内容都应该是不可变的），是否有任何 Elixir 方法可以实现类似的行为。

这是不可能的，因为属性仅存在于该特定模块的编译之前。编译模块时，所有属性都会被内联并被遗忘，因此当您能够从该模块调用函数时，就不再可能修改属性。

这段代码应该更清楚地显示这一点：

defmodule Test do
  @attr 1
  @attr 2

  def attr do
    @attr
  end
end

IO.inspect Test.attr # => 2
Module.put_attribute(Test, :attr, 3)
IO.inspect Test.attr # => ** (ArgumentError) could not call put_attribute on module Test because it was already compiled

请注意，您可以在模块尚未编译时（例如在模块主体中）更改属性的值，只需再次设置它，就像我在设置时所做的那样@attr to 2.

顺便说一句，您似乎想要实现的目标可以通过Agent:

defmodule Storage do
  def start_link do
    Agent.start_link(fn -> 10 end, name: __MODULE__)
  end

  def add_to(input) do
    Agent.get_and_update(__MODULE__, fn (x) -> {x + input, x + input} end)
  end
end

Storage.start_link
IO.inspect Storage.add_to(5) # => 15
IO.inspect Storage.add_to(5) # => 20

Elixir 中的一个好的经验法则是，每当您需要跟踪某些可变状态时，您都需要有一个进程来包装该状态。