如何在Excel VBA中获取给定模块名称的函数和子列表

我正在开发一个帮助宏，它可以查看活动 Excel 工作簿上给定模块名称的列表函数。 例如：我有一个模块名称“Module1”。该模块内部有以下功能或子功能

Sub Sub1()
End Sub

Sub Sub2()
End Sub

Function Func1()
End Function

Function Func2()
End Function

是否有命令或例程可以返回函数和子名称列表？

这是 Chip Pearson 网站的链接。每当我需要编写影响或使用 VBE 的内容时，我都会去这里。您可能会对 2 个部分感兴趣。将列出项目中的所有模块。另一个将列出模块中的所有过程。希望有帮助。

http://www.cpearson.com/excel/vbe.aspx http://www.cpearson.com/excel/vbe.aspx

来自站点的代码（请确保访问该站点以获取有关添加对 VBIDE 对象库的引用的说明：

此代码将列出 Module1 中的所有过程，从单元格 A1 中开始列出。

Sub ListProcedures()
    Dim VBProj As VBIDE.VBProject
    Dim VBComp As VBIDE.VBComponent
    Dim CodeMod As VBIDE.CodeModule
    Dim LineNum As Long
    Dim NumLines As Long
    Dim WS As Worksheet
    Dim Rng As Range
    Dim ProcName As String
    Dim ProcKind As VBIDE.vbext_ProcKind

    Set VBProj = ActiveWorkbook.VBProject
    Set VBComp = VBProj.VBComponents("Module1")
    Set CodeMod = VBComp.CodeModule

    Set WS = ActiveWorkbook.Worksheets("Sheet1")
    Set Rng = WS.Range("A1")
    With CodeMod
        LineNum = .CountOfDeclarationLines + 1
        Do Until LineNum >= .CountOfLines
            ProcName = .ProcOfLine(LineNum, ProcKind)
            Rng.Value = ProcName
            Rng(1, 2).Value = ProcKindString(ProcKind)
            LineNum = .ProcStartLine(ProcName, ProcKind) + _
                    .ProcCountLines(ProcName, ProcKind) + 1
            Set Rng = Rng(2, 1)
        Loop
    End With

End Sub

Function ProcKindString(ProcKind As VBIDE.vbext_ProcKind) As String
    Select Case ProcKind
        Case vbext_pk_Get
            ProcKindString = "Property Get"
        Case vbext_pk_Let
            ProcKindString = "Property Let"
        Case vbext_pk_Set
            ProcKindString = "Property Set"
        Case vbext_pk_Proc
            ProcKindString = "Sub Or Function"
        Case Else
            ProcKindString = "Unknown Type: " & CStr(ProcKind)
    End Select
End Function