Delphi TListBox OnClick / OnChange？

使用 TListBox 获得“OnChange”类型的功能是否有技巧？我可以对组件进行子类化并添加属性等，然后仅在索引更改时执行 OnClick 代码...我还可以使用表单级别变量来破解它以存储当前索引，但只是想知道我是否忽略了之前明显的内容我选择一种方式或另一种方式。

除了自己实现之外，似乎没有其他办法了。您需要的是记住当前选择的项目，并且每当ItemIndex http://docwiki.embarcadero.com/Libraries/en/Vcl.Controls.TCustomListControl.ItemIndex属性从代码中更改或每当控件收到LBN_SELCHANGE http://msdn.microsoft.com/en-us/library/windows/desktop/bb775161%28v=vs.85%29.aspx通知（当前触发OnClick http://docwiki.embarcadero.com/Libraries/en/Vcl.Controls.TControl.OnClick事件），您将比较您存储的项目索引与当前选择的项目索引，如果它们不同，则触发您自己的项目索引OnChange事件。在插入类的代码中，它可能是：

type
  TListBox = class(StdCtrls.TListBox)
  private
    FItemIndex: Integer;
    FOnChange: TNotifyEvent;
    procedure CNCommand(var AMessage: TWMCommand); message CN_COMMAND;
  protected
    procedure Change; virtual;
    procedure SetItemIndex(const Value: Integer); override;
  published
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

implementation

{ TListBox }

procedure TListBox.Change;
begin
  if Assigned(FOnChange) then
    FOnChange(Self);
end;

procedure TListBox.CNCommand(var AMessage: TWMCommand);
begin
  inherited;
  if (AMessage.NotifyCode = LBN_SELCHANGE) and (FItemIndex <> ItemIndex) then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;

procedure TListBox.SetItemIndex(const Value: Integer);
begin
  inherited;
  if FItemIndex <> ItemIndex then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;