程序员经验分享-hwhale

Kanzi Shader入门

2023-10-29

1. 版本

kanzi默认支持Opengl ES 2.0，在qnx平台可以支持到ES 3.0

2. 着色器

在这里插入图片描述
kanzi只支持【顶点着色器】和【片段着色器】

3. kanzi studio

无法直接使用shader，需要通过画刷和材质间接使用
在这里插入图片描述

  • 在【普通节点】上设置背景画刷-【材质画刷】
  • 在【材质画刷】上设置材质-【材质】
  • 在【材质】上设置材质类型-【材质类型】
  • 【材质类型】里有顶点和片段着色器
    在这里插入图片描述

4. shader内容

参考：shader系列教程 - shader tutorial series
在这里插入图片描述
kzPosition等是kanzi自动映射好的，本质是节点的4个顶点等

修改颜色

在这里插入图片描述

修改透明度
需要先设置【混合模式】

  • 【材质类型】提供了【混合模式】Input
  • 【材质】里设置为Mixed
    在这里插入图片描述

4分之一圆

在这里插入图片描述
另一种实现方法


precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

float circleshape(vec2 position, float radius)
{
    return step(radius, length(position));
}

void main()
{
    vec2 position = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    float circle = circleshape(position, 0.5);
    
    color = vec3(circle);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

中心全圆

在这里插入图片描述
另一种实现方法


precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

float circleshape(vec2 position, float radius)
{
    return step(radius, length(position-0.5));
}

void main()
{
    vec2 position = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    float circle = circleshape(position, 0.2);
    
    color = vec3(circle);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

方形


precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

float rectshape(vec2 position, vec2 scale)
{
    scale = vec2(0.5) - scale * 0.5;
    vec2 shaper = vec2(step(scale.x, position.x), step(scale.y, position.y));
    shaper *= vec2(step(scale.x, 1.0 - position.x), step(scale.y, 1.0 - position.y));
    return shaper.x * shaper.y;
}

void main()
{
    vec2 position = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    float rectangle = rectshape(position, vec2(0.3, 0.3));
    
    color = vec3(rectangle);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

多边形


precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

const float PI = 3.1415926535;

float polygonshape(vec2 position, float radius, float sides)
{
    position = position * 2.0 - 1.0;
    float angle = atan(position.x, position.y);
    float slice = PI * 2.0 / sides;
    
    return step(radius, cos(floor(0.5 + angle / slice) * slice - angle) * length(position));
}

void main()
{
    vec2 position = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    float polygon = polygonshape(position, 0.5, 6.0);
    
    color = vec3(polygon);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

位移

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

float circleshape(vec2 position, float radius)
{
    return step(radius, length(position-0.5));
}

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    vec2 translate = vec2(1.0, -1.0);
    coord += translate * 0.5;
    
    float circle = circleshape(coord, 0.2);
    
    color = vec3(circle);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

正弦余弦

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;

float circleshape(vec2 position, float radius)
{
    return step(radius, length(position-0.5));
}

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    vec2 translate = vec2(sin(u_time / 10.0), cos(u_time));
    coord += translate * 0.5;
    
    float circle = circleshape(coord, 0.2);
    
    color = vec3(circle);
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

缩放

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;

mat2 scale(vec2 scale)
{
    return mat2(scale.x, 0.0, 0.0, scale.y);
}

float circleshape(vec2 position, float radius)
{
    return step(radius, length(position-0.5));
}

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    coord -= vec2(0.5);
    coord = scale(vec2(2.0 + sin(u_time), 2.0 + sin(u_time))) * coord;
    coord += vec2(0.5);
    
    float circle = circleshape(coord, 0.5);
    
    color = vec3(circle);
    
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

旋转

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;

float rectshape(vec2 position, vec2 scale)
{
    scale = vec2(0.5) - scale * 0.5;
    vec2 shaper = vec2(step(scale.x, position.x), step(scale.y, position.y));
    shaper *= vec2(step(scale.x, 1.0 - position.x), step(scale.y, 1.0 - position.y));
    return shaper.x * shaper.y;
}

mat2 rotate(float angle){
    return mat2(cos(angle), -sin(angle), sin(angle), cos(angle));
}

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    coord -= vec2(0.5);
    coord = rotate(sin(u_time)) * coord;
    coord += vec2(0.5);
    
    float rectangle = rectshape(coord, vec2(0.3, 0.3));
    
    color = vec3(rectangle);
    
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

warp grid

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;


void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);
    
    color += sin(coord.x * cos(u_time / 60.0) * 60.0) + sin(coord.y * cos(u_time / 60.0) * 10.0);
    color += cos(coord.y * sin(u_time / 30.0) * 10.0) + cos(coord.x * sin(u_time / 20.0) * 10.0);
    
    color += sin(u_time / 10.0) * 0.5;
    
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

water color

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;


void main()
{
    vec2 coord = 6.0 * vTexCoord;
    
    vec3 color = vec3(0.0);
    
    for(int n = 1; n < 8; n++){
        float i = float(n);
        coord += vec2(0.7 / i * sin(i * coord.y + u_time + 0.3*i) + 0.8, 0.4 / i * sin(coord.x + u_time + 0.3 * i) + 1.6);
    
    }  
    
    //coord *= vec2(0.7 / sin(coord.y + u_time + 0.3) + 0.8, 0.4 / sin(coord.x + u_time + 0.3) + 1.6);
    
    
    color = vec3(0.5 * sin(coord.x) + 0.5, 0.5 * sin(coord.y) + 0.5, sin(coord.x + coord.y));
    
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

water color2

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;

const int AMOUNT = 12;


void main()
{
    vec2 coord = 20.0 * (vTexCoord - 0.5);
    
    vec3 color = vec3(0.0);
    
    float len;
    
    for(int i = 0; i < AMOUNT; i++){
        len = length(vec2(coord.x, coord.y));
        coord.x = coord.x - cos(coord.y + sin(len)) + cos(u_time / 9.0);
        coord.y = coord.y - sin(coord.x + cos(len)) + sin(u_time / 12.0);
    }
    
    //coord *= vec2(0.7 / sin(coord.y + u_time + 0.3) + 0.8, 0.4 / sin(coord.x + u_time + 0.3) + 1.6);
    
    
    color = vec3(0.5 * sin(coord.x) + 0.5, 0.5 * sin(coord.y) + 0.5, sin(coord.x + coord.y));
    
    gl_FragColor = vec4(cos(len * 2.0), cos(len * 3.0), cos(len * 1.0), 1.0);
}

请添加图片描述

warp line

precision mediump float;

varying mediump vec2 vTexCoord;

uniform mediump vec2 u_resolution;

uniform float u_time;

void main()
{
    vec2 coord = vTexCoord;
    
    float color = 0.0;
    
    color += sin(coord.x * 50.0 + cos(u_time + coord.y * 10.0 + sin(coord.x * 50.0 + u_time * 2.0))) * 2.0;
    color += cos(coord.x * 20.0 + sin(u_time + coord.y * 10.0 + cos(coord.x * 50.0 + u_time * 2.0))) * 2.0;
    color += sin(coord.x * 30.0 + cos(u_time + coord.y * 10.0 + sin(coord.x * 50.0 + u_time * 2.0))) * 2.0;
    color += cos(coord.x * 10.0 + sin(u_time + coord.y * 10.0 + cos(coord.x * 50.0 + u_time * 2.0))) * 2.0;
    
    gl_FragColor = vec4(color + coord.x, color + coord.y, color, 1.0);
}

请添加图片描述

wave draw lines

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    vec2 coord = vTexCoord;
    
    float color = 0.0;
    
    color += sin(coord.x * 6.0 + sin(u_time + coord.y * 90.0 + cos(coord.x * 30.0 + u_time * 2.0))) * 0.5;
 
    gl_FragColor = vec4(color + coord.x, color + coord.x, color, 1.0);
}

请添加图片描述

正态分布

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

// x [-5.0~5.0]
float gaussian(float x, float mean, float stddev) {
    const float pi = 3.14159265358979323846; // 定义pi常量
    // 计算高斯分布的概率密度函数
    return exp(-1.0 * pow(x - mean, 2.0) / (2.0 * pow(stddev, 2.0))) / sqrt(2.0 * pi * pow(stddev, 2.0));
}

float getK(float index, float size)
{
    float k = index / size;
    k = gaussian(k * 20.0 * 0.5-5.0, 0.0, 1.0) / 2.0; 
    return k;
}

void main()
{
    float range = 50.0;
    vec2 coord = range * vTexCoord;
    
    float color = 0.0;  
   // for(float i=0.0;i<coord.x;i++){
        color = getK(coord.x+sin(u_time)*10.0, range);
        color = step(color, vTexCoord.y);
  //  }
   
    gl_FragColor = vec4(color, color, color, 1.0);
}

请添加图片描述

修改方差的效果

float getK(float index, float size)
{
    float k = index / size;
    k = gaussian(k * 20.0 * 0.5-5.0, 0.0, 1.0+sin(u_time) / 2.0) / 2.0; 
    return k;
}

请添 加图片描述

请添加图片描述

rainbow swirl 彩虹漩涡

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(0.0);  
    float angle = atan(-coord.y + 0.5, coord.x - 0.5) * 0.1;
    float len = length(coord - vec2(0.5, 0.5));
    
    color.r += sin(len * 40.0 + angle * 40.0 + u_time * 1.0);
    color.g += cos(len * 30.0 + angle * 60.0 - u_time * 1.0);
    color.b += sin(len * 50.0 + angle * 50.0 + 6.0);
   
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

scanning lines 扫描线

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    vec2 coord = vTexCoord;
    
    vec3 color = vec3(1.0);  
    float size = 12.0;
    
    float alpha = sin(floor(coord.x * size) + u_time * 4.0) + 1.0 / 2.0;
   
    gl_FragColor = vec4(color, alpha);
}

请添加图片描述

moving light

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    vec2 coord = vTexCoord;
    
    coord -= vec2(0.5);
    
    coord.x += sin(u_time) + cos(u_time * 2.1);
    coord.y += cos(u_time) + sin(u_time * 1.6);
    
    float color = 0.0;  
    
    color += 0.1 * (abs(sin(u_time)) + 0.1) / length(coord);
   
    gl_FragColor = vec4(vec3(color), 1.0);
}

请添加图片描述

circle of lights

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;
    
    vec3 color = vec3(0.0);  
    
    vec2 translate = vec2(-0.5, -0.5);
    coord += translate;
    
    for(int i=0;i<40;i++){
        float radius = 0.3;
        float rad = radians(360.0 / 20.0) * float(i);
        color += 0.003 / length(coord + vec2(radius * cos(rad), radius * sin(rad)));
    }
    
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

morping grid boxes

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

void main()
{
    float range = 50.0;
    vec2 coord = range * vTexCoord;
    
    vec3 color = vec3(0.0);  
    
    color += abs(cos(coord.x / 1.0) + sin(coord.y / 1.0) - cos(u_time));
    
    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

morph grid


precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

float random2d(vec2 coord){
    return fract(sin(dot(coord.xy, vec2(12.9898, 78.233))) * 43758.5453);
}

void main()
{
    float range = 20.0;
    vec2 coord = range * vTexCoord;
    coord -= u_time + vec2(sin(coord.y), cos(coord.x));
    
    vec3 color = vec3(0.0);  
    
    float rand01 = fract(random2d(floor(coord)) + u_time / 60.0);
    float rand02 = fract(random2d(floor(coord)) + u_time / 40.0);
    
    rand01 += -0.4 - length(fract(coord));
    
    gl_FragColor = vec4(rand01 * 4.0, rand02 * rand01 * 4.0, 0.0, 1.0);
}

请添加图片描述

circle color pulse 圆形彩色脉冲

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

float random2d(vec2 coord){
    return fract(sin(dot(coord.xy, vec2(12.9898, 78.233))) * 43758.5453);
}

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec3 color = vec3(0.0);  
    
    vec2 translate = vec2(-0.5);
    coord += translate;
    
    color.r += abs(0.1 + length(coord) - 0.6 * abs(sin(u_time * 1.9 / 12.0)));
    color.g += abs(0.1 + length(coord) - 0.6 * abs(sin(u_time * 1.6 / 4.0)));
    color.b += abs(0.1 + length(coord) - 0.6 * abs(sin(u_time * 1.3 / 9.0)));

    gl_FragColor = vec4(0.1 / color, 1.0);
}

请添加图片描述

noise 1d

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

float noise1d(float value){
    return cos(value + cos(value * 90.0) * 100.0) * 0.5 + 0.5;
}

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec3 color = vec3(0.0);  
    
    color.r += noise1d(u_time);

    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

image

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    coord.x += sin(u_time);    
  
    gl_FragColor = texture2D(u_tex0, coord);
}

请添加图片描述

image color

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec4 image = texture2D(u_tex0, coord);
    
    image.r += 0.3;
    image.b += sin(u_time);
  
    gl_FragColor = vec4(image);
}

请添加图片描述

image manipulate

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec4 image = texture2D(u_tex0, coord);
    
    image.r += sin(coord.x * 50.0);
    image.r += cos(coord.y * 50.0);
  
    gl_FragColor = vec4(image);
}

在这里插入图片描述

image color mix

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;
    
    vec3 color = vec3(1.0, 0.0, 1.0);

    vec4 image = texture2D(u_tex0, coord);
    
    color = mix(color, image.rgb, image.a);
  
    gl_FragColor = vec4(color, 1.0);
}

在这里插入图片描述

white noise

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

float random2d(vec2 coord){
    return fract(sin(dot(coord.xy, vec2(12.9898, 78.233))) * 43758.5453);
}

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec3 color = vec3(0.0);  
    
    float grain = 0.0;
  
    grain = random2d(vec2(sin(coord) / 999999.9) * u_time);
    
    color = vec3(grain);

    gl_FragColor = vec4(color, 1.0);
}

请添加图片描述

scan image

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec3 color = vec3(0.0);  
    
    vec4 image = texture2D(u_tex0, coord);
    
    image.a = sin(floor(coord.x * 3.0) - u_time * 9.0);

    gl_FragColor = image;
}

请添加图片描述

noise image

precision mediump float;

varying mediump vec2 vTexCoord;

uniform float u_time;

uniform sampler2D u_tex0;

float amount = 0.5;

float random2d(vec2 coord){
    return fract(sin(dot(coord.xy, vec2(12.9898, 78.233))) * 43758.5453);
}

void main()
{
    float range = 1.0;
    vec2 coord = range * vTexCoord;

    vec3 color = vec3(0.0);  
    
    vec4 image = texture2D(u_tex0, coord);
    
    float noise = (random2d(coord) - 0.5) * amount;
    
    image.r += noise;
    image.g += noise;
    image.b += noise;

    gl_FragColor = image;
}

在这里插入图片描述

本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)

kanzi

Kanzi Shader入门 的相关文章

  • opencv图像金字塔的介绍

    1 学习目标 掌握opencv图像金字塔的原理 学习内容 1 什么是图像金字塔 2 图像金字塔有什么用 3 图像金字塔实现方式 学习产出 1 什么是图像金字塔 图像金字塔 如图 1 所示 是一种以多分辨率来解释图像的结构 通过对原始图像进行

  • spring cloud eureka server界面自定义

    spring cloud eureka server注册中心的界面不太好看 想自定义 经查看源码发现 源码位于spring cloud netflix eureka server servers的首页由template eureka目录下的

  • 各版本Pytorch安装详解

    Pytorch安装教程 windows版本 conda安装 1 cuda9 0 python3 6 3 5 3 7 conda install pytorch c pytorch pip3 install torchvision 2 cud

  • Win10、Win11打开远程桌面连接方法

    目录 一 打开网络发现 二 打开远程桌面连接 一 打开网络发现 二 打开远程桌面连接 1 打开此电脑 右击 属性 2 相关链接处点解高级系统设置 3 远程协助和远程桌面处 均勾选允许远程协助连接这台计算机 4 点击选择用户 查看或添加远程用

  • flutter 权限和图片权限之前的冲突

    权限插件 permission handler 9 2 0 想调起相册和视频 这个插件只有Permission storage request 获取存储权限 问题是android 13的一些手机 系统设置没有存储权限 用了上面这个权限 三次

  • 三种常见加密算法MD5、对称加密，非对称加密

    1 MD5加密html MD5加密的特色 前端 不可逆运算python 对不一样的数据加密的结果是定长的32位字符 无论文件多大都同样 算法 对相同的数据加密 获得的结果是同样的 也就是复制 后端 抗修改性 信息 指纹 对原数据进行任何改动

  • 扫频的matlab及FPGA实现

    扫频原理 已知扫频表达式 s t e x p

  • Linux文件I/O实验报告

    实验代码下载地址 https download csdn net download Qingyuyuehua 16305028 任务1 在当前用户目录下创建数据文件student txt 文件的内部信息存储格式为Sname S Sdept

  • sqli-lab教程——Less-8 GET - Blind - Boolian Based - Single Quotes (布尔型单引号GET盲注)

    题目名字暴露一切 本来不想看的 又瞥到了 布尔型盲注 单引号 id 1回显 价格单引号不回显 构造一下验证是不是布尔型payload id 1 and 1 1 回显了 证明没跑了 那就一步一步来吧 和less5一样的 根据回显判断 可以通过

  • clion三角形运行键是灰的_能打游戏能编程，如何用吃灰机器，安装完整ChromeOS（支持安卓）...

    常看IT新闻的人 一定听说过基于Chrome浏览器的系统ChromeOS 作为云系统的先行者 它的优点非常多 1 轻量 系统简单 资源占用少 低配硬件也能流畅运行 2 现代 界面风格统一 触摸手势好用 手感不输MacOS 3 同步 扩展程序

  • windows启动Docker失败提示：waiting for docker daemon: context deadline exceeded

    报错提示如下图 解决方法 以管理员方式打开CMD 运行netsh winsock reset 后 重启电脑之后再次启动Docker就可以了 如果还是没有效果可以尝试以下解决方法 检查Docker服务是否已启动 在命令行中输入 service

  • 完美解决eclipse中文注释错位、缩进、被放大BUG

    完美解决eclipse中文注释错位 缩进 被放大BUG 1 常规操作 2 另辟蹊径 2 1 基本思路 字体融合法 2 2 操作步骤 2 2 1 软件准备 2 2 2 文件准备 2 2 3详细步骤 3 写在最后 1 常规操作 这个BUG有大量

  • C++数组

    C 支持数组数据结构 它可以存储一个固定大小的相同类型元素的顺序集合 数组是用来存储一系列数据 但它往往被认为是一系列相同类型的变量 一维数组 一维数组定义的三种方式 1 数据类型 数组名 数组长度 2 数据类型 数组名 数组长度 值1 值

  • 总经理、总裁、总监、首席执行官，谁最了不起？

    总经理 总裁 总监 首席执行官 谁最了不起 中国的 头衔贬值 日趋严重 在中国 近来突然发现身边多了很多只有数名员工的 总裁 或者只管记帐的 财务总监 当然 在中国想要办点儿事 依靠个人的权限与力量是很关键的 因此也造成了这种刻意显示 自己

  • 如何把Eclipse改成中文版

    一 打开浏览器 输入http www eclipse org babel downloads php 如图所示 Babel Language 开头的一栏下面就是各个eclise版本的语言包 此处以Indigo版为例 二 目标锁定 Babel

随机推荐

  • Python 录入学生信息 提示用户在控制台输入3个学生的信息，学生信息包含姓名、年龄

    需求 按照以下要求完成代码的编写 第一步 录入学生信息 1 提示用户在控制台输入3个学生的信息 学生信息包含姓名 年龄 2 要求 封装录入单个学生信息的函数 并返回学生的信息 第二步 展示学生列表信息 1 封装打印学生信息的函数 格式要求如

  • sql sever——创建数据库

    创建数据库 并且指定存储数据库的主数据文件和日志文件 USE master GO CREATE DATABASE BOOK ON PRIMARY 主数据文件组primary NAME book data 主数据文件逻辑文件名 FILENAM

  • 力扣练习题（数组中数据反转）

    力扣练习题 数组中数据反转 要求 int arr 12 23 34 45 56 67 78 89 90 变为 int arr 90 89 78 67 56 45 34 23 12 思路 1 定义一个数组用静态初始化完成元素的初始化 2 循环

  • 剑指 Offer 39. 数组中出现次数超过一半的数字--java解法和心得

    class Solution public int majorityElement int nums 给数组排序 Arrays sort nums 排序后所找的元素比在中间 return nums nums length 2 拓展解法 摩根

  • 线程中断标志位 interrupt()、interrupted()、isInterrupted() 的认识

    常见问题 首先你是怎么去关闭一个开启的线程 调用中断方法之后 线程就立即停止运行吗 带着这两个问题探讨一下 主要围绕着这三个方法讲述 interrupt interrupted isInterrupted 归类为中断 什么是中断标识位 首先

  • 在js中forEach中使用try catch捕获异常

    forEach跳出循环使用try catch 这是我们都知道的 但是今天使用的时候发现出了问题 一 forEach中使用try catch捕获异常 如下图 1 正常情况下try catch是可以捕获到throw里面的内容 并且不会报错 程序

  • 二进制部署K8S

    目录 一 环境准备 1 常见的k8s部署方式 2 关闭防火墙 3 关闭selinux 4 关闭swap 5 根据规划设置主机名 6 在master添加hosts 7 将桥接的IPv4流量传递到iptables的链 8 时间同步 二 部署et

  • wireshark工具使用心得

    抓http包 但是protocal全部为tcp 并且Info也没有解析为http 打开 Edit Preferences 选择Protocals 选择http 在 tcp ports 中加入http端口 抓包数据不完整 清除浏览器缓存 再抓

  • 判断机器IP是公网ip还是内网ip

    首先是恭喜开通blog 对于ip是否是公网ip 网上已经有很多文章进行了描述 但我每次都记不太住 总要查找一下才又清楚 因此决定在这里记录下来 方便以后查询 ip地址分为五类 E类为保留为今后使用 D类为组播地址 用于主机网络地址的就是A类

  • windows套接字I/0模型-IOCP完成端口模型

    在 Windows 网络编程中 IOCP Input Output Completion Port 是一种高性能的 I O 模型 可以使应用程序能够处理大量并发 I O 操作 IOCP 模型主要通过事件通知和回调函数来处理异步 I O 操作

  • 最长01交替子串（浪潮笔试题）

    题意 给一个只有0和1的字符串 允许反转一个连续区间 即0变成1 1变成0 求最长的01交替串多长 允许不连续 我最先想到的是动态规划解法 状态设计方面 首先一个串的状态会有以0结尾和以1结尾两种 然后题目中说允许反转一个连续区间 那么根据

  • 【JavaEE】_JavaScript(WebAPI)

    目录 1 DOM 1 1 DOM基本概念 1 2 DOM树 2 选中页面元素 2 1 querySelector 2 2 querySelectorAll 3 事件 3 1 基本概念 3 2 事件的三要素 3 3 示例 4 操作元素 4 1

  • vue3使用高德地图完成标注点聚合

  • Linux内核提权漏洞CVE-2023-32233复测及POC脚本

    近日 研究人员发现了Linux内核的NetFilter框架中的新漏洞 CVE 2023 32233 该漏洞可被本地用户用于将权限提升为root 并完全控制系统 问题的根源在于tfilter nf tables是如何处理批处理请求的 经过身份

  • C++引用（&）解析：引用的作用，什么时候使用引用，引用与指针的不同

    引用是什么 什么时候使用引用 做函数的参数 做函数的返回值 引用与指针的不同 引用是什么 引用是变量的别名 理论上不开辟新的空间 符号 是类型标识符的一部分 被引用的数据类型 变量名称 如下图中 变量a 与变量ra 指向同一块内存空间 由此

  • 使用python的tkinter模块制作一个计算器

    使用tkinter模块制作的一个简单的计算器 由于刚学这个模块 所以做的不是很好 截图 点击计算后算式区的值会改成结果 可自行在数字触发的函数中添加数字输入就进行计算回显的功能 代码如下 import tkinter as tk impor

  • Python学习笔记（十）：包、模块

    一 包 模块 Python中的包相当于文件夹 模块就是 py文件 不同包下有相同名称的模块时 为了区分 可在模块里加上 包名 模块名 路径 这个路径叫做命名空间 注 如果想让一个普通的文件夹变为包 则需要在这个文件夹内添加 init py文

  • 原子操作实现无锁栈

    atomic3 cpp 使用CAS操作实现一个无锁栈 include

  • Vulkan® A Specification Core And Extension::Vulkan文档核心部分和扩展部分对照与翻译说明

    2020 7 1 更 修改和完善某些描述 Vulkan版本 1 2 137 1 2 145 Vulkan文档分成两种 核心部分 核心部分 扩展部分 核心部分是必定要翻译的 对于扩展部分 本人并不是所有扩展都见过 所以对于扩展部分尽可能的翻译

  • Kanzi Shader入门

    1 版本 kanzi默认支持Opengl ES 2 0 在qnx平台可以支持到ES 3 0 2 着色器 kanzi只支持 顶点着色器 和 片段着色器 3 kanzi studio 无法直接使用shader 需要通过画刷和材质间接使用 在 普

热门标签