Fortran 接受来自 C 的字符串(?)

我觉得这应该是一个简单的问题，但我无法让它发挥作用。我有一些 Fortran 代码，需要如下输入：

      SUBROUTINE TRACE(X,Y,NAME,XX,YY)
      EXTERNAL NAME
      CALL NAME(X,Y,XX,YY)

我正在尝试以以下形式从 C++ 传递名称：

float x,y,xx,yy;
char * name="IGRF";
trace_(&x;,&y;,name,&xx;,&yy;);

它可以编译，但当我尝试调用 NAME 子例程时，总是会出现段错误。文件中定义了一个名为 IGRF 的子例程，我可以直接从 C++ 调用 IGRF 子例程，但需要这个 TRACE 例程。当在 gdb 中运行时，它说 NAME 变量作为指向 void 的指针出现。

我尝试传递 NAME、&NAME、&NAME[0]、一个字符 NAME[4]，该字符 NAME[4] 被删除了 \0 以完全适合该名称，并且它们都返回显示相同的 void 指针。有谁知道如何将 C++ 中的函数名称放入 Fortran 中的 EXTERNAL 变量中？

谢谢

因此，Fortran2003 及更高版本的优点之一是 C 互操作性defined纳入标准；使用起来有点像 PITA，但一旦完成，就保证可以跨平台和编译器工作。

所以这里是cprogram.c，调用 Fortran 例程getstring:

#include <stdio.h>

int main(int argc, char **argv) {
    int l;
    char *name="IGRF";

    l = getstring(name);

    printf("In C: l = %d\n",l);

    return 0;
}

这是fortranroutine.f90:

integer(kind=c_int) function getstring(instr) bind(C,name='getstring') 
    use, intrinsic :: iso_c_binding
    character(kind=c_char), dimension(*), intent(IN) :: instr
    integer :: len
    integer :: i

    len=0
    do
       if (instr(len+1) == C_NULL_CHAR) exit
       len = len + 1
    end do


    print *, 'In Fortran:'
    print *, 'Got string: ', (instr(i),i=1,len)
    getstring = len
end function getstring

makefile 很简单：

CC=gcc
FC=gfortran

cprogram: cprogram.o fortranroutine.o
    $(CC) -o cprogram cprogram.o fortranroutine.o -lgfortran

fortranroutine.o: fortranroutine.f90
    $(FC) -c $^

clean:
    rm -f *.o cprogram *~

并在 gcc/gfortran 和 icc/ifort 下运行它：

 In Fortran:
 Got string: IGRF
In C: l = 4

Update：哦，我刚刚意识到你正在做的事情比仅仅传递一个字符串要复杂得多；您本质上是在尝试传递一个指向 C 回调例程的函数指针。这是一个小技巧，因为你必须使用 Fortraninterface声明 C 例程——仅使用 extern 是行不通的（而且不如显式接口好，因为没有类型检查等）所以这应该有效：

c 程序.c:

#include <stdio.h>

/* fortran routine prototype*/
int getstring(char *name, int (*)(int));

int square(int i) {
    printf("In C called from Fortran:, ");
    printf("%d squared is %d!\n",i,i*i);
    return i*i;
}


int cube(int i) {
    printf("In C called from Fortran:, ");
    printf("%d cubed is %d!\n",i,i*i*i);
    return i*i*i;
}

int main(int argc, char **argv) {
    int l;
    char *name="IGRF";

    l = getstring(name, &square);
    printf("In C: l = %d\n",l);
    l = getstring(name, &cube);
    printf("In C: l = %d\n",l);


    return 0;
}

例程.f90：

integer(kind=c_int) function getstring(str,func) bind(C,name='getstring')
    use, intrinsic :: iso_c_binding
    implicit none
    character(kind=c_char), dimension(*), intent(in) :: str
    type(c_funptr), value :: func

    integer :: length
    integer :: i

    ! prototype for the C function; take a c_int, return a c_int
    interface
        integer (kind=c_int) function croutine(inint) bind(C)
            use, intrinsic :: iso_c_binding
            implicit none
            integer(kind=c_int), value :: inint
        end function croutine
    end interface
    procedure(croutine), pointer :: cfun

    integer(kind=c_int) :: clen

    ! convert C to fortran procedure pointer,
    ! that matches the prototype called "croutine"
    call c_f_procpointer(func, cfun)

    ! find string length
    length=0
    do
       if (str(length+1) == C_NULL_CHAR) exit
       length = length + 1
    end do

    print *, 'In Fortran, got string: ', (str(i),i=1,length), '(',length,').'

    print *, 'In Fortran, calling C function and passing length'
    clen = length
    getstring = cfun(clen)

end function getstring

结果：

$ gcc -g -Wall   -c -o cprogram.o cprogram.c
$ gfortran -c fortranroutine.f90 -g -Wall
$ gcc -o cprogram cprogram.o fortranroutine.o -lgfortran -g -Wall
$ gpc-f103n084-$ ./cprogram 
./cprogram 
 In Fortran, got string: IGRF(           4 ).
 In Fortran, calling C function and passing length
In C called from Fortran:, 4 squared is 16!
In C: l = 16
 In Fortran, got string: IGRF(           4 ).
 In Fortran, calling C function and passing length
In C called from Fortran:, 4 cubed is 64!
In C: l = 64