带有 Spock Stub 的泛型

我无法为泛型类编译 Spock 存根。构造函数的签名如下：

SomeClass(SerSup<Cap> capSup, String foo, String bar);

我需要存根第一个参数。以下是我失败的尝试。

第一次尝试：

def someClass = new SomeClass(Stub(SerSup<Cap>), "foo", "bar")

Error: Groovyc: unexpected token: >
Status bar: ',' or ')' expected

另一种尝试：

def someClass = new someClass(Stub(Cup) as SerSup<Cup>, "foo" ,"bar")

groovy.lang.MissingMethodException: No signature of method: com.sun.proxy.$Proxy10.get() is applicable for argument types: () values: []
Possible solutions: grep(), getAt(java.lang.String), grep(java.lang.Object), wait(), any(), wait(long)

at loom.SomeClass.SomeMethod(SomeClassTest.groovy:14)

存根第一个参数的正确方法是什么SomeClass构造函数？

您的第二次尝试失败，因为您无法施放Stub(Cap) to SerSup<Cap>。你必须Stub(SerSup)相反，或者您可以应用我在下面描述的建议。

我建议在初始化之前为您的存根创建一个变量SomeClass。您可以使用存根泛型类Stub(type: ...)构造函数，例如

SerSup<String> serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type) as SerSup<String>

此初始化不会在 IDE 中产生任何警告。如果您可以接受一些警告，您可以将其简化为：

def serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type)

或者，您可以尝试类似的方法：

SerSup<String> serSup = Stub(SerSup) {
    get() >> ""
}

这种替代解决方案需要存根方法返回有效类型，否则它返回相当于new Object()。在第一种情况下，返回“默认”值，因为我们满足了所有类型检查（例如，在String，返回空字符串）。

下面是一个显示这两种方法的示例：

import com.google.common.reflect.TypeToken
import spock.lang.Specification

class StubSpec extends Specification {

    def "test stubbing with default value for String"() {
        when:
        SerSup<String> serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type) as SerSup<String>

        then:
        serSup.get() == ""
    }

    def "test stubbing without explicit type"() {
        when:
        SerSup<String> serSup = Stub(SerSup) {
            get() >> "lorem ipsum"
        }

        then:
        serSup.get() == "lorem ipsum"
    }

    static class SerSup<T> {
        private final T obj

        SerSup(T t) {
            this.obj = t
        }

        T get() {
            return obj
        }
    }
}