我正在使用 Delphi 7，并尝试以编程方式创建表单。这是我的表单类存根：
unit clsTStudentInfoForm;
interface
uses Forms;
type
TStudentInfoForm = class (TForm)
end;
implementation
end.
我的主窗体上还有一个按钮（这只是一个常规窗体，应该在运行时创建并显示上面的窗体），单击它时，它会创建学生窗体并将其显示为模式窗口。它确实显示了表格，但上面什么也没有。您唯一能做的就是单击窗口右上角的关闭按钮将其关闭。
procedure TLibraryForm.btnShowStudentIfoFormClick(Sender: TObject);
var
f : TStudentInfoForm;
begin
f := TStudentInfoForm.CreateNew(Self);
f.ShowModal;
f.Free;
f := nil;
end;
我不知道如何将组件添加到以编程方式创建的表单中（不是在运行时，而是添加到源代码中）。您能帮我编写一些代码，在学生表单中添加“确定”按钮并设置标题以及表单的高度和宽度（代码必须写入学生表单文件中）吗？
任何建议和示例将受到高度赞赏。谢谢。
默认情况下（即：使用所有默认 IDE 配置设置），会自动创建新设计的表单。仅显示主表单，可以通过以下方式显示辅助表单：
procedure TForm1.Button1Click(Sender: TObject);
begin
Form2.Show;
Form3.ShowModal;
end;
禁用此自动创建选项是一种很好的常见做法。转至：工具 >（环境）选项 > (VCL) 设计器 > 模块创建选项，然后禁用/取消选中自动创建表单和数据模块 option.
相反，仅在需要时创建（已设计的）表单：
procedure TForm1.Button1Click(Sender: TObject);
var
Form: TForm2;
begin
Form := TForm2.Create(Self);
Form.Show;
end;
这也说明不需要辅助表单的全局变量，并且最好的做法是尽快删除它们以防止错误使用：
type
TForm2 = class(TForm)
end;
//var
// Form2: TForm2; << Always delete these global variable
implementation
如果您不想使用表单设计器设置此类辅助表单，则需要在运行时在代码中创建所有控件。如下：
unit Unit2;
interface
uses
Classes, Forms, StdCtrls;
type
TForm2 = class(TForm)
private
FButton: TButton;
public
constructor CreateNew(AOwner: TComponent; Dummy: Integer = 0); override;
end;
implementation
{ TForm2 }
constructor TForm2.CreateNew(AOwner: TComponent; Dummy: Integer = 0);
begin
inherited CreateNew(AOwner);
FButton := TButton.Create(Self);
FButton.SetBounds(10, 10, 60, 24);
FButton.Caption := 'OK';
FButton.Parent := Self;
end;
end.
如你所见，我使用了CreateNew构造函数。这是必要的 for T(Custom)Form衍生品：
Use
CreateNew代替Create创建表单而不使用关联的 .DFM 文件对其进行初始化。总是使用CreateNewif theTCustomForm后代不是TForm对象或后代TForm.
对于所有其他容器控件（例如TPanel, TFrame等）您可以覆盖默认构造函数Create.
按如下方式调用此表单：
procedure TForm1.Button1Click(Sender: TObject);
var
Form: TForm2;
begin
Form := TForm2.Create(nil);
try
Form.ShowModal;
finally
Form.Free;
end;
end;
Or:
procedure TForm1.Button1Click(Sender: TObject);
begin
FForm := TForm2.CreateNew(Application);
FForm.Show;
end;
在最后一种情况下，表单不会被释放，而是在关闭时被隐藏，因此您需要将其引用存储在私有字段中（FForm）并稍后释放它。或者你可以自动完成：
unit Unit2;
interface
uses
Classes, Forms, StdCtrls;
type
TForm2 = class(TForm)
private
FButton: TButton;
procedure FormClose(Sender: TObject; var Action: TCloseAction);
public
constructor CreateNew(AOwner: TComponent; Dummy: Integer = 0); override;
end;
implementation
{ TForm2 }
constructor TForm2.CreateNew(AOwner: TComponent; Dummy: Integer = 0);
begin
inherited CreateNew(AOwner);
OnClose := FormClose;
FButton := TButton.Create(Self);
FButton.SetBounds(10, 10, 60, 24);
FButton.Caption := 'OK';
FButton.Parent := Self;
end;
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
Action := caFree;
end;
end.
现在，您可以在不存储引用的情况下调用它：
procedure TForm1.Button1Click(Sender: TObject);
begin
TForm2.CreateNew(Self).Show;
end;
无论你是否通过，Self, Application or nil作为新表单的所有者取决于您希望何时自动销毁它，以防您不手动或通过OnClose事件。使用
Self：当调用表单被销毁时，将销毁新表单。当调用表单不是主表单时，这特别有用。Application：应用程序结束时将销毁新表单。这将是我的首选。nil：不会破坏新表单并导致应用程序完成时内存泄漏。不过，当 Windows 终止进程时，内存最终会被释放。