Perl 中的“字符串化”是什么？

在 CPAN 模块的文档中DateTime http://search.cpan.org/~drolsky/DateTime-0.66/lib/DateTime.pm#Formatters_And_Stringification我发现了以下内容：

设置格式化程序后， 重载的字符串化方法将 使用格式化程序。

似乎有一些名为“字符串化”的 Perl 概念我不知何故错过了。谷歌搜索并没有澄清太多。这个“串化”是什么？

每当 Perl 需要将值转换为字符串时，就会发生“字符串化”。这可能是打印它、将它与另一个字符串连接、对其应用正则表达式，或者使用 Perl 中的任何其他字符串操作函数。

say $obj;
say "object is: $obj";
if ($obj =~ /xyz/) {...}
say join ', ' => $obj, $obj2, $obj3;
if (length $obj > 10) {...}
$hash{$obj}++;
...

通常，对象会字符串化为类似的东西Some::Package=HASH(0x467fbc)其中 perl 正在打印它所在的包，以及引用的类型和地址。

某些模块选择覆盖此行为。在 Perl 中，这是通过overload http://perldoc.perl.org/overload.html杂注。下面是一个对象的示例，当字符串化时会产生其总和：

{package Sum;
    use List::Util ();

    sub new {my $class = shift; bless [@_] => $class}

    use overload fallback => 1,
        '""' => sub {List::Util::sum @{$_[0]}}; 

    sub add {push @{$_[0]}, @_[1 .. $#_]}
}

my $sum = Sum->new(1 .. 10);

say ref $sum; # prints 'Sum'
say $sum;     # prints '55'
$sum->add(100, 1000);
say $sum;     # prints '1155'

还有其他几个证明overload让您定义：

'bool' Boolification    The value in boolean context   `if ($obj) {...}`
'""'   Stringification  The value in string context    `say $obj; length $obj`
'0+'   Numification     The value in numeric context   `say $obj + 1;`
'qr'   Regexification   The value when used as a regex `if ($str =~ /$obj/)`

对象甚至可以表现为不同的类型：

'${}'   Scalarification   The value as a scalar ref `say $$obj`
'@{}'   Arrayification    The value as an array ref `say for @$obj;`
'%{}'   Hashification     The value as a hash ref   `say for keys %$obj;`
'&{}'   Codeification     The value as a code ref   `say $obj->(1, 2, 3);`
'*{}'   Globification     The value as a glob ref   `say *$obj;`