使用 ANTLR4 识别单行中的多行注释

我想用 ANTLR4 解析 PostScript 代码。我完成了语法，但是一种特定的语言扩展（由其他人引入）很难被识别。

一个简短的例子：

1: % This is a line comment
2: % The next line just pushes the value 10 onto the stack
3: 10
4: 
5: %?description This is the special line-comment in question
6: /procedure {
7:   /var1 30 def %This just creates a variable
8:   /var2 10 def %?description A description associated with var2 %?default 20
9:   /var3 (a string value) def %?description I am even allowed to use % signs %?default (another value)
10: }

识别行注释，例如第 1、2 和 7 行，可以使用 Lexer-Rules 来完成

LINE_COMMENT: '%' .*? NEWLINE;
NEWLINE: '\r'? '\n';

它简单地匹配 % 之后直到行尾的所有内容。

我遇到的问题是那些特殊的行注释，它们以类似的内容开头%?description or %?default，因为这些也应该被识别，但与 LINE_COMMENT 相比，可以将多个这些放在一行中（例如第 8 行和第 9 行）。所以第 8 行包含两个特殊注释%?description A description associated with var2 and %?default 20.

把它想象成这样（尽管这行不通）：

SPECIAL_COMMENT: '%?' .*? (SPECIAL_COMMENT|NEWLINE);

现在是真正棘手的部分：应该允许您在后面添加任意文本%?description包括%同时仍然能够分割个人评论。

简而言之，问题可以简化为分割表格的一行

(%?<keyword> <content with % allowed in it>)+ NEWLINE

e.g.

%?description descr. with % in in %?default (my default value for 100%) %?rest more

into

1.) %?description descr. with % in in 
2.) %?default (my default value for 100%)
3.) %?rest more

有什么想法，如何制定词法分析器或解析器规则来实现这一目标？

考虑到这些规则，我认为您必须在词法分析器中使用谓词来检查输入流中是否出现%?。您还必须确保正常的评论必须以%，但后面没有?（或换行符）。

给定语法：

grammar T;

@lexer::members {
  boolean ahead(String text) {
    for (int i = 0; i < text.length(); i++) {
      if (text.charAt(i) != _input.LA(i + 1)) {
        return false;
      }
    }
    return true;
  }
}

parse
 : token* EOF
 ;

token
 : t=SPECIAL_COMMENT {System.out.println("special : " + $t.getText());}
 | t=COMMENT         {System.out.println("normal  : " + $t.getText());}
 ;

SPECIAL_COMMENT
 : '%?' ( {!ahead("%?")}? ~[\r\n] )*
 ;

COMMENT
 : '%' ( ~[?\r\n] ~[\r\n]* )?
 ;

SPACES
 : [ \t\r\n]+ -> skip
 ;

可以按如下方式进行测试：

String source = "% normal comment\n" +
    "%?description I am even allowed to use % signs %?default (another value)\n" +
    "% another normal comment (without a line break!)";
TLexer lexer = new TLexer(new ANTLRInputStream(source));
TParser parser = new TParser(new CommonTokenStream(lexer));
parser.parse();

并将打印以下内容：

normal  : % normal comment
special : %?description I am even allowed to use % signs 
special : %?default (another value)
normal  : % another normal comment (without a line break!)

那个部分( {!ahead("%?")}? ~[\r\n] )*可以读作如下：如果没有“%”呢？前面，匹配除\r and \n，并执行此操作零次或多次.