XSLT 和 xpath v1.0 查找重复项并聚合

我想知道是否有一种方法可以在 xml 中搜索重复项，然后在找到时将所有重复项聚合到一个节点。埃克斯

<car name="one">
 <person>john</person>
 <person>Jay</person>
</car>
<car name="two">
 <person>kim</person>
 <person>chris</person>
</car>
<car name="one">
 <person>jane</person>
 <person>liz</person>
</car>

应该：

<car name="one">
 <person>john</person>
 <person>Jay</person>
 <person>jane</person>
 <person>liz</person>
</car>
<car name="two">
 <person>kim</person>
 <person>chris</person>
</car>

非常感谢所有帮助！

Br Kim

在 XSLT 1.0 中，您必须使用称为慕尼黑方法 http://www.jenitennison.com/xslt/grouping/muenchian.html这是使用以下方法对元素进行分组的过程key and generate-id功能。

这个过程是这样的：

您首先定义一个键来表示要分组的数据。

<xsl:key name="car-by-name" match="car" use="@name"/>

然后，您可以通过基于该密钥生成 id 来在模板匹配中使用该密钥。

<xsl:apply-templates select="car[generate-id() = generate-id(key('car-by-name', @name)[1])]" mode="group"/>

现在您已经对节点进行了分组，您所要做的就是再次使用该键来获取该键中的所有节点。

<xsl:apply-templates select="key('car-by-name', @name)"/>

现在，当您获取此 XML（添加document使其格式良好）。

<document>
  <car name="one">
    <person>john</person>
    <person>Jay</person>
  </car>
  <car name="two">
    <person>kim</person>
    <person>chris</person>
  </car>
  <car name="one">
    <person>jane</person>
    <person>liz</person>
  </car>
</document>

并应用这个 XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" />
  <xsl:key name="car-by-name" match="car" use="@name"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="document">
    <xsl:copy>
      <xsl:apply-templates select="car[generate-id() = generate-id(key('car-by-name', @name)[1])]" mode="group"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="car" mode="group">
    <car name="{@name}">
      <xsl:apply-templates select="key('car-by-name', @name)"/>
    </car>
  </xsl:template>

  <xsl:template match="car">
    <xsl:apply-templates select="@*|node()"/>
  </xsl:template>

</xsl:stylesheet>

它产生这个结果。

<?xml version="1.0" encoding="UTF-8"?>
<document>
  <car name="one">
    <person>john</person>
    <person>Jay</person>

    <person>jane</person>
    <person>liz</person>
  </car>
  <car name="two">
    <person>kim</person>
    <person>chris</person>
  </car>
</document>