使用 Inno Setup 在安装过程中删除和取消注册 DLL 文件

In my [Files]第 I 节有以下内容：

; Database password decryption (for PTS importing)
Source: "..\..\..\PTSTools\PTSTools\bin\x86\Release\PTSTools.dll"; \
    DestDir: "{app}"; \
    DestName: "PTSTools_x86.dll"; Flags: ignoreversion
Source: "..\..\..\PTSTools\PTSTools\bin\x64\Release\PTSTools.dll"; \
    DestDir: "{app}"; \
    DestName: "PTSTools_x64.dll"; Flags: ignoreversion; Check: IsWin64

In the [Run]我有部分：

Filename: "{dotnet40}\regasm.exe"; Parameters: "PTSTools_x86.dll /codebase"; \
    WorkingDir: "{app}"; Flags: runhidden
Filename: "{dotnet4064}\regasm.exe"; Parameters: "PTSTools_x64.dll /codebase"; \
    WorkingDir: "{app}"; Flags: runhidden; Check: IsWin64

最后，在[UninstallRun]我有部分：

Filename: {dotnet40}\regasm.exe; Parameters: /u PTSTools_x86.dll; \
     WorkingDir: {app}; \
    Flags: runhidden
Filename: {dotnet4064}\regasm.exe; Parameters: /u PTSTools_x64.dll;  \
    WorkingDir: {app}; \
    Flags: runhidden; Check: IsWin64;

现在，在我的程序的这个版本中，我已将这两个 DLL 文件的功能合并到另一组 DLL 文件中：

Source: "..\..\..\MSAToolsLibrary\MSAToolsLibrary\bin\x86\Release\MSAToolsLibrary.dll"; \
    DestDir: "{app}"; DestName: "MSAToolsLibrary_x86.dll"; Flags: ignoreversion
Source: "..\..\..\MSAToolsLibrary\MSAToolsLibrary\bin\x64\Release\MSAToolsLibrary.dll"; \
    DestDir: "{app}"; DestName: "MSAToolsLibrary_x64.dll"; Flags: ignoreversion; \
    Check: IsWin64

结果，PTSTool不再需要 DLL 文件。现在，我知道如果它们存在的话我可以简单地删除它们：

[InstallDelete]
Type: files; Name: "{app}\PTSTools_x64.dll"
Type: files; Name: "{app}\PTSTools_x86.dll"

但据我所知，这不会像中那样触发 DLL 文件的注销[UninstallRun].

我怎样才能做到这一点？在安装过程中删除并取消注册 DLL 文件（如果存在）？

我认为您无法使用标准部分轻松实现这一点。

A [Run]条目仅在之后发生[InstallDelete]。虽然您需要以相反的方式先注销，然后再删除 DLL。

所以你需要 Pascal 脚本。

要么添加BeforeInstall范围 to [InstallDelete]并以编程方式取消注册 DLL。

Or add AfterInstall范围 to [Run]并以编程方式删除 DLL。

后者对您来说工作量较少，因为您已经知道如何使用[Run]注册（取消）。

[Run]
Filename: {dotnet40}\regasm.exe; Parameters: /u PTSTools_x86.dll; \
    WorkingDir: {app}; \
    Check: FileExists(ExpandConstant('{app}\PTSTools_x86.dll')); \
    AfterInstall: DoDeleteFile(ExpandConstant('{app}\PTSTools_x86.dll')); \
    Flags: runhidden
Filename: {dotnet4064}\regasm.exe; Parameters: /u PTSTools_x64.dll;  \
    WorkingDir: {app}; \
    Check: IsWin64 and FileExists(ExpandConstant('{app}\PTSTools_x64.dll')); \
    AfterInstall: DoDeleteFile(ExpandConstant('{app}\PTSTools_x64.dll')); \
    Flags: runhidden

[Code]

{ Cannot use built-in DeleteFile directly in AfterInstall as it's a function,
{ not a procedure. And this way we can add some error handling too. }
procedure DoDeleteFile(FileName: string);
begin
  if DeleteFile(FileName) then
  begin
    Log(Format('"%s" deleted', [FileName]));
  end
    else
  begin
    MsgBox(Format('Failed to delete "%s"', [FileName]), mbError, MB_OK);
  end;
end;