组件中这些嵌套控件的 Tab 键顺序与组件所在窗体的 Tab 键顺序不同。当您按 Tab 键切换到嵌套控件时,窗体的 Tab 键顺序列表中组件的 Tab 键顺序将由您决定。一旦所有选项卡顺序列表组合起来,就会产生最终循环:
- 表单上的控件 (
TabOrder=0
)
- 表单上的另一个控件(
TabOrder=1
)
- Your panel component (
TabOrder=2
)
- Edit 1 (
TabOrder=0
)
- Edit 2 (
TabOrder=1
)
- 表单上的另一个控件(
TabOrder=3
)
为了能够设置面板组件设计时的选项卡顺序:
在运行时,始终可以设置组件的 Tab 键顺序,因为TabOrder
财产被宣布为公开TWinControl
.
...它无法获得焦点,因为它是一个面板。
不,面板可以很好地获得焦点,但默认情况下不会。这是用TabStop
属性,即False
默认情况下。你不想要TabStop
to set True
对于您的组件,因为(1)面板没有指示器,它具有焦点,(2)它是不需要的(我想)。
更改嵌套控件的 Tab 键顺序最好在组件的构造函数中或在运行时完成。
为了能够在设计时设置组件内嵌套控件的 Tab 键顺序,需要做更多的工作。我不认为你想要那样,但由于我之前的答案(已删除)是垃圾(并且奇怪地投票),我已经制定了一个例子作为补偿。
首先,请注意,使用设计器中的 Tab 键顺序编辑器(右键单击面板组件)设置这些编辑的 Tab 键顺序将更改 Tab 键顺序,但不会持续。这是因为这些更改不会传输到 DFM。
为了能够流式传输/保存控件的设计时更改,您需要发布它们:
type
TMyPanel = class(TCustomPanel)
private
FEdit1: TEdit;
FEdit2: TEdit;
public
constructor Create(AOwner: TComponent); override;
published
property Edit1: TEdit read FEdit1;
property Edit2: TEdit read FEdit2;
end;
constructor TMyPanel.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FEdit1 := TEdit.Create(Self);
FEdit1.SetBounds(10, 10, 100, 21);
FEdit1.Name := 'Edit1';
FEdit1.Parent := Self;
FEdit1.SetSubComponent(True);
FEdit2 := TEdit.Create(Self);
FEdit2.SetBounds(10, 41, 100, 21);
FEdit2.Name := 'Edit2';
FEdit2.Parent := Self;
FEdit2.SetSubComponent(True);
end;
当然,这会发布这些控件的所有属性,现在用户可以更改他们想要的任何内容。为了防止这种情况,请考虑限制已发布的属性TEdit
控制:
unit MyPanelEdit;
interface
uses
DesignEditors, Unit2, DesignIntf, SysUtils, Classes, TypInfo, StdCtrls;
type
TEditProperty = class(TComponentProperty)
private
function FilterFunc(const ATestEditor: IProperty): Boolean;
public
function GetAttributes: TPropertyAttributes; override;
procedure GetProperties(Proc: TGetPropProc); override;
end;
procedure Register;
implementation
procedure Register;
begin
RegisterPropertyEditor(TypeInfo(TEdit), TMyPanel, '', TEditProperty);
end;
{ TEditProperty }
function TEditProperty.FilterFunc(const ATestEditor: IProperty): Boolean;
begin
Result := ATestEditor.GetName = 'TabOrder';
end;
function TEditProperty.GetAttributes: TPropertyAttributes;
begin
Result := [paSubProperties];
end;
procedure TEditProperty.GetProperties(Proc: TGetPropProc);
var
LComponents: IDesignerSelections;
LDesigner: IDesigner;
begin
LComponents := GetSelections;
if LComponents <> nil then
begin
if not Supports(
FindRootDesigner(LComponents[0]), IDesigner, LDesigner) then
LDesigner := Designer;
GetComponentProperties(LComponents, [tkInteger], LDesigner, Proc,
FilterFunc);
end;
end;
end.
这限制了已发布的属性TEdit
仅显示属性TabOrder
.