将所有工作表中的值替换为新值

我有大约 40 个电子表格，每个电子表格最多包含 300k 行 x 93 列（当前）。大约有 11 亿个数据点。我需要检查每个单元格，并确定单元格是否包含 8 个特殊字符之一，这些字符在电子表格的导入中已被弄乱。

这是一项每天需要运行多次的任务以及许多其他步骤。因此，我正在寻找一种使用 VBA 来完成此操作的方法。我有以下代码：

Sub Hide_All_Sheets()

Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.DisplayStatusBar = False

Dim k As Integer
Dim t As String
Dim x As Integer

k = Sheets.Count
x = 1

    While x <= k
        t = Sheets(x).Name
        If t = "Launch Screen" Or t = "Equiv sheet" Then
            x = x + 1
        ElseIf t = "Summary_1" And Worksheets("Launch Screen").Range("N5") = "1" Then
            Sheets(x).Visible = True
            x = x + 1
        Else

            Cells.Replace What:="ö", Replacement:=Chr(214), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="ü", Replacement:=Chr(220), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="ä", Replacement:=Chr(220), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="ß", Replacement:=Chr(223), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="è", Replacement:=Chr(200), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="Ü", Replacement:=Chr(223), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False
            Cells.Replace What:="Ä", Replacement:=Chr(223), LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=True, SearchFormat:=False, _
            ReplaceFormat:=False

            Sheets(x).Visible = False
            x = x + 1
        End If

    Wend

End Sub

唯一的问题是加载过程从 20 秒变成了 900 秒。

我想知道有没有办法更快地做到这一点？特别是如果有一种方法可以运行手动 CTRL-H 过程，并在所有电子表格中进行替换，但使用 VBA？

11亿个任务还有很多工作要做。您的代码有条不紊地循环遍历每个工作表广告，替换七个（not8) 输入时损坏的特殊字符。

下面使用工作簿范围的方法来替换工作表集合中的循环。这可能有助于保留要处理的信息的“负载”。

Sub Repair_All_Worksheets()
    Dim fr As Long, FandR As Variant, vWSs As Variant

    appTGGL bTGGL:=False

    FandR = Array("ö", Chr(214), "ü", Chr(220), "ä", Chr(220), "ß", Chr(223), _
              "è", Chr(200), "Ü", Chr(223), "Ä", Chr(223))

    With ActiveWorkbook
        ReDim vWSs(1 To .Worksheets.Count)
        For fr = LBound(vWSs) To UBound(vWSs)
            vWSs(fr) = .Worksheets(fr).Name
        Next fr

        With .Worksheets(vWSs)
            .Select
            .Parent.Worksheets(vWSs(1)).Activate
            For fr = LBound(FandR) To UBound(FandR) Step 2
                Cells.Replace What:=FandR(fr), Replacement:=FandR(fr + 1), LookAt:=xlPart
            Next fr
        End With
    End With

    appTGGL

End Sub

Public Sub appTGGL(Optional bTGGL As Boolean = True)
    Debug.Print Timer
    With Application
        .ScreenUpdating = bTGGL
        .EnableEvents = bTGGL
        .DisplayAlerts = bTGGL
        .Calculation = IIf(bTGGL, xlCalculationAutomatic, xlCalculationManual)
    End With
End Sub

The Application.EnableEvents 属性 https://msdn.microsoft.com/en-us/library/office/ff821508.aspx与其他环境变量一起被禁用。这应用.计算 https://msdn.microsoft.com/en-us/library/office/ff821260.aspx同样暂时暂停xl计算手册 https://msdn.microsoft.com/en-us/library/office/ff835845.aspx。这对于具有易失性函数的工作表尤其重要，但这里的情况似乎并非如此。

顺便说一句，导入数据时，文本导入向导允许您在第一页上指定代码页文件来源：文本框。将其设置为正确的区域代码页（或者可能只是 65001：Unicode (UTF-8)）应该可以修复您的导入问题。这工作簿.OpenText 方法 https://msdn.microsoft.com/en-us/library/office/ff837097.aspx有类似的选项。