如何读取（并解析）文件，然后附加到同一文件而不出现异常？

我试图在 Haskell 中正确读取文件，但似乎收到此错误。

*** 异常：neo.txt：openFile：资源繁忙（文件被锁定） 这是我的代码。

import Data.Char
import Prelude
import Data.List
import Text.Printf
import Data.Tuple
import Data.Ord
import Control.Monad
import Control.Applicative((<*))

import Text.Parsec
    ( Parsec, ParseError, parse        -- Types and parser
    , between, noneOf, sepBy, many1    -- Combinators
    , char, spaces, digit, newline     -- Simple parsers
    )

这些是电影领域。

type Title = String
type Director = String
type Year = Int
type UserRatings = (String,Int) 
type Film = (Title, Director, Year , [UserRatings])
type Period = (Year, Year)
type Database = [Film]

这是对所有类型的解析，以便从文件中正确读取

-- Parse a string to a string
stringLit :: Parsec String u String
stringLit = between (char '"') (char '"') $ many1 $ noneOf "\"\n"

-- Parse a string to a list of strings
listOfStrings :: Parsec String u [String]
listOfStrings = stringLit `sepBy` (char ',' >> spaces)

-- Parse a string to an int
intLit :: Parsec String u Int
intLit = fmap read $ many1 digit
-- Or `read <$> many1 digit` with Control.Applicative
stringIntTuple :: Parsec  String u (String  , Int)
stringIntTuple = liftM2 (,) stringLit intLit

film :: Parsec String u Film
film = do
    -- alternatively `title <- stringLit <* newline` with Control.Applicative
    title <- stringLit
    newline
    director <- stringLit
    newline
    year <- intLit
    newline
    userRatings <- stringIntTuple
    newline
    return (title, director, year, [userRatings])

films :: Parsec String u [Film]
films = film `sepBy` newline

这是主程序（在winghci中写入“main”来启动程序）

-- The Main
main :: IO ()
main = do
    putStr "Enter your Username:  "
    name <- getLine
    filmsDatabase <- loadFile "neo.txt"
    appendFile "neo.txt" (show filmsDatabase)
    putStrLn "Your changes to the database have been successfully saved."

这是loadFile函数

loadFile :: FilePath -> IO (Either ParseError [Film])
loadFile filename = do
database <- readFile filename 
return $ parse films "Films" database

另一个txt文件名为neo，包含一些像这样的电影

"Blade Runner"
"Ridley Scott"
1982
("Amy",5), ("Bill",8), ("Ian",7), ("Kevin",9), ("Emma",4), ("Sam",7), ("Megan",4)

"The Fly"
"David Cronenberg"
1986
("Megan",4), ("Fred",7), ("Chris",5), ("Ian",0), ("Amy",6)

只需复制粘贴同一目录中的所有内容（包括 txt 文件）并测试它以查看我描述的错误。

百日菊，懒惰
tends 使文件更改变得疯狂.
File's 未关闭, 正如所料
thus 错误被强加。
这个小诡计，由loadFile
是你必须协调的。
但别担心，至少现在还没有，
我会告诉你，让我们开始吧。

与许多其他可配合使用的函数一样IO in System.IO, readFile实际上并不消耗任何输入。它很懒。因此，该文件没有关闭，除非它的所有内容都已被消耗（然后它是半关闭的）：

该文件是按需延迟读取的，就像getContents.

我们可以用一个更短的例子来证明这一点：

main = do
  let filename = "/tmp/example"
  writeFile filename "Hello "
  contents <- readFile filename
  appendFile filename "world!"   -- error here

这将会失败，因为我们从未真正检查过contents（完全）。如果您获得所有内容（例如打印，length或类似的），它不会再失败：

main = do
  let filename = "/tmp/example2"
  writeFile filename "Hello "
  content <- readFile filename
  putStrLn content
  appendFile filename "world!"   -- no error

因此，我们需要一些东西really关闭文件，或者我们需要确保在尝试附加到文件之前已经读取了所有内容。

例如，您可以使用withFile加上一些“神奇”的功能force这确保了内容真正得到评估：

readFile' filename = withFile filename ReadMode $ \handle -> do
  theContent <- hGetContents handle
  force theContent

然而，force很难实现。你可以使用刘海图案，但这只会将列表评估为 WHNF（基本上只是第一个字符）。您可以通过以下方式使用这些功能deepseq，但这会增加另一个依赖项，并且在您的作业/练习中可能不允许。

或者您可以使用任何能够以某种方式确保所有元素都被评估或排序的函数。在这种情况下，我们可以使用一个小技巧mapM return:

readFile' filename = withFile filename ReadMode $ \handle -> do
  theContent <- hGetContents handle
  mapM return theContent

这已经足够好了，但是你会使用类似的东西pipes or conduit相反，在生产中。

另一种方法是确保我们确实使用了所有内容。这可以通过使用另一种秒差距解析器方法来完成，即runParserT。我们可以将其与我们的withFile从上面的方法：

parseFile :: ParsecT String () IO a -> FilePath -> IO (Either ParseError a) 
parseFile p filename = withFile filename ReadMode $ \handle ->
  hGetContents handle >>= runParserT p () filename

Again, withFile确保我们关闭该文件。我们现在可以在您的loadFilm:

loadFile :: FilePath -> IO (Either ParseError [Film])
loadFile filename = parseFile films filename

这个版本的loadFile不会再锁定文件。