用于创建计划任务的 VBScript

我正在尝试创建一个 VBScript，它创建一个批处理文件，然后创建一个计划任务来运行该批处理文件。到目前为止，我尝试过的所有操作都创建了批处理文件，但没有创建计划任务，并且我没有收到任何错误。这是我到目前为止所拥有的：

Option Explicit

Dim objFSO, outFile, wShell
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set outFile = objFSO.CreateTextFile("C:\test.bat", True)
outFile.WriteLine "Start www.google.com"
outFile.Close

Set wShell = CreateObject ("Wscript.Shell") 
wShell.Run "cmd SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN 'Test Task' /TR 'C:\test.bat' /ST 16:30", 0

我试过了""Test Task"" and ""C:\test.bat""，并得到相同的结果。但是当我在命令提示符下运行以下命令时：

SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN "Test Task" /TR "C:\test.bat" /ST 16:30

任务创建成功。

我尝试的另一种方法是创建 2 个批处理文件：一个用于打开网页的批处理文件，一个用于创建计划任务的批处理文件。然后我结束了运行task.bat文件在最后。这就是我为此所做的：

Option Explicit

Dim objFSO, outFile, wShell
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set outFile = objFSO.CreateTextFile("C:\test.bat", True)
outFile.WriteLine "Start www.google.com"
outFile.Close

Set outFile = objFSO.CreateTextFile("C:\task.bat", True)
outFile.WriteLine "SchTasks /Create /SC WEEKLY /D MON,TUE,WED,THU,FRI /TN ""Test Task"" /TR ""C:\test.bat"" /ST 16:30"

Set wShell = CreateObject ("Wscript.Shell") 
wShell.Run "cmd start ""C:\task.bat"""

这创建了批处理文件，但刚刚打开cmd最后什么也没做。

我的猜测是问题出在wShell.Run部分，但我的经验不够，不知道问题出在哪里。

我不知道从这里去哪里所以任何建议都会很棒。

作为 VBScript，您可以执行命令可以执行的任何操作。

以下是如何列出根文件夹中的计划任务。

Set TS = CreateObject("Schedule.Service")
TS.Connect("Serenity")

Set rootFolder = TS.GetFolder("\")

Set tasks = rootFolder.GetTasks(0)

If tasks.Count = 0 Then 
    Wscript.Echo "No tasks are registered."
Else
    WScript.Echo "Number of tasks registered: " & tasks.Count

    For Each Task In Tasks
    A=Task.Name
    A = A & " " & Task.NextRunTime
    A = A & " " & Task.LastTaskResult
    wscript.echo A
    Next
End If

这是来自文档 https://msdn.microsoft.com/en-us/library/windows/desktop/aa383665%28v=vs.85%29.aspx展示如何创建任务。

时间触发器示例（脚本）

此脚本示例演示如何创建在特定时间运行记事本的任务。该任务包含一个基于时间的触发器，指定激活任务的开始边界、运行记事本的可执行操作以及停用任务的结束边界。

以下过程描述如何安排任务以在特定时间启动可执行文件。

安排记事本在特定时间启动

1. 创建一个 TaskService 对象。该对象允许您在指定文件夹中创建任务。

2. 获取任务文件夹并创建任务。使用TaskService.GetFolder方法获取存储任务的文件夹和TaskService.NewTask方法来创建代表任务的 TaskDefinition 对象。

3. 使用以下命令定义有关任务的信息TaskDefinition目的。使用TaskDefinition.Settings属性来定义确定任务计划程序服务如何执行任务的设置以及TaskDefinition.RegistrationInfo属性来定义描述任务的信息。
4. 使用创建基于时间的触发器TaskDefinition.Triggers财产。此属性可让您访问TriggerCollection目的。使用TriggerCollection.Create方法（指定要创建的触发器类型）来创建基于时间的触发器。创建触发器时，设置触发器的开始边界和结束边界以激活和停用触发器。开始边界指定任务操作的执行时间。
5. 使用以下命令创建要执行的任务的操作TaskDefinition.Actions财产。此属性可让您访问ActionCollection目的。使用ActionCollection.Create方法来指定要创建的操作类型。这个例子使用了一个ExecAction对象，表示执行命令行操作的操作。
6. 使用注册任务TaskFolder.RegisterTaskDefinition方法。对于此示例，任务将在当前时间加上 30 秒启动记事本。

以下 VBScript 示例显示如何安排任务在注册任务 30 秒后执行记事本。

' This sample schedules a task to start notepad.exe 30 seconds
' from the time the task is registered.
'------------------------------------------------------------------

' A constant that specifies a time-based trigger.
const TriggerTypeTime = 1
' A constant that specifies an executable action.
const ActionTypeExec = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at a certain time"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a time-based trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeTime)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime

Dim time
time = DateAdd("s", 30, Now)  'start time = 30 seconds from now
startTime = XmlTime(time)

time = DateAdd("n", 5, Now) 'end time = 5 minutes from now
endTime = XmlTime(time)

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "TimeTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test TimeTrigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

'------------------------------------------------------------------
' Used to get the time for the trigger 
' startBoundary and endBoundary.
' Return the time in the correct format: 
' YYYY-MM-DDTHH:MM:SS. 
'------------------------------------------------------------------
Function XmlTime(t)
    Dim cSecond, cMinute, CHour, cDay, cMonth, cYear
    Dim tTime, tDate

    cSecond = "0" & Second(t)
    cMinute = "0" & Minute(t)
    cHour = "0" & Hour(t)
    cDay = "0" & Day(t)
    cMonth = "0" & Month(t)
    cYear = Year(t)

    tTime = Right(cHour, 2) & ":" & Right(cMinute, 2) & _
        ":" & Right(cSecond, 2)
    tDate = cYear & "-" & Right(cMonth, 2) & "-" & Right(cDay, 2)
    XmlTime = tDate & "T" & tTime 
End Function