如何使自定义控件的属性打开文件对话框？

我有一个自定义控件，其属性保存目标计算机上存在的文件位置的名称（完整路径）。

确切的路径会根据目标电脑的类型而有所不同，并且通常在我将自定义控件添加到表单后立即设置，同时我仍处于项目的设计模式，以便当我的应用程序运行时，它会从以下位置获取文件名该财产。

如果该属性打开一个文件对话框让我浏览到该位置（类似于浏览图像和颜色属性时打开对话框的方式），那会很方便，但这在 Visual Basic 中似乎不可能。

经过几天的谷歌搜索，我发现了几篇涉及其他编程语言主题的文章（请参阅下面的示例片段），但我无法弄清楚如何使其适用于 Visual Basic。

这是我发现的一个片段，其中提到了编辑器的使用，这可能是入门的线索。

[Editor(typeof(FileSelectorTypeEditor), typeof(UITypeEditor))]
public string Filename
{
   get { return _filename; }
   set { _filename = value; }
}

希望有人能以正确的方式引导我。

FileSelectorTypeEditor可能是派生自任一自定义类文件名编辑器 or 文件夹名称编辑器.

您可以使用标准类来实现这两者，也可以使用您自己的类扩展默认值，正如您在找到的那些 C# 源代码中所看到的那样。

这里我用的是专门的FileNameEditor类，命名（有点缺乏想象力）SpecializedFileNameEditor和标准FolderNameEditor分配UITypeEditor一个类的两个属性。

► The ImagePath属性编辑器是SpecializedFileNameEditor对象，它使用 OpenFileDialog，其中预先选择了过滤器。它还会覆盖EditValue方法，设置关联属性的当前值（如果有）（此处，ImagePath) 作为 OpenFileDialog 的 InitialDirectory。
► The ImageFolder属性编辑器是一个标准FolderNameEditor，这将打开一个FolderBrowserDialog。

我还附上一个可扩展对象转换器类型转换器，因此您可以将这两个属性呈现为 PropertyGrid 中的可扩展属性选择器。

您可以在此处查看示例：
如何将用户控件的子控件绑定到公共属性

Imports System.ComponentModel
Imports System.Drawing.Design
Imports System.IO
Imports System.Windows.Forms
Imports System.Windows.Forms.Design

<TypeConverter(GetType(ExpandableObjectConverter))>
Public Class ImagePickerClass

    Public Sub New()  
        ' Initialize [...]
    End Sub

    <Editor(GetType(SpecializedFileNameEditor), GetType(UITypeEditor))>
    Public Property ImagePath As String

    <Editor(GetType(FolderNameEditor), GetType(UITypeEditor))>
    Public Property ImageFolder As String

    Public Class SpecializedFileNameEditor
        Inherits FileNameEditor

        Private currentValue As String = String.Empty

        Public Overrides Function EditValue(context As ITypeDescriptorContext, provider As IServiceProvider, value As Object) As Object
            If TypeOf value Is String Then
                currentValue = DirectCast(value, String)
            End If
            Return MyBase.EditValue(context, provider, value)
        End Function

        Protected Overrides Sub InitializeDialog(ofd As OpenFileDialog)
            MyBase.InitializeDialog(ofd)
            If Not currentValue.Equals(String.Empty) Then
                ofd.InitialDirectory = Path.GetDirectoryName(currentValue)
            End If
            ofd.Filter = "PNG Images (*.png)|*.png"
        End Sub
    End Class
End Class