在 SPSS 中生成语法的语法

我正在尝试构建一个语法来在 SPSS 中生成语法，但我遇到了一些问题...... 我有一个包含元数据的 Excel 文件，我想使用它来创建一个语法来从中提取信息（就像这样，如果我有一个巨大的数据库，我只需要保持 Excel 更新 - 添加/删除变量，等等 - 然后运行语法来提取新语法所需的信息）。 我还注意到生成的语法始终在 15Mb 左右，这很大（适用于超过 500 行）！ 由于不同计算机和/或配置中的运行语法，我不使用 Python。 有任何想法吗？谁能帮帮我吗？ 先感谢您。

Example:
（test.xlsx – 表 1）
Var 代码标签列表 Var_label（连接 Var+Label）
V1 3 性别 1 V1“性别”
V2 1 工作 2 V2“工作”
V3 3 国家 3 V3 “国家”
V4 1 已婚 2 V4 “已婚”
V5 1 儿童 2 V5“儿童”
V6 2 满足1 4 V6“满足1”
V7 2 满足2 4 V7“满足2”

（来自其他文件的信息）
列表 = 1
1 “男”
2 “女”
列表 = 2
1 “Yes”
2 “No”
列表 = 3
1“欧洲”
2 “美国”
3“亚洲”
4“非洲”
5“大洋洲”
列表 = 4
1 “非常不满意”
10 “非常满意”

我想创建一个语法来生成新的语法来应用“变量标签”和“值标签”。所以，我想到了这样的事情：

GET DATA
/TYPE=XLSX
/FILE="test.xlsx"
/SHEET=name 'sheet 1'
/CELLRANGE=FULL
/READNAMES=ON
/DATATYPEMIN PERCENTAGE=95.0.
EXECUTE.

STRING vlb (A15) labels (A150) value (A12) lab (A1500) point (A2) separate (A50) space (A2) list1 (A100) list2 (A100).

SELECT IF (Code=1).
COMPUTE vlb = "VARIABLE LABELS".
COMPUTE labels = CONCAT (RTRIM(Var_label)," ").
COMPUTE point = ".".
COMPUTE value = "VALUE LABELS".
COMPUTE lab = CONCAT (RTRIM(Var)," ").
COMPUTE list1 = '1 " Yes "'.
COMPUTE list2 = '2 "No".'.
COMPUTE space = " ".
COMPUTE separate="************************************************.".

WRITE OUTFILE = "list_01.sps" / vlb.
WRITE OUTFILE = "list_01.sps" /labels.
WRITE OUTFILE = "list_01.sps" /point.
WRITE OUTFILE = "list_01.sps" /value.
WRITE OUTFILE = "list_01.sps" /lab.
WRITE OUTFILE = "list_01.sps" /list1.
WRITE OUTFILE = "list_01.sps" /list2.
WRITE OUTFILE = "list_01.sps" /space.
WRITE OUTFILE = "list_01.sps" /separate.
WRITE OUTFILE = "list_01.sps" /space.

如果只有一个变量具有相同的列表（例如：V1），则它可以正常工作。然而，如果有多个变量具有相同的列表，它会按照变量的数量重复生成代码（例如：V2、V4 和 V5）。

运行上面的代码后，我所拥有的（例如：V2、V4 和 V5）：

变量标签
V2“工作”
.
价值标签
V2
1 “是”
2“不”
******************************************************。
变量标签
V4《结婚了》
.
价值标签
V4
1 “是”
2“不”
******************************************************。
变量标签
V5“孩子们”
.
价值标签
V5
1 “是”
2“不”
******************************************************。

我想要什么：

变量标签
V2“工作”
V4《结婚了》
V5“孩子们”
.
价值标签
V2 V4 V5
1 “是”
2“不”

我认为可能有一些方法可以更好地自动化整个过程，包括使用第二个数据源。但对于这个问题的范围，我将建议一种方法来获得您具体要求的内容。

关键是为第一行和最后一行构建具有特殊条件的命令：

string cmd1 cmd2 (a200).
sort cases by code.
match files /file=* /first=first /last=last /by code. /* marking first and last lines.
do if first.
    compute cmd1="VARIABLE LABELS".
    compute cmd2="VALUE LABELS".
end if.
if not first cmd1=concat(rtrim(cmd1), " /"). /* "/" only appears from the second varname.
compute cmd1=concat(rtrim(cmd1), " ", Var_label).
compute cmd2=concat(rtrim(cmd2), " ", Var).
do if last.
    compute cmd1=concat(rtrim(cmd1), " .").
    compute cmd2=concat(rtrim(cmd2), " ", '  1 " Yes "  2 "No". ').
end if.
exe.

命令现在已准备就绪，但我们不想将它们混淆，因此我们将它们一层一层地堆叠起来，然后才将它们写出来：

add files /file=* /rename cmd1=cmd /file=* /rename cmd2=cmd.
exe.
WRITE OUTFILE = "var definitions.sps" / cmd .
exe.

EDIT:请注意，上面的代码假设您已经运行了select cases if code = ... 并且有一个code在所有剩余的行中。
另请注意，我添加了一个exe.命令在末尾 - 不运行新语法将显示为空。