我拥有的：

1. 我有一个 Excel VBA 自定义用户表单。
2. 该表单包含一个下拉列表（行业类别）和文本框（对应行业规范者).
3. 对于每个行业类别有一个行业规范者（该类别的缩写版本）。
4. The 行业类别 and 行业规范者将始终位于同一行。
5. 下拉列表由单元格名称范围填充。

我需要的：

文本框的值需要依赖于下拉列表的值。

例如当行业类别被选中后，对应的行业代码应该出现在文本框中。

我的细胞结构：

A 列（行业类别）：

Agriculture                               
Art and photography                       
Arts and theatre                          
Charity and non-profit                    
Corporate                                   
Educational and academic                

B 栏（行业规范者):

ag
ap
at
cn
co
ea

我的VBA代码：

填充下拉列表行业类别:

'Populate Industry combo box.
Dim range_c As Range
Dim ws_c As Worksheet
Set ws_c = Worksheets("4.1 List data")

For Each range_c In ws_c.Range("IndustryList")
  With Me.Industry
    .AddItem range_c.Value
    .List(.ListCount - 1, 1) = range_c.Offset(0, 1).Value
  End With
Next range_c

文本框用于行业规范者:

IndustrySpecifier.Value = ""

我尝试过的：

我已经查看了有关如何单独使用 VBA 代码实现我需要的教程，但我不知道从哪里开始使用依赖命名范围

你需要这样的东西：

Private Sub UserForm_Initialize()
    Dim range_c As Range

    For Each range_c In Worksheets("4.1 List data").Range("IndustryList")
      With Me.Industry
        .AddItem range_c.Value
        .List(.ListCount - 1, 1) = range_c.Offset(0, 1).Value
      End With
    Next range_c
End Sub

Private Sub Industry_Change()
    With Me.Industry
        If .ListIndex = -1 Then
            IndustrySpecifier.Text = ""
        Else
            IndustrySpecifier.Text = .List(.ListIndex, 1)
        End If
    End With
End Sub