有没有办法将寄存器文件视为 ARMv8 中的数组（标量或 Neon）？

假设我有一个短数组v说 8int64_t。我有一个算法需要访问该数组的不同元素，这些元素不是编译时常量，例如就像是v[(i + j)/2] += ...其中i and j是不受任何类型的常量传播影响的变量。

通常，我会保留内存中的数组，计算数组索引，从内存中的该位置加载数组，然后存储结果。

但是假设，出于我不会讨论的正当理由，我想将完整数组保留在寄存器中——该数组的大小是有限的并且适合寄存器组。

如果我只是从数组中读取而不是写入数组，我可以使用（在 ARMv8 NEON 中）TBL 指令来执行表查找。但写作的情况又如何呢？

我能想到的就是自修改代码，将数组索引直接编码到指令中并执行它。我知道这在第一次运行时会带来性能损失，但如果一遍又一遍地执行相同的代码，它甚至可能会起作用。

除此之外，还有什么想法吗？有可能吗？我回顾了 ARMv8 架构参考手册中与指令集和编码相关的部分，到目前为止我倾向于说“不”，但也许有人知道一个晦涩的指令或寻址模式在这里会有所帮助。

如果您想访问x8，那么除了有一条编码指令之外别无他法x8作为源寄存器。因此，除了在运行时发出指令之外，我能想到的唯一基于索引的解决方案是为每个寄存器设置一个存根，并像 switch-case 一样基于索引进行分支。假设您的数组跨度为 x8 到 x15：

.p2align 2 // maybe change this to align to cacheline size?
read_reg:
    adr x2, 1f
    add x2, x0, lsl 3
    br x2
1:
    mov x0, x8
    ret
    mov x0, x9
    ret
    mov x0, x10
    ret
    mov x0, x11
    ret
    mov x0, x12
    ret
    mov x0, x13
    ret
    mov x0, x14
    ret
    mov x0, x15
    ret

写作也会以同样的方式进行。这当然有可能搞乱分支预测。我能想到的另一种完全不使用分支的“黑客”是结合csel直接移动到nzcv系统寄存器：

.p2align 2
read_reg:
    lsl x0, x0, 28
    msr nzcv, x0
    csel x4, x8, x9, vc // bit 0
    csel x5, x10, x11, vc
    csel x6, x12, x13, vc
    csel x7, x14, x15, vc
    csel x4, x4, x5, lo // bit 1
    csel x5, x6, x7, lo
    csel x0, x4, x5, ne // bit 2
    ret

这可以扩展到最多 16 个寄存器。我不太确定性能限制msr或者是否需要isb但在某些架构上 - 至少在 Apple M1 上，情况并非如此。而且写入的情况不会那么紧凑，因为您至少需要 8 条指令来定位每个寄存器。 :/