如何通过 Grails 使用 imgscalr

我最近几天才开始使用 Groovy 和 Grails。我之前没有任何 Java 经验，所以您必须原谅这个（可能）非常基本的问题。我搜索了 Google 和 Stack Overflow，但没有找到任何可以帮助我实际安装的内容。

我已经可以上传图像，并且正在将文件存储在服务器上。我使用 IBM Grails 教程来指导我完成它。效果很好。

我还想以大、中、小格式调整文件大小。我想使用 imgscalr 来实现此目的，但我无法让它工作。我已经下载了 4.2 版本，其中包含各种 .jar 文件。我需要将它们放在服务器上的某个位置并引用它们吗？我所做的唯一一件事就是将这些行添加到buildConfig.groovy

dependencies {
    // specify dependencies here under either 'build', 'compile', 'runtime', 'test' or 'provided' scopes eg.

    // runtime 'mysql:mysql-connector-java:5.1.20'
    compile 'org.imgscalr:imgscalr-lib:4.2'
}

and import org.imgscalr.Scalr.* in my PhotoController.Groovy

这是我将文件保存到服务器上的代码，我还想调整大小并保存图像。

def save() {
    def photoInstance = new Photo(params)

    // Handle uploaded file
    def uploadedFile = request.getFile('photoFile')
    if(!uploadedFile.empty) {
        println "Class: ${uploadedFile.class}"
        println "Name: ${uploadedFile.name}"
        println "OriginalFileName: ${uploadedFile.originalFilename}"
        println "Size: ${uploadedFile.size}"
        println "ContentType: ${uploadedFile.contentType}"

        def webRootDir = servletContext.getRealPath("/")

        def originalPhotoDir = new File(webRootDir, "/images/photographs/original")
        originalPhotoDir.mkdirs()
        uploadedFile.transferTo(new File(originalPhotoDir, uploadedFile.originalFilename))

        BufferedImage largeImg = Scalr.resize(uploadedFile, 1366);
        def largePhotoDir = new File(webRootDir, "/images/photographs/large")
        largePhotoDir.mkdirs()

        photoInstance.photoFile = uploadedFile.originalFilename
    }

    if (!photoInstance.hasErrors() && photoInstance.save()) {
        flash.message = "Photo ${photoInstance.id} created"
        redirect(action:"list")
    }
    else {
        render(view:"create", model:[photoInstance: photoInstance])
    }
}

我收到的错误是No such property: Scalr for class: garethlewisweb.PhotoController

我显然做了一些非常错误的事情。任何指导表示赞赏。

这是“How to use imgscalr in grails”的第一个谷歌结果，我对谷歌搜索时缺乏信息和示例感到惊讶。虽然第一个答案很接近，但仍有一些错误需要纠正。

对于像我这样通过谷歌结束这里的人，这里有一个更详细的示例，说明如何正确使用这个不错的插件：

首先，在您的中声明插件BuildConfig.groovy file:

dependencies {
    // specify dependencies here under either 'build', 'compile', 'runtime', 'test' or 'provided' scopes eg.

    // runtime 'mysql:mysql-connector-java:5.1.20'
    compile 'org.imgscalr:imgscalr-lib:4.2'
}

然后，安装后，只需将这段代码粘贴到您的控制器中，在接收带有上传图像的多部分表单的操作中。

def create() {

     def userInstance = new User(params)

     //saving image
     def imgFile = request.getFile('myFile')
     def webRootDir = servletContext.getRealPath("/")
     userInstance.storeImageInFileSystem(imgFile, webRootDir)  

     (...) 
}

在我的域内，我实现了这个storeImageInFileSystem方法，它将调整图像大小并将其存储在文件系统中。但首先，将其导入到文件中：

import org.imgscalr.Scalr
import java.awt.image.BufferedImage
import javax.imageio.ImageIO

然后，实现该方法：

def storeImageInFileSystem(imgFile, webRootDir){

    if (!imgFile.empty)
    {
        def defaultPath = "/images/userImages"
        def systemDir = new File(webRootDir, defaultPath)

        if (!systemDir.exists()) {
            systemDir.mkdirs()
        }

        def imgFileDir = new File( systemDir, imgFile.originalFilename)
        imgFile.transferTo( imgFileDir )

        def imageIn = ImageIO.read(imgFileDir);

        BufferedImage scaledImage = Scalr.resize(imageIn, 200);   //200 is the size of the image
        ImageIO.write(scaledImage, "jpg", new File( systemDir, imgFile.originalFilename )); //write image in filesystem

       (...)
    }
}

这对我来说效果很好。根据需要更改任何详细信息，例如系统目录或图像的大小。