如何使用“here-doc”将行打印到文件？

基本上，这是我在过去半小时内编程和使用 Google 的结果，试图实现一个简单的事情：从以下位置获取用户输入：STDIN并将它们写入结构化 XML 文件作为输出。下面是我丑陋的代码：

#!/bin/perl
print "img URL = ?    ";
$img = <>;
chomp($img);
print "filename = ?    ";
$filename = <>;
chomp($filename);

# now write xml with inserted contents to a file:
open (CARDFILE, ">>$filename");
print CARDFILE "<card>\r\n";
print CARDFILE "    <img>$img</img>\r\n";
print CARDFILE "    <type>$type</type>\r\n";
print CARDFILE "    <expansion>$expansion</expansion>\r\n";
print CARDFILE "    <keyword>$keyword</keyword>\r\n";
print CARDFILE "    <color>$color</color>\r\n";
print CARDFILE "    <linkcolor>$linkcolor</linkcolor>\r\n";
print CARDFILE "    <kickercolor>$kickercolor</kickercolor>\r\n";
print CARDFILE "    <cost>$cost</cost>\r\n";
print CARDFILE "    <strength>$strength</strength>\r\n";
print CARDFILE "    <health>$health</health>\r\n";
print CARDFILE "</card>";
close (CARDFILE);  

我是 Perl 新手，但我可以说出我的代码中的一些重大问题：

1. 使用两条线先接收STDIN then chomp()它摆脱了尾随的回车符。是否应该有一个单行线？

2. 我无法弄清楚如何使用“here-doc”一次性打印多行文件。如果没有CARDFILE文件句柄，我可以使用here-doc语法将所有字符串打印到STDOUT在单个打印语句中。现在我必须多次调用打印函数。

3. 对于这些"\r\n"s，有没有办法使用不同的函数，这样我就不必记住在每行后面手动插入它们？

读取一行

阅读一行的习惯用法是

chomp(my $var = <>);

但我通常最终会写一个小prompt子程序：

sub prompt {
  print @_;
  chomp(my $answer = <>);
  return $answer;
}
...;
my $img = prompt("img URL = ? ");

此处文档

Here-doc 只是另一种字符串文字，例如

my $str = <<"END";
foo bar
baz
END
print $str;

如果将分隔符用单引号引起来：<<'END'，那么您就无法将变量插入到此处文档中。请注意，结束标记必须始终位于行的开头，但可以包含空格字符：

    my $string = <<'END THIS';
    foo
    bar
END THIS
    # marker must be at start of line!

您可以直接打印此处文档，例如

print CARDFILE <<"END";
<card>
    <img>$img</img>
    <type>$type</type>
    <expansion>$expansion</expansion>
    <keyword>$keyword</keyword>
    <color>$color</color>
    <linkcolor>$linkcolor</linkcolor>
    <kickercolor>$kickercolor</kickercolor>
    <cost>$cost</cost>
    <strength>$strength</strength>
    <health>$health</health>
</card>
END

区别就在这里，不会有\r\n位于行尾，除非您使用 Windows 行结尾保存源文件。但是，此处文档确实包含物理换行符，并且始终以换行符终止。

打印东西

The print函数打印由 分隔的参数$,特殊变量，然后输出$\多变的。默认情况下，这两个都是空的。但我们可以提供一个临时值：

local $\ = "123";
print "foo";

Output:

foo123

当然，我们通常会设置为\n。但有一个捷径：只需放一个use feature 'say' or use 5.010（或更高）在源代码的开头，那么你可以

say "foo";

它会自动附加换行符。

打开文件句柄

使用词汇变量。使用三参数打开。进行适当的错误处理。这意味着：

use autodie;
open my $fh, "<", "filename";

or

my $filename = "filename";
open my $fh, "<", $filename or die "Can't open $filename: $!";

第二个参数是mode，这将是>>用于追加。明确指定它而不是作为文件名的一部分更安全。

一般说明

Always use strict; use warnings;在脚本的顶部，这有助于发现问题。