XSLT定义一个变量并检查它是否存在

我正在尝试转换 XML 文档。首先，我定义一个全局变量：

 <xsl:variable name="foo"><xsl:value-of select="bar"/></xsl:variable>

现在我正在转换的 XML 有可能<bar>some data</bar>定义的。也有可能它没有被定义。

一旦我声明了下面的全局变量，我将尝试输出以下内容（如果已定义）：

<foo>DEFINED</foo>

如果没有定义：

<foo>NOT DEFINED</foo>

我在用<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

解决这个问题的最佳方法是什么？

由于您使用的是 XSLT 1.0，因此您可以使用string()进行测试。

这是一个样式表示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar"/>
        <results>
            <xsl:choose>
                <xsl:when test="string($foo)">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

请注意，空白区域已折叠，因此<bar> </bar>将返回 false。还，string()当直接测试元素而不是变量时将起作用。

以下是一些输入/输出示例：

Input

<test>
    <bar/>
</test>

or

<test>
    <bar></bar>
</test>

or

<test>
    <bar>    </bar>
</test>

Output

<foo>NOT DEFINED</foo>

Input

<test>
    <bar>x</bar>
</test>

Output

<foo>DEFINED</foo>

如果您可以使用 XSLT 2.0，则可以将变量声明为xs:string并在测试中使用变量名称（test="$foo").

Example:

<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar" as="xs:string"/>
        <results>
            <xsl:choose>
                <xsl:when test="$foo">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>