使用 groovy 向 jenkins 作业添加附加参数

我们有一组 groovy 脚本，用户可以在他们的 jenkins 文件中调用它们来设置一些常见的作业属性。但是，我们无法弄清楚在进行此更新时如何保留其现有参数。

我们的常规代码片段：

def newParamsList = []
def newbool = booleanParam(defaultValue: false, description: "deploy", name: "deploy_flag")
newParamsList.add(newbool)
def newParams = parameters(newParamsList)
properties([ //job property declaration
    jobProperties,
    disableConcurrentBuilds(),
    newParams,
    addSchedule,
  ])

但是，这会覆盖参数定义，因此如果用户在调用我们的 groovy 之前在其 jenkins 文件中指定了不同的参数定义，那么它就会被清除。

我可以使用 currentBuild.rawBuild.getAction(ParametersAction) 访问现有参数，但如果我理解正确，我需要 ParameterDefinition 而不是 ParameterValue 才能设置属性。我尝试了 currentBuild.rawBuild.getAction(ParametersDefinitionProperty.class) 认为我可以像ParameterAction一样使用它，但它返回 null。

是否可以获取从 Jenkinsfile 调用的 groovy 内的参数定义？或者是否有其他方法可以让我们向作业添加附加参数，而无需清除 jenkinsfile 中当前定义的现有参数？

因此，我们这样做的方法是将其视为一个简单的列表，然后将它们连接在一起。因此 jenkinsfile 首先从共享库获取一个列表，然后将自己的列表添加到列表中，然后设置参数（不是共享库）

存储库 jenkinsfiles 这样做：

#!groovy
@Library('shared') _

// Call shared libaray for common params
def paramList = jobParams.listParams ([
    "var1": "value",
    "var2": "value2"
])
// Define repo specific params
def addtionalParams = [
    booleanParam(defaultValue: false, name: 'SOMETHING', description: 'description?'),
    booleanParam(defaultValue: false, name: 'SOMETHING_ELSE', description: 'description?'),
]
// Set Jenkins job properties, combining both
properties([
    buildDiscarder(logRotator(numToKeepStr: '20')),
    parameters(paramList + addtionalParams)
])

// Do repo stuff

我们的共享库如下所示：

List listParams(def body = [:]) {
    //return list of parameters
    config = BuildConfig.resolve(body)

    // Always common params
    def paramsList = [
        choice(name: 'ENV', choices: ['dev', 'tst'].join('\n'), description: 'Environment'),
        string(name: 'ENV_NO', defaultValue: "1", description: 'Environment number'),
    ]

    // Sometimes common params, switch based on jenkinsfile input
    def addtionalParams = []

    switch (config.var1) {
        case 'something':
        case 'something2':
            addtionalParams = [
                choice(name: 'AWS_REGION', choices: ['us-west-2'].join('\n'), description: 'AWS Region to build/deploy'),
            ]
            break
        case 'something3':
            addtionalParams = [
                string(name: 'DEBUG', defaultValue: '*', description: 'Namespaces for debug logging'),
            ]
            break
    }

    return paramsList + addtionalParams
}