qmake的概念

qmake是用来为不同的平台的开发项目创建makefile的一个工具。qmake简化了makefile的生成，因此创建一个makefile只需要几行信息的文件。qmake可以供任何一个软件项目使用，而不用管他是不是使用Qt写成的，尽管它包含了为支持Qt开发所拥有的额外的特征。

项目(.pro)文件

一个项目文件是用来告诉qmake关于为这个应用程序创建makefile所需要的细节。例如，一个源文件和头文件的列表、任何应用程序特定配置。例如，一个必需链接的额外库或者一个额外的包含路径、都应该放到项目文件中。

使用Qt的时候，我们经常会对pro进行一系列繁琐的配置，为方便大家理解、查找，现将常用的配置进行整理。

配置

注释

以“#”开始，到这一行结束。
快捷键：Ctrl + /

CONFIG

指定编译器选项和项目配置，值由qmake内部识别并具有特殊意义。

以下配置值控制编译标志：

CONFIG += console （Windows用户）只有针对Windows平台才需要一行

CONFIG += console

其作用是告诉编译器要建立一个“控制台”应用，这种应用能够通过标准的输入/输出流与用户交互。如果使用的是 MS Dev studio，则这个设置与菜单选项 Project Properties->Configuration Properties->Linker->
System->Subsystem->Console 等价。如果没有这个选项，就不会看到发送给 qDebug()，stdout 或者 stderr 的消息。

当使用debug和release选项时(Windows下默认的)，该项目将被处理三次：一次生成一个”meta”Makefile，另外两次生成Makefile.Debug和Makefile.Release。

在后面的次数，build_pass和相应的debug或release添加到CONFIG选项。这使得它可以执行构建特定任务。

例如：

build_pass:CONFIG(debug, debug|release) {
    unix: TARGET = $$join(TARGET,,,_debug)
    else: TARGET = $$join(TARGET,,,d)
}

DEFINES

qmake添加这个变量的值作为编译器C预处理器宏(-D选项)。

例如：

DEFINES += USE_MY_STUFF
 
 
 
 

然后就可以在代码中使用：

#ifdef USE_MY_STUFF
    // TODO
#else
    // TODO
#endif
 
 
 
 

往往可以指定项目的特殊版本（比如：正式版、试用版）、对一些特殊功能模块（比如：加密狗）进行限制等。

DEPENDPATH

指定查看解决依赖关系的目录列表，当包含文件时使用。

例如：

DEPENDPATH += . forms include qrc sources
 
 
 
 

DESTDIR

指定在何处放置目标文件。

例如：

DESTDIR = ../../lib
 
 
 
 

FORMS

指定UI文件（参考： Qt Designer Manual）在编译前被uic处理。所有的构建这些UI文件所需的依赖、头文件和源文件都会自动被添加到项目中。

例如：

FORMS = mydialog.ui \
        mywidget.ui \
        myconfig.ui
 
 
 
 

HEADERS

指定项目中所有的头文件。

qmake会自动检测是头文件的类中是否需要moc，并增加适当的依赖关系和文件到项目中，来生成和链接moc文件。

例如：

HEADERS = myclass.h \
          login.h \
          mainwindow.h
 
 
 
 

INCLUDEPATH

指定编译项目时应该被搜索的#include目录。

例如：

INCLUDEPATH = c:/msdev/include d:/stl/include
 
 
 
 

如果路径包含空格，需要使用引号包含。

win32:INCLUDEPATH += "C:/mylibs/extra headers"
unix:INCLUDEPATH += "/home/user/extra headers"
 
 
 
 

LIBS

指定链接到项目中的库列表。如果使用Unix -l (library) 和 -L (library path) 标志，在Windows上qmake正确处理库（也就是说，将库的完整路径传递给链接器），库必须存在，qmake会寻找-l指定的库所在的目录。

例如：

win32:LIBS += c:/mylibs/math.lib
unix:LIBS += -L/usr/local/lib -lmath
 
 
 
 

如果路径包含空格，需要使用引号包含路径。

win32:LIBS += "C:/mylibs/extra libs/extra.lib"
unix:LIBS += "-L/home/user/extra libs" -lextra
 
 
 
 

MOC_DIR

指定来自moc的所有中间文件放置的目录（含Q_OBJECT宏的头文件转换成标准.h文件的存放目录）。

例如：

unix:MOC_DIR = ../myproject/tmp
win32:MOC_DIR = c:/myproject/tmp
 
 
 
 

OBJECTS_DIR

指定所有中间文件.o（.obj）放置的目录。

例如：

unix:OBJECTS_DIR = ../myproject/tmp
win32:OBJECTS_DIR = c:/myproject/tmp
 
 
 
 

QT

指定项目中使用Qt的模块。默认情况下，QT包含core和gui，以确保标准的GUI应用程序无需进一步的配置就可以构建。

如果想建立一个不包含Qt GUI模块的项目，可以使用“ -=”操作符。

下面一行将构建一个很小的Qt项目：

QT -= gui # 仅仅使用core模块
 
 
 
 

如果要创建一个界面，里面用到XML及网络相关的类，那么需要包含如下模块：

QT += core gui widgets xml network
 
 
 
 

如果你的项目是一个Qt Designer插件，使用值uiplugin指定项目构建成库，但特定的Qt Designer插件支持，请参考：Building and Installing the Plugin。

RCC_DIR

指定Qt资源编译器输出文件的目录（.qrc文件转换成qrc_*.h文件的存放目录）。

例如：

unix:RCC_DIR = ../myproject/resources
win32:RCC_DIR = c:/myproject/resources
 
 
 
 

RESOURCES

指定资源文件 (qrc) 的名称，参考：Qt之资源系统

例如：

RESOURCES += Resource/resource.qrc
 
 
 
 

RC_FILE

指定应用程序资源文件的名称。这个变量的值通常是由qmake或qmake.conf处理，很少需要进行修改。

例如：

RC_FILE += myapp.rc
 
 
 
 

RC_ICONS

仅适用于Windows，指定的图标应该包含在一个生成的.rc文件里。如果RC_FILE 和RES_FILE变量都没有设置这才可利用。

例如：

RC_ICONS = myapp.ico  
 
 
 
 

SOURCES

指定项目中所有源文件。

例如：

SOURCES = myclass.cpp \
          login.cpp \
          mainwindow.cpp
 
 
 
 

TARGET

指定目标文件的名称。默认情况下包含的项目文件的基本名称。

例如：

TEMPLATE = app
TARGET = myapp
SOURCES = main.cpp
 
 
 
 

上面项目会生成一个可执行文件，Windows下为myapp.exe，Unix下为myapp。

TEMPLATE

模板变量告诉qmake为这个应用程序生成哪种makefile。

可供使用的选项：

例如：

TEMPLATE = lib
SOURCES = main.cpp
TARGET = mylib
 
 
 
 

TRANSLATIONS

指定包含用户界面翻译文本的翻译(.ts)文件列表。

例如：

TRANSLATIONS += Resource/myapp_zh.ts \
                Resource/myapp_en.ts
 
 
 
 

UI_DIR

指定来自uic的所有中间文件放置的目录（.ui文件转化成ui_*.h文件的存放目录）。

例如：

unix:UI_DIR = ../myproject/ui
win32:UI_DIR = c:/myproject/ui
 
 
 
 

总结：

Qt程序的编译执行过程：(1) 创建.pro文件，(2) 由.pro文件生成Makefile文件，(3) Makefile中保存了编译器和链接器的参数选项，还表述了所有源文件之间的关系(源文件需要的特定的包含文件，可执行文件要求包含的目标文件模块及库等)，(4) 创建程序(make)，读取Makefile文件，然后激活编译器，汇编器，资源编译器和链接器等以便产生最后的输出，最后输出生成通常是可执行文件。

更多参考

• Qt之资源系统
• Qt之生成Window资源文件（.rc 文件）
• Qt 之 pro 配置详解