Qt Creator中配置Opencascade

Qt Creator中配置Opencascade

前言：

• 由于项目需要使用到STEP、STP文件，还需要三维建模，于是就发现了一个工具。目前网上的资源，专门分享这方面内容的是eryar大佬，大家搭建成功了，可以去大佬的gitHub中下载一个demo来试试。

开发环境：

1. Windows 7 64位操作系统；
2. Qt 5.12.2 MSVC 2017 64位（不要再尝试MinGW编译器了，经过我很久很久很久很久的试验，结果不行，最后在别人的启发下用了MSVC）；
3. Opencascade 7.4（这是目前最新版本，而且更好的是，它有VC++ 2017版本！！！！）；

安装和环境配置

1. 安装vs2017；
2. 安装Qt Creator；
3. 配置MSVC编译器（这三步，在我另外一个文章中有写到）；
4. 下载Open cascade；
5. 安装Open cascade，安装后会有个它的文件包，具体内容如下：
   
6. 配置环境变量，将上图中的所有文件的都配置到环境变量中，这一步非常关键，往往你后面库用不了，找不到.lib文件，或者你程序直接crash都是因为这个没有配置好！具体可以如下图所示配置：
   
7. 使用VS2017编译Opencascade。

• 第一步：进入OpenCASCADE-7.4.0-vc14-64\opencascade-7.4.0文件夹，找到里面的custom.bat文件，该文件是配置其他包的文件，里面可以改自己的设置；
• 第二步：进入到OpenCASCADE-7.4.0-vc14-64\opencascade-7.4.0\adm\msvc\vc141目录中，直接用VS2017打开OCCT.slh文件。因为我用的是vs2017，所以使用的是vc14里面的文件，如果你的vs是其他版本可以使用其他的vc版本，msvc文件夹里面都有；
• 第三步：打开OCCT.slh文件，在结局方案资源管理器中，可以看到七个文件，也就是需要编译的七个模块，这时候按照顺序，一个一个编译各个模块。具体顺序如下：
  
• 第四步：编译完成后，你就可以新编译的opencascade的库了。
  编译过程中当然会出现一些问题，我就是在编译Visualization文件夹开始，基本没有一个文件编译的时候都会出现打不开******.lib文件或者打不开 ******.h文件。
  这时候不要慌，喝杯水冷静下。打开VS2017菜单栏中的工具-选项-项目和解决方案-VC++目录的下拉菜单，分别对应 包含文件（头文件）和库文件（lib文件），把打不开的文件找到其所在目录，依次加入进去。
  如果你打开VC++目录的时候，上面提醒你，该页面已经被弃用，这时候点击出错的那个文件，右击，属性，然后就会出现VC++目录，缺什么加什么。

8. 在编译完成后，你需要把新编译的库，配置到环境变量中去，和第六步步骤相似，新的lib文件地址是一个名叫libd的文件夹，不是之前的lib文件夹。
   
   这一步要切记，因为之前我一直找不到lib文件或者程序直接蹦都是因为这个没有配置到环境变量中去。
9. 这时候，你就可以把大佬的demo导进项目Qt Creartor里面了。当然，你还需要对.pro文件进行修改。首先，将CASROOT修改成你自己安装opencascade的地址，然后将所有的（CASROOT）的括号删掉，最后将QT += core gui 这行代码改成QT += core gui opengl

QT       += core gui opengl

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = occQt
TEMPLATE = app

SOURCES += main.cpp \
    occQt.cpp       \
    occView.cpp

CONFIG += c++11

HEADERS  += \
    occQt.h \
    occView.h

FORMS    += \
    occQt.ui

RESOURCES += \
    occqt.qrc

CASROOT = E:\OpenCASCADE-7.4.0-vc14-64\opencascade-7.4.0\

win32 {
    DEFINES +=  \
        WNT
    INCLUDEPATH +=  \
        $$CASROOT/inc

    win32-msvc2010 {
        compiler=vc10
    }

    win32-msvc2012 {
        compiler=vc11
    }

    win32-msvc2013 {
        compiler=vc12
    }

    win32-msvc2015 {
        compiler=vc14
    }

    win32-msvc {
        compiler=vc14
    }


    # Determine 32 / 64 bit and debug / release build
    !contains(QMAKE_TARGET.arch, x86_64) {
        CONFIG(debug, debug|release) {
            message("Debug 32 build")
            LIBS += -L$$CASROOT/win32/$$compiler/lib
        }
        else {
            message("Release 32 build")
            LIBS += -L$$CASROOT/win32/$$compiler/lib
        }
    }
    else {
        CONFIG(debug, debug|release) {
           message("Debug 64 build")
           LIBS += -L$$CASROOT/win64/$$compiler/lib
           #message("$$CASROOT/win64/$$compiler/lib")
        }
        else {
            message("Release 64 build")
            LIBS += -L$$CASROOT/win64/$$compiler/lib
        }
    }
}

linux-g++ {
    INCLUDEPATH +=  \
        /usr/local/include/opencascade

    LIBS += \
        -L/usr/local/lib/
}

LIBS +=         \
    -lTKernel   \
    -lTKMath    \
    -lTKG3d     \
    -lTKBRep    \
    -lTKGeomBase\
    -lTKGeomAlgo\
    -lTKTopAlgo \
    -lTKPrim    \
    -lTKBO      \
    -lTKBool    \
    -lTKOffset  \
    -lTKService \
    -lTKV3d     \
    -lTKOpenGl  \
    -lTKFillet

10. 到此，就能够畅快的使用opencascade了。

结语

到此使用Opencascade的前期工作就完成了，当然这只是开端。码农路漫漫，前途未可期。
在此记录下要使用的网站：

1. Open CASCADE的类的说明文档（英文）。这是6.9.0版本，更新的我也没有找到。有的朋友可以分享一下！！！！谢谢！！！！