检测 Skype 是否处于“紧凑视图”或“默认视图”

我的应用程序的运行方式由 Skype 的视图模式决定，因为我的应用程序正在寻找类窗口TConversationWindow，如果在默认视图中，它是tSkMainForm，如果在紧凑视图中，它不是tSkMainForm.

这是我尝试做的：

Function IsCompactView:Boolean;
Var
 Wnd : Hwnd;
Begin
  Result := True;
  Wnd := FindWindow('TConversationForm',nil);

  if Wnd <> 0 then
  begin
   Wnd := GetParent(Wnd);
   // Custom function that grabs the Window Text
   if GetHandleText(Wnd) <> '' then
   Result := False;

  end;

End;

上面的函数将寻找顶级（除非我弄错了 - 没有窗口父窗口的窗口）TConversationForm的，通过检查他们的父母是否有文本。如果 Skype 处于默认视图，TConversationForm的孩子是tSkMainForm，其中总是有一些文本。它按预期工作。

现在解决实际问题：每当用户在两个视图之间切换时，顶层TConversationForm的没有“刷新”。它们消失得很好，但为了让它作为一个孩子出现tSkMainForm再次（因此更改可见于温斯派克特间谍），你必须在 Skype 中选择它，我不能依赖用户来这样做。

如果您不知道，这是两种视图之间的区别：

紧凑视图

默认视图

如果您需要更多信息，请告诉我，谢谢！

不要使用 Windows 方法检测 Skype 是否处于“紧凑视图”或“默认视图”，而是尝试阅读配置文件文件存储这些类型的设置并由 Skype“实时”更新。该文件位于

%AppData%\Skype\<your-skype-user-name>

例如在 Windows 7 中，这是位置

C:\Users\<your windows user>\AppData\Roaming\Skype\<your-skype-user-name>

该文件内部存在一个名为MultiWindowMode

这是 Xpath 的位置MultiWindowMode

/config/UI/General/MultiWindowMode'

对于“紧凑视图”，该条目的值为“1”；对于“默认视图”，该条目的值为“0”

检查这个演示，它使用 XPath 解析文件并读取MultiWindowMode.

{$APPTYPE CONSOLE}

uses
  ComObj,
  ActiveX,
  Variants,
  SysUtils;


function SkypeISCompactView(const SettingsFile : string) : Boolean;
var
   XmlDoc      : OleVariant;
   Node        : OleVariant;
begin
  Result:=False;
   if FileExists(SettingsFile) then
   begin
     XmlDoc       := CreateOleObject('Msxml2.DOMDocument.6.0');
     try
       XmlDoc.Async := False;
       XmlDoc.Load(SettingsFile);
       XmlDoc.SetProperty('SelectionLanguage','XPath');

        if (XmlDoc.parseError.errorCode <> 0) then
         raise Exception.CreateFmt('Error in Xml Data %s',[XmlDoc.parseError]);

       Node  :=XmlDoc.selectSingleNode('/config/UI/General/MultiWindowMode');
       if not VarIsClear(Node) then
        Result:=Node.text='1';
     finally
       XmlDoc:=Unassigned;
     end;
   end;
end;


begin
 try
    CoInitialize(nil);
    try
      Writeln(BoolToStr(SkypeISCompactView('C:\Users\<your windows user>\AppData\Roaming\Skype\<skype user>\config.xml'),True));
    except
      on E:Exception do
      begin
          Writeln(E.Classname, ':', E.Message);
      end;
    end;
 finally
      CoUninitialize;
 end;
 Readln;
end.