如何设置 CMake 与 clang 交叉编译 Windows 上的 ARM 嵌入式系统？

我正在尝试生成 Ninja makefile 以使用 Clang 为 ARM Cortex A5 CPU 交叉编译 C++ 项目。我为 CMake 创建了一个工具链文件，但似乎存在错误或缺少一些我无法找到的东西。当使用下面的工具链文件调用 CMake 时，出现以下错误。

CMake命令：

cmake -DCMAKE_TOOLCHAIN_FILE="..\Src\Build\Toolchain-clang-arm.cmake" -GNinja ..\Src\

Output:

-- C 编译器标识为 Clang 7.0.0 CMake 错误，位于 C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCompilerId.cmake:802 （消息）：Clang 编译工具

“C:/Program Files/LLVM/bin/clang.exe”

以 MSVC ABI 为目标，但具有类似 GNU 的命令行界面。 不支持此操作。使用 'clang-cl' 代替，例如通过设置 环境中的“CC=clang-cl”。此外，使用 MSVC 命令行环境。调用堆栈（首先是最近的调用）：
C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCCompiler.cmake:113 （CMAKE_DIAGNOSE_UNSUPPORTED_CLANG）CMakeLists.txt：2（项目）

-- 配置不完整，出现错误！

CMake 工具链文件（工具链-clang-arm.cmake）：

set(CMAKE_CROSSCOMPILING TRUE)
SET(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR arm)

# Clang target triple
SET(TARGET armv7-none-eabi)

# specify the cross compiler
SET(CMAKE_C_COMPILER_TARGET ${TARGET})
SET(CMAKE_C_COMPILER clang)
SET(CMAKE_CXX_COMPILER_TARGET ${TARGET})
SET(CMAKE_CXX_COMPILER clang++)
SET(CMAKE_ASM_COMPILER_TARGET ${TARGET})
SET(CMAKE_ASM_COMPILER clang)

# C/C++ toolchain
SET(TOOLCHAIN "C:/Program Files (x86)/GNU Tools ARM Embedded/7 2018-q2-update")
SET(CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})
SET(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})

# specify compiler flags
SET(ARCH_FLAGS "-target armv7-none-eabi -mcpu=cortex-a5")
SET(CMAKE_C_FLAGS "-Wall -Wextra ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
SET(CMAKE_CXX_FLAGS "-Wall -Wextra -std=c++11 -fno-exceptions -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")

我用的是CMake https://cmake.org/cmake/help/latest/manual/cmake-toolchains.7.html#cross-compiling-using-clang and Clang https://clang.llvm.org/docs/CrossCompilation.html文档和一些随机链接 https://gist.github.com/vpetrigo/29e3bfbe7d4aa133e4f661c8420af172从网上创建工具链文件。整个项目可以使用适用于 Windows 的 ARM GCC 进行良好的编译，因此工具链文件似乎是拼图中唯一缺失的部分。

EDIT

我尝试通过强制编译器来解决 CMake 编译器检查。我将这些行替换为 SET(CMAKE_C_COMPILER clang)、SET(CMAKE_CXX_COMPILER clang++) 等：

CMAKE_FORCE_C_COMPILER(clang Clang)
CMAKE_FORCE_CXX_COMPILER(clang++ Clang)

错误保持不变。

EDIT

我可以使用 clang -target arm-none-eabi 成功编译 hello world 示例。所以问题似乎出在 CMake 中。我创建了一个bug https://gitlab.kitware.com/cmake/cmake/issues/18880在 CMake 问题跟踪器中。

工具版本：

• clang 版本 7.0.0 (tags/RELEASE_700/final)
• cmake 版本 3.13.4

我的问题已通过reply https://gitlab.kitware.com/cmake/cmake/issues/18880到我的错误报告中，但我在此处添加了答案，以便将所有信息集中在一处以供将来参考。

简而言之：如果您从以下位置安装 Clang，CMake 目前不支持使用 clang/clang++ 命令行界面llvm.org http://releases.llvm.org/download.html。如果你想使用 clang/clang++ 接口（这是 ARM 交叉编译所必需的），你必须通过以下方式安装 Clangmsys2 https://www.msys2.org/.

详细

Windows 上的 Clang 有两种不同的命令行界面：

• 铿锵/铿锵++ https://clang.llvm.org/docs/UsersManual.html#command-line-options尝试与 GCC gcc/g++ 兼容并针对 GNU ABI 的默认接口
• clang-cl https://clang.llvm.org/docs/UsersManual.html#clang-cl尝试与 Microsoft 的 Visual C++ 编译器 cl.exe 兼容并针对 MSVC ABI

为了针对 ARM 进行交叉编译，您需要 clang/clang++ 接口。问题是 CMake 支持不同的接口，具体取决于您安装 Clang 的方式（请参阅bug https://gitlab.kitware.com/cmake/cmake/issues/18880在 CMake 问题跟踪器中了解更多详细信息）：

• 如果您从以下位置安装 Clangllvm.org http://releases.llvm.org/download.htmlCMake 仅支持 clang-cl 接口。
• 如果你通过以下方式安装 Clangmsys2 https://www.msys2.org/CMake 支持 clang/clang++ 接口。

所以这就是我所做的：

1. Install msys2 https://www.msys2.org/
2. 安装 Clang 和 CMakepacman https://github.com/msys2/msys2/wiki/Using-packages。 msys2中有两个clang包，一个是mingw32版本，一个是mingw64版本。我使用了 mingw64 包（mingw-w64-x86_64-clang）。
3. 启动 mingw64 shell 并运行 CMake 并从那里构建。

工具链文件

我的原始工具链文件有两个问题，花了我很长时间才修复。所以我希望这能节省其他人一些时间：

1. The 目标三重 https://clang.llvm.org/docs/CrossCompilation.html#target-triple（例如arm-none-eabi）需要匹配GCC binutils的前缀exactly。我的 binutils 的前缀是arm-none-eabi（例如arm-none-eabi-ar），所以我必须相应地更改目标三元组。
2. CMAKE_TRY_COMPILE_TARGET_TYPE https://cmake.org/cmake/help/v3.6/variable/CMAKE_TRY_COMPILE_TARGET_TYPE.html需要更改为 STATIC_LIBRARY 以防止 CMake 在编译检查期间运行链接器。

这是我使用的最终工具链文件（您还可以在此处找到工具链文件的一个很好的示例）GitHub 仓库 https://github.com/vpetrigo/arm-cmake-toolchains/blob/master/clang-arm-gcc-toolchain.cmake):

cmake_minimum_required(VERSION 3.13)

set(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR ARM)

if(DEFINED ENV{GCC_ARM_TOOLCHAIN})
    set(GCC_ARM_TOOLCHAIN $ENV{GCC_ARM_TOOLCHAIN})
else()
    set(GCC_ARM_TOOLCHAIN "C:/Users/user/tools/gcc-arm-none-eabi-7-2018-q2-update-win32")
endif()

LIST(APPEND CMAKE_PROGRAM_PATH ${GCC_ARM_TOOLCHAIN})

# Specify the cross compiler
# The target triple needs to match the prefix of the binutils exactly
# (e.g. CMake looks for arm-none-eabi-ar)
set(CLANG_TARGET_TRIPLE arm-none-eabi)
set(GCC_ARM_TOOLCHAIN_PREFIX ${CLANG_CLANG_TARGET_TRIPLE})
set(CMAKE_C_COMPILER clang)
set(CMAKE_C_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_CXX_COMPILER clang++)
set(CMAKE_CXX_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_ASM_COMPILER clang)
set(CMAKE_ASM_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})

# Don't run the linker on compiler check
set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)

# Specify compiler flags
set(ARCH_FLAGS "-mcpu=cortex-a5 -mthumb -mfpu=neon-vfpv4 -mfloat-abi=hard -mno-unaligned-access")
set(CMAKE_C_FLAGS "-Wall ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
set(CMAKE_CXX_FLAGS "-Wall -std=c++17 -fno-exceptions -fno-rtti -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")
set(CMAKE_ASM_FLAGS "-Wall ${ARCH_FLAGS} -x assembler-with-cpp" CACHE STRING "Common flags for assembler")
set(CMAKE_EXE_LINKER_FLAGS "-nostartfiles -Wl,-Map,kernel.map,--gc-sections -fuse-linker-plugin -Wl,--use-blx --specs=nano.specs --specs=nosys.specs" CACHE STRING "")

# C/C++ toolchain
set(GCC_ARM_SYSROOT "${GCC_ARM_TOOLCHAIN}/${GCC_ARM_TOOLCHAIN_PREFIX}")
# set(CMAKE_SYSROOT ${GCC_ARM_SYSROOT})
set(CMAKE_FIND_ROOT_PATH ${GCC_ARM_SYSROOT})

# Search for programs in the build host directories
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
# For libraries and headers in the target directories
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)