Antlr 处理异常

我使用 Antlr 3 和 AST 树开发了一个复杂的语法。 ANTLR 生成词法分析器和解析器。问题是，例如，当用户输入无效的语法时，该语法需要“;”。用户没有输入此内容，然后在我的 Eclipse IDE 中出现以下异常：

 line 1:24 mismatched input '<EOF>' expecting ';'

如何处理这个异常，因为我尝试捕获这个异常，但是异常没有被捕获。这是一个例外吗？我似乎不明白为什么这个异常没有被捕获。我试图找出答案，但 Antlr 网站似乎已经关闭了一段时间了。

我查看了以下内容：ANTLR 异常处理与“$”，Java https://stackoverflow.com/questions/7705845/antlr-exception-handling-with-java并遵循该示例，但是当 Lexer 通过添加 RuntimeException() 生成代码时，我得到无法访问的代码。

我不知道该怎么办。

当我尝试从解析器获取语法错误数时，它显示 0。

EDIT:

我找到了一个可行的解决方案：ANTLR 不会在无效输入时抛出错误 https://stackoverflow.com/questions/8658753/antlr-not-throwing-errors-on-invalid-input

但是，当我尝试取回异常消息时，它为空。我是否已正确设置所有内容？请参阅示例语法：

grammar i;

options {
output=AST;
}

@header {
package com.data;
}

@rulecatch {
    catch(RecognitionException e) {
        throw e;
   }
}

// by having these below it makes no difference
/**@parser::members {
    @Override
    public void reportError(RecognitionException e) {
        throw new RuntimeException("Exception : " + " " + e.getMessage());
    }
}

@lexer::members {
    @Override
    public void reportError(RecognitionException e) {
       throw new RuntimeException("Exception : " + " " + e.getMessage());
    }
}*/

EDIT:

请看看我到目前为止所拥有的：

grammar i;

options {
output=AST;
}

@header {
package com.data;
}

@rulecatch {
    // ANTLR does not generate its normal rule try/catch
    catch(RecognitionException e) {
        throw e;
    }
}

@parser::members {
    @Override
    public void displayRecognitionError(String[] tokenNames, RecognitionException e) {
        String hdr = getErrorHeader(e);
        String msg = getErrorMessage(e, tokenNames);
        throw new RuntimeException(hdr + ":" + msg);
    }
}

@lexer::members {
    @Override
    public void displayRecognitionError(String[] tokenNames, RecognitionException e) {
        String hdr = getErrorHeader(e);
        String msg = getErrorMessage(e, tokenNames);
        throw new RuntimeException(hdr + ":" + msg);
    }
}

operatorLogic   : 'AND' | 'OR';
value       : STRING;
query       : (select)*;
select      : 'SELECT'^ functions 'FROM table' filters?';';
operator    : '=' | '!=' | '<' | '>' | '<=' | '>=';
filters : 'WHERE'^ conditions;
members : STRING operator value;
conditions  : (members (operatorLogic members)*);
functions   : '*';
STRING  : ('a'..'z'|'A'..'Z')+;
WS      : (' '|'\t'|'\f'|'\n'|'\r')+ {skip();}; // handle white space between keywords

public class Processor {

public Processor() {

}

/**
 * This method builds the MQL Parser.
 * @param args the args.
 * @return the built IParser.
 */
private IParser buildMQLParser(String query) {
    CharStream cs = new ANTLRStringStream(query);
    // the input needs to be lexed
    ILexer lexer = new ILexer(cs);
          CommonTokenStream tokens = new CommonTokenStream();
    IParser parser = new IParser(tokens);
    tokens.setTokenSource(lexer);
    // use the ASTTreeAdaptor so that the grammar is aware to build tree in AST format
    parser.setTreeAdaptor((TreeAdaptor) new ASTTreeAdaptor().getASTTreeAdaptor());
return parser;
}

/**
 * This method parses the MQL query.
 * @param query the query.
 */
public void parseMQL(String query) {
    IParser parser = buildMQLParser(query);
    CommonTree commonTree = null;
    try {
                     commonTree = (CommonTree) parser.query().getTree();
                    }
    catch(Exception e) {
        System.out.println("Exception :" + " " + e.getMessage());
    }
}
}

public class ASTTreeAdaptor {

public ASTTreeAdaptor() {

}

/**
 * This method is used to create a TreeAdaptor.
 * @return a treeAdaptor.
 */
public Object getASTTreeAdaptor() {
    TreeAdaptor treeAdaptor = new CommonTreeAdaptor() {
        public Object create(Token payload) {
        return new CommonTree(payload);
        }
    };
    return treeAdaptor; 
}
}

所以当我输入以下内容时： 从表中选择 *

没有 ';'我得到 MismatchedTokenException：

catch(Exception e) {
     System.out.println("Exception : " + " " e);
}

当我尝试时：

e.getMessage();

它返回 null。

尝试覆盖displayRecognitionError反而：

@parser::members { 
   ...

    @Override    
    public void displayRecognitionError(String[] tokenNames, RecognitionException e) {
        String hdr = getErrorHeader(e);
        String msg = getErrorMessage(e, tokenNames);
        throw new RuntimeException(hdr + ":" + msg);
    }
    ...
}
//same code in @lexer::members

如果您想跟踪错误而不是中止，您可以创建一个处理程序接口来跟踪它们：

@parser::members { 
   ...
    private YourErrorTrackerInterface errorTracker;

    //getter/setter for errorTracker here        

    @Override    
    public void displayRecognitionError(String[] tokenNames, RecognitionException e) {
        String hdr = getErrorHeader(e);
        String msg = getErrorMessage(e, tokenNames);
        if (errorTracker != null){
          errorTracker.addError(e, tokenNames, hdr, msg);
        }
    }
    ...
}
//same code in @lexer::members

然后错误跟踪器可以决定是抛出异常还是继续。

上面的代码允许您跟踪“可恢复”错误，ANTLR 可以跳过的错误。仍然有一些场景会产生不可恢复的错误，例如SELECT * FROM table（没有结局;）。在这种情况下，您必须捕获异常parseMQL或者那里附近的某个地方。 （您可以尝试编写自己的恢复代码，但我不建议您这样做。）

这是修改后的parseMQL显示两种不同类型的解析错误。请注意，我删除了对getMessage因为并非所有异常都源自RecognitionException填入。

public void parseMQL(String query) {
    iParser parser = buildMQLParser(query);
    CommonTree commonTree = null;
    try {
        commonTree = (CommonTree) parser.query().getTree();
    } catch (MismatchedTokenException e){
        //not production-quality code, just forming a useful message
        String expected = e.expecting == -1 ? "<EOF>" : iParser.tokenNames[e.expecting];
        String found = e.getUnexpectedType() == -1 ? "<EOF>" : iParser.tokenNames[e.getUnexpectedType()];

        System.out.println("Fatal mismatched token exception: expected " + expected + " but was " + found);   

    } catch (RecognitionException e) {
        System.out.println("Fatal recognition exception " + e.getClass().getName()
                + " : " + e);

    } catch (Exception e) {
        System.out.println("Other exception : " + e.getMessage());
    }
}

Input SELECT * FROM table产生消息“致命的不匹配令牌异常：预期';'但是”。这个异常是由ANTLR直接产生的。

Input SELECT FROM table;生成消息“其他异常：第 1:7 行：'FROM table' 处缺少 '*'”。这个异常是由上面的代码产生的。