Async.StartChild是否存在内存泄漏？

当我运行以下测试（使用 F#2.0 构建）时，我得到 OutOfMemoryException。在我的系统上大约需要 5 分钟才能达到异常（如果它作为 x86 进程运行，则为 i7-920 6gb ram），但无论如何我们都可以在任务管理器中看到内存如何增长。

module start_child_test
    open System
    open System.Diagnostics
    open System.Threading
    open System.Threading.Tasks

    let cnt = ref 0
    let sw = Stopwatch.StartNew()
    Async.RunSynchronously(async{
        while true do
            let! x = Async.StartChild(async{
                if (Interlocked.Increment(cnt) % 100000) = 0 then
                    if sw.ElapsedMilliseconds > 0L then
                        printfn "ops per sec = %d" (100000L*1000L / sw.ElapsedMilliseconds)
                    else
                        printfn "ops per sec = INF"
                    sw.Restart()
                    GC.Collect()
            })
            do! x
    })

    printfn "done...."

我认为这段代码没有任何问题，也没有看到内存增长的任何原因。我做了替代实现以确保我的论点有效：

module start_child_fix
    open System
    open System.Collections
    open System.Collections.Generic
    open System.Threading
    open System.Threading.Tasks


    type IAsyncCallbacks<'T> = interface
        abstract member OnSuccess: result:'T -> unit
        abstract member OnError: error:Exception -> unit
        abstract member OnCancel: error:OperationCanceledException -> unit
    end

    type internal AsyncResult<'T> = 
        | Succeeded of 'T
        | Failed of Exception
        | Canceled of OperationCanceledException

    type internal AsyncGate<'T> = 
        | Completed of AsyncResult<'T>
        | Subscribed of IAsyncCallbacks<'T>
        | Started
        | Notified

    type Async with
        static member StartChildEx (comp:Async<'TRes>) = async{
            let! ct = Async.CancellationToken

            let gate = ref AsyncGate.Started
            let CompleteWith(result:AsyncResult<'T>, callbacks:IAsyncCallbacks<'T>) =
                if Interlocked.Exchange(gate, Notified) <> Notified then
                    match result with
                        | Succeeded v -> callbacks.OnSuccess(v)
                        | Failed e -> callbacks.OnError(e)
                        | Canceled e -> callbacks.OnCancel(e)

            let ProcessResults (result:AsyncResult<'TRes>) =
                let t = Interlocked.CompareExchange<AsyncGate<'TRes>>(gate, AsyncGate.Completed(result), AsyncGate.Started)
                match t with
                | Subscribed callbacks -> 
                    CompleteWith(result, callbacks)
                | _ -> ()
            let Subscribe (success, error, cancel) = 
                let callbacks = {
                    new IAsyncCallbacks<'TRes> with
                        member this.OnSuccess v = success v
                        member this.OnError e = error e
                        member this.OnCancel e = cancel e
                }
                let t = Interlocked.CompareExchange<AsyncGate<'TRes>>(gate, AsyncGate.Subscribed(callbacks), AsyncGate.Started)
                match t with
                | AsyncGate.Completed result -> 
                    CompleteWith(result, callbacks)
                | _ -> ()

            Async.StartWithContinuations(
                computation = comp,
                continuation = (fun v -> ProcessResults(AsyncResult.Succeeded(v))),
                exceptionContinuation = (fun e -> ProcessResults(AsyncResult.Failed(e))),
                cancellationContinuation = (fun e -> ProcessResults(AsyncResult.Canceled(e))),
                cancellationToken = ct
            )
            return Async.FromContinuations( fun (success, error, cancel) ->
                Subscribe(success, error, cancel)
            )
        }

对于此测试，它运行良好，没有任何显着的内存消耗。不幸的是，我在 F# 方面经验不多，并且怀疑我是否错过了一些东西。如果是错误，我如何向 F# 团队报告？

我认为你是对的 - 执行中似乎存在内存泄漏StartChild.

我做了一些分析（遵循Dave Thomas 的精彩教程 http://moiraesoftware.com/blog/2011/12/11/fixing-a-hole/）和开源 F# 版本 https://github.com/fsharp/fsharp/blob/master/src/fsharp/FSharp.Core/control.fs我想我什至知道如何解决这个问题。如果你看一下实施StartChild，它使用工作流的当前取消令牌注册一个处理程序：

let _reg = ct.Register(
    (fun _ -> 
        match !ctsRef with
        |   null -> ()
        |   otherwise -> otherwise.Cancel()), null)

在堆中保持活动状态的对象是该注册函数的实例。他们可以通过致电取消注册_reg.Dispose()，但这在 F# 源代码中从未发生过。我尝试添加_reg.Dispose()异步完成时调用的函数：

(fun res -> _reg.Dispose(); ctsRef := null; resultCell.RegisterResult (Ok res, reuseThread=true))   
(fun err -> _reg.Dispose(); ctsRef := null; resultCell.RegisterResult (Error err,reuseThread=true))   
(fun err -> _reg.Dispose(); ctsRef := null; resultCell.RegisterResult (Canceled err,reuseThread=true))

...根据我的实验，这解决了问题。因此，如果您想要解决方法，您可以从以下位置复制所有必需的代码control.fs并将其添加为修复。

我将向 F# 团队发送错误报告，并附上您的问题的链接。如果您发现其他问题，可以通过将错误报告发送至fsbugs at microsoft dot com.