Gradle，在撰写多平台项目中使用material3

我正在使用 Jetpack Compose Multiplatform Desktop 做一个项目。 我对 Gradle 不太熟悉，我想在我的项目中使用 Material 3。 所以，我添加了这一行build.gradle.kts file:

implementation("androidx.compose.material3:material3:1.0.0-alpha14")

但是当我尝试使用以下命令将库导入 Kotlin 文件中时：

import androidx.compose.material3.*

我有一个unresolved reference issue.

这是我的build.gradle.kts file:

import org.jetbrains.compose.desktop.application.dsl.TargetFormat

plugins {
    kotlin("multiplatform")
    id("org.jetbrains.compose")
}

group = "com.example"
version = "1.0-SNAPSHOT"

repositories {
    google()
    mavenCentral()
    maven("https://maven.pkg.jetbrains.space/public/p/compose/dev")
}

kotlin {
    jvm {
        compilations.all {
            kotlinOptions {
                jvmTarget = "18"
                freeCompilerArgs = listOf("-opt-in=kotlin.RequiresOptIn")
            }
        }
        withJava()
    }
    sourceSets {
        val jvmMain by getting {
            dependencies {
                implementation(compose.desktop.currentOs)
                implementation("androidx.compose.material3:material3:1.0.0-alpha14")
            }
        }
        val jvmTest by getting
    }
}

compose.desktop {
    application {
        mainClass = "MainKt"
        jvmArgs += listOf("-Djava.library.path=./lib")
        nativeDistributions {
            targetFormats(TargetFormat.Dmg, TargetFormat.Msi, TargetFormat.Deb)
            packageName = "FanControl"
            packageVersion = "1.0.0"
        }
    }
}

我想我应该能够使用这个库，因为发行公告 https://github.com/JetBrains/compose-jb/releases/tag/v1.2.1表示支持。

编辑1： 当我尝试同步时，我收到来自 Gradle 的消息：

Could not resolve: androidx.compose.material3:material3:1.0.0-alpha14

终于找到问题所在了，是库错误， 改变

implementation("androidx.compose.material3:material3:1.0.0-alpha14")

with

implementation("org.jetbrains.compose.material3:material3-desktop:1.2.1")