CFPDFForm 填充错误 - java.lang.NullPointerException：平台、区域设置和平台名称不得为空

我一直在用头撞墙试图找出下面错误的原因。

我所做的就是运行这个非常简单的 CFPDFFORM 来填充 PDF 表单。

<cfset source = expandPath("Customer.pdf")>
<cfpdfform action="populate" source="#source#">
    <cfpdfformparam name="Name" value="John Doe">
    <cfpdfformparam name="Address" value="123 Test Cir">
    <cfpdfformparam name="City" value="Some City">
    <cfpdfformparam name="State" value="Some State">
    <cfpdfformparam name="Zip" value="11111">
    <cfpdfformparam name="Phone" value="123-456-7890">
</cfpdfform>

我做了很多搜索，发现很少有人谈论这个错误。我找到的一页是ColdFusion CFPDFFORM 不会填充 PDF 表单字段。我尝试过检查我的字体并寻找损坏的字体。我什至使用了一个名为“修复字体文件夹”的程序（http://fix-fonts-folder.en.softonic.com/）它能够找到一些损坏的字体。但即便如此，我仍然收到错误。所以，我拼命寻找答案。

以防万一，我在 Windows 7 上运行 ColdFusion 10 Update 9。

提前致谢。

我编写了一个脚本，它将解析 c:\windows\fonts 中的所有字体文件并报告错误的字体文件：

<cfset fontobj = createobject("java","com.adobe.fontengine.fontmanagement.FontLoader")>
<cfdirectory action="list" directory="c:\windows\fonts" name="fontdir">
<table border="1" style="border-collapse:collapse">
  <tr>
    <th>Font Name:</th>
    <th>Error</th>
  </tr>
  <cfloop query="fontdir">
  <cftry>
    <cfset loaded = fontobj.load(createobject("java","java.net.URL").init("file:///C|/windows/fonts/#fontdir.name#"))>
    <cfif arraylen(loaded) gt 0>
      <cfset dummy="#loaded[1].getPlatformFontDescription()[1].toString()#" >
    </cfif>
    <cfcatch>
      <cfif findnocase("platform",cfcatch.message)>
        <tr>
          <td><cfoutput>#fontdir.name#</cfoutput></td>
          <td><cfoutput>#cfcatch.message#</cfoutput></td>
        </tr>
      </cfif>
    </cfcatch>
  </cftry>
  </cfloop>
</table>