Excel VBA 禁用快捷键有时会禁用数据输入

为什么我的代码会随机偶尔禁用数据输入，但即使我隔离它并删除所有其他宏，大多数时间仍然可以工作？

该代码禁用了几乎所有快捷键，但不应影响简单的数据输入。

Option Explicit
Rem mod__ShortCutKeys

' Ctrl = "^"
' Alt = "%"
' Shift = "+"
' Combinations ("^", "%", "+", "^%", "^+", "%+", "^%+")

Rem Declare Variables
Dim Ctrl As String
Dim Alt As String
Dim Shift As String
Dim CtrlAlt As String
Dim CtrlShift As String
Dim AltShift As String
Dim CtrlAltShift As String

Dim KeyArray As Variant
Dim Key As Variant
Dim i As Long

Rem Public Sub ShortCutKeysInitializeVariables
Public Sub ShortCutKeysInitializeVariables()

    Ctrl = "^"
    Alt = "%"
    Shift = "+"
    CtrlAlt = "^%"
    CtrlShift = "^+"
    AltShift = "%+"
    CtrlAltShift = "^%+"

    KeyArray = Array(Ctrl, Alt, Shift, CtrlAlt, CtrlShift, AltShift, CtrlAltShift)

End Sub

Rem Public Sub ShortCutKeysDisable
Sub ShortCutKeysDisable()

    Rem Calls
    Call ShortCutKeysInitializeVariables

    ' Combinations
    For Each Key In KeyArray
        For i = 1 To 255
            On Error Resume Next
            Application.OnKey Key & Chr(i), ""
        Next i
    Next Key

    ' Functions keys
    For i = 1 To 12
        On Error Resume Next
        Application.OnKey "{F" & i & "}", ""
    Next i

    ' Combinations & Functions keys
    For Each Key In KeyArray
        For i = 1 To 12
            On Error Resume Next
            Application.OnKey Key & "{F" & i & "}", ""
        Next i
    Next Key

End Sub

灵感来自：禁用按键或组合键 https://stackoverflow.com/questions/30117337/disable-key-or-key-combination

为什么这段代码会阻止我输入任何数据？随机发生且仅有时发生。

我所说的数据输入的意思是，如果我选择了一个单元格并尝试在该单元格中键入数据（大写或小写），它不会执行任何操作。即使我双击单元格进入编辑模式，该问题仍然存在。

关闭并打开文件可以解决该问题，但该问题偶尔会出现。

我正在使用：Excel 2021 Pro Plus LTSC

正如评论中所说，Application.Onkey当您处于编辑模式时，不应对按键行为产生任何影响，因此这告诉我这可能是 Excel/VBA 的错误。

这可能是由于您设置了很多OnKey目标，它会导致一些处理按键的进程表现不稳定，甚至有时会挂起。

可以尝试的一件事是减少您设置的组合键数量。您正在尝试设置1,785（7 x 255）OnKey仅在第一个循环中的目标！

如果您的目标是针对键盘快捷键，那么您当然可以将字符范围从 32 减少到 255，因为我真的怀疑您的键盘是否可以输出不可打印的 ASCII 字符 https://learn.microsoft.com/en-us/office/vba/language/reference/user-interface-help/chr-function#:%7E:text=Numbers%20from%200%E2%80%9331%20are%20the%20same%20as%20standard%2C%20nonprintable%20ASCII%20codes。您甚至可以考虑将其减少到 32 到 127，具体取决于键盘上是否有重音字符。

如果这还不足以解决问题，您可以尝试重置Application.OnKey组合恢复到原始状态，然后重新禁用所有快捷方式，看看是否可以正确重置。

例如，您可以对过程进行修改版本，该版本利用传递Application.OnKey "...", Null将重置所传递的键的行为：

Sub ShortCutKeysToggle(Enabled As Boolean)

    Dim Proc As Variant
    If Enabled Then
        Proc = Null
    Else
        Proc = ""
    End If

    ShortCutKeysInitializeVariables

    ' Combinations
    For Each Key In KeyArray
        For i = 32 To 255
            On Error Resume Next
            Application.OnKey Key & Chr(i), Proc
        Next i
    Next Key

    ' Functions keys
    For i = 1 To 12
        On Error Resume Next
        Application.OnKey "{F" & i & "}", Proc
    Next i

    ' Combinations & Functions keys
    For Each Key In KeyArray
        For i = 1 To 12
            On Error Resume Next
            Application.OnKey Key & "{F" & i & "}", Proc
        Next i
    Next Key

End Sub

然后，当您遇到错误时，您可以通过以下过程来切换或重置按键。

Sub ShortCutKeysEnable()
    ShortCutKeysToggle True
End Sub

Sub ShortCutKeysDisable()
    ShortCutKeysToggle False
End Sub

Sub ShortCutKeysReset()
    ShortCutKeysToggle True
    ShortCutKeysToggle False
End Sub

UPDATE：以下部分现在无关紧要，因为它不是关闭并重新打开文件来解决问题，而是关闭并重新打开 Excel 应用程序。

如果这不起作用，您提到关闭和打开文件解决了问题，因此您始终可以使用一个宏来关闭文件并重新打开它。

Sub CloseAndReopenActiveWorkbook()
    
    Application.ScreenUpdating = False
    
    Dim FileName As String
    FileName = ActiveWorkbook.FullName
    
    ActiveWorkbook.Close SaveChanges:=True
    Workbooks.Open FileName:=FileName
    
    Application.ScreenUpdating = True

End Sub