在 PL/SQL 存储过程中拆分逗号分隔的字符串

我有 CSV 字符串 100.01,200.02,300.03，我需要将其传递给 Oracle 中的 PL/SQL 存储过程。 在过程中，我需要将这些值插入表中的数字列中。

为此，我从这里得到了一个工作方法：

如何在 oracle 9i 中最好地分割 csv 字符串 https://stackoverflow.com/questions/1089508/how-to-best-split-csv-strings-in-oracle-9i

[2) 使用SQL的按级别连接]。

现在，我还有另一个要求。 我需要传递 2 个 CSV 字符串[长度相等]作为 PL/SQL 存储过程的输入。并且，我需要断开该字符串并将两个 CSV 字符串中的每个值插入到表中的两个不同列中。您可以让我吗？知道该怎么做吗？

CSV 输入示例： mystring varchar2(2000):='0.75, 0.64, 0.56, 0.45';

myAmount varchar2(2000):= '0.25, 0.5, 0.65, 0.8';

myString 值将进入表中的 A 列，myAmount 值将进入 B 列。

您能让我知道如何实现这一目标吗？

Thanks.

这应该可以满足您的需求。它假设您的列表始终只是数字。如果不是这种情况，只需将对 DBMS_SQL.NUMBER_TABLE 的引用更改为适用于所有数据的表类型：

CREATE OR REPLACE PROCEDURE insert_from_lists(
    list1_in IN VARCHAR2,
    list2_in IN VARCHAR2,
    delimiter_in IN VARCHAR2 := ','
)
IS 
    v_tbl1 DBMS_SQL.NUMBER_TABLE;
    v_tbl2 DBMS_SQL.NUMBER_TABLE;

    FUNCTION list_to_tbl
    (
        list_in IN VARCHAR2
    )
    RETURN DBMS_SQL.NUMBER_TABLE
    IS
        v_retval DBMS_SQL.NUMBER_TABLE;
    BEGIN

        IF list_in is not null
        THEN
            /*
            || Use lengths loop through the list the correct amount of times,
            || and substr to get only the correct item for that row
            */
            FOR i in 1 .. length(list_in)-length(replace(list_in,delimiter_in,''))+1
            LOOP
                /*
                || Set the row = next item in the list
                */
                v_retval(i) := 
                        substr (
                            delimiter_in||list_in||delimiter_in,
                            instr(delimiter_in||list_in||delimiter_in, delimiter_in, 1, i  ) + 1,
                            instr (delimiter_in||list_in||delimiter_in, delimiter_in, 1, i+1) - instr (delimiter_in||list_in||delimiter_in, delimiter_in, 1, i) -1
                        );
            END LOOP;
        END IF;

        RETURN v_retval;

    END list_to_tbl;
BEGIN 
   -- Put lists into collections
   v_tbl1 := list_to_tbl(list1_in);
   v_tbl2 := list_to_tbl(list2_in);

   IF v_tbl1.COUNT <> v_tbl2.COUNT
   THEN
      raise_application_error(num => -20001, msg => 'Length of lists do not match');
   END IF;

   -- Bulk insert from collections
   FORALL i IN INDICES OF v_tbl1
      insert into tmp (a, b)
      values (v_tbl1(i), v_tbl2(i));

END insert_from_lists;