使用单个字符串查找多个文件路径

我尝试编写一个批处理脚本来查找与输入字符串同名的文件的所有路径。现在它只能找到找到的第一个文件，我想不出一种方法让它列出多个文件位置。我经验不足，需要一些帮助。

这是脚本代码的一部分：

:start
    cls
    echo Enter file name with extension:
    set /p filename=
    echo Searching...

for %%a in (C D E F G H U W) do (
    for /f "tokens=*" %%b in ('dir /s /b "%%a:\%filename%"') do (
        set file=%%~nxb
        set datapath=%%~dpb\
        ::the path of the file without the filename included "C:\folder\folder\"
        set fullpath=%%b
        ::the path of the file with the filename included "C:\folder\folder\file"
        goto break
  )
)
:notfound
    cls
    echo Enter file name with extension:
    echo %filename%
    echo File Not Found!
    ping localhost -n 4 >nul
    goto start

:break
    if "%datapath:~-1%"=="\" set datapath=%datapath:~,-1%
    cls
    echo 3 %filename% found
    echo %fullpath1%
    echo %fullpath2%
    echo %fullpath3%
    --- || ---

我希望脚本搜索计算机并列出每个遇到的同名文件，并且我希望能够将这些文件的路径放入不同的变量中。
例如，如果 readme.txt 是输入，那么我想要具有该特定名称 (readme.txt) 的所有文件的所有路径的列表，并且我想为每个路径设置变量，以便之后可以使用它。

input:  
readme.txt

output:  
3 files found  
C:\folder\folder\readme.txt  
C:\folder\folder\folder\readme.txt  
D:\folder\readme.txt

@echo off
set filename=readme.txt
for %%a in (C D E F G H U W) do (
  for /f "tokens=*" %%b in ('dir /s /b "%%a:\%filename%"') do (
    echo you can do something here with  %%~nxb in %%~dpb
    echo    full name: %%b
  )
)

我认为不需要将文件名设置为变量，因为您可以在循环内处理它们。但如果你确实需要它们（出于某种原因）在变量中：

@echo off
setlocal enabledelayedexpansion
set filename=readme.txt
set count=0
for %%a in (C D E F G H U W) do (
  for /f "tokens=*" %%b in ('dir /s /b "%%a:\%filename%" 2^>nul') do (
    set /a count+=1
    set _file[!count!]=%%b
  )
)
set _file