wikidata 获取带有项目标签和值的所有属性

我的问题是如何从 wikidata（最好是通过 SPARQL）提取在网页上呈现的所有属性及其各自的标签。

以Google https://www.wikidata.org/wiki/Q95维基数据上的条目。对于属性 P414（证券交易所）或 P159，有 P969（位于街道地址）等子属性。一旦你真正出现，他们就会出现 wbgetentities作为预选赛。问题在于wbgetentities是标签丢失了。我得到了所需的输出（例如wdt:P17 => country => United States of America）使用以下 SPARQL 查询：

SELECT ?prop_id ?prop_label ?prop_val_label WHERE {
  VALUES (?company) {
    (wd:Q95)
  }
  ?company ?prop_id ?company_item.
  ?wd wikibase:directClaim ?prop_id.
  ?wd rdfs:label ?prop_label.
  OPTIONAL {
    ?company_item rdfs:label ?prop_val.
    FILTER((LANG(?prop_val)) = "en")
  }
  BIND(COALESCE(?prop_val, ?companyItem) AS ?prop_val_label)
  FILTER((LANG(?prop_label)) = "en")
}

但这些“子财产”缺失，因为它们没有被直接主张。要提取单个语句限定符，我可以这样做：

SELECT ?company ?hq ?country WHERE {
  wd:Q95 p:P159 ?company.
  OPTIONAL {
    ?company ps:P159 ?hq.
    ?company pq:P17 ?country. 
  }
}

但问题是是否有一种方法可以将所有内容合并到一个查询中？

维基数据数据模型的有用链接：

• RDF 转储格式 https://www.mediawiki.org/wiki/Wikibase/Indexing/RDF_Dump_Format
• 维基数据限定词、参考文献和排名 https://en.wikibooks.org/wiki/SPARQL/WIKIDATA_Qualifiers,_References_and_Ranks
• 帮助:预选赛 https://www.wikidata.org/wiki/Help:Qualifiers

您的查询应该是这样的：

SELECT ?wdLabel ?ps_Label ?wdpqLabel ?pq_Label {
  VALUES (?company) {(wd:Q95)}

  ?company ?p ?statement .
  ?statement ?ps ?ps_ .

  ?wd wikibase:claim ?p.
  ?wd wikibase:statementProperty ?ps.

  OPTIONAL {
  ?statement ?pq ?pq_ .
  ?wdpq wikibase:qualifier ?pq .
  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} ORDER BY ?wd ?statement ?ps_

Try it! https://query.wikidata.org/#SELECT%20%3FwdLabel%20%3Fps_Label%20%3FwdpqLabel%20%3Fpq_Label%20%7B%0A%20%20VALUES%20(%3Fcompany)%20%7B(wd%3AQ95)%7D%0A%20%20%0A%20%20%3Fcompany%20%3Fp%20%3Fstatement%20.%0A%20%20%3Fstatement%20%3Fps%20%3Fps_%20.%0A%20%20%0A%20%20%3Fwd%20wikibase%3Aclaim%20%3Fp.%0A%20%20%3Fwd%20wikibase%3AstatementProperty%20%3Fps.%0A%20%20%0A%20%20OPTIONAL%20%7B%0A%20%20%3Fstatement%20%3Fpq%20%3Fpq_%20.%0A%20%20%3Fwdpq%20wikibase%3Aqualifier%20%3Fpq%20.%0A%20%20%7D%0A%20%20%0A%20%20SERVICE%20wikibase%3Alabel%20%7B%20bd%3AserviceParam%20wikibase%3Alanguage%20%22en%22%20%7D%0A%7D%20ORDER%20BY%20%3Fwd%20%3Fstatement%20%3Fps_

结果中仅包含限定符及其值。既不包含出处引用，也不包含值注释（例如时间精度）。如果您需要添加，请写评论。