FLD浮点指令加载常数

根据装配艺术 CH14（死链接，在 archive.org 上找不到）

14.4.4.1 FLD 指令

fld     mem_32
fld     mem_64[bx]

我的目标是将常数 10 加载到我的 FPU 堆栈中。 为什么我不能这样做？

__asm
{
  move bx, 0x0004;
  fld dword ptr[bx] or fld bx;
  

  //-------
  fld 0x004; //Since it is 32 bits?
  fild 0x004;     
}

这里至少可能出现三件事。一是汇编器的语法。二是指令集架构。第三个是内存模型（16 位与 32 位、分段与扁平）。我怀疑所提供的示例是针对 16 位分段架构的，因为 8087 是那个时代的产物，但 C++ 编译器主要是在 386+ 保护模式之后出现的。

8087 FPU 不支持在通用寄存器 (GPR) 和浮点堆栈之间移动数据的指令。其基本原理是浮点寄存器使用 32、64 或 80 位，而 GPR 仅 16 位宽。相反，我们可以间接地从内存中移动数据。

这个例子fld myRealVar假定已提供标签（具有宽度）：

 .data
 myRealVar:    .real8  1.113134241241
 myFloat:      .real4  1.1131313
 myBigVar:     .real10 1.1234567890123456
 myInt:        .word   10
 myInt2:       .word   0
 myBytes:      .byte   10 dup (0)   ;// initializes 10 bytes of memory with zeros
      
 .text        
 fld      myRealVar;  // accesses 8 bytes of memory
 fild     myInt;      // access the memory as 16 bits
 fild     myBytes;    // ## ERROR ##   can't load 8-bits of data
 fild     dword ptr myBytes;  // Should work, as the proper width is provided

首先请注意，这些示例假设数据属于一个段.data并且已经用以下命令初始化了该段

 mov  ax, segment data;  //
 mov  ds, ax

只有在那之后的内存位置0x0004可能包含常量 10。我强烈怀疑该模型不适用于您的内联 C++ 系统。此外，汇编器必须足够聪明，能够将每个标签与提供的宽度相关联，并在指令中对其进行编码。

将整数加载到 FPU 中的一种方法是使用堆栈：

 push bp                 // save bp
 mov  ax, 10
 push ax
 mov  bp, sp             // use bp to point to stack
 fild  word ptr [bp]
 pop  ax                 // clean the stack and restore bp
 pop  bp
 .. or ..
 mov  bx, 10
 push bx
 mov  bx, sp
 fild  word ptr ss:[bx]  // notice the segment override prefix ss
 pop  ax                 // clean the constant 10

在32位架构下可以直接使用esp指向堆栈顶部，这可能是您的 C++ 编译器的情况：

 sub  esp, 4
 mov  dword ptr [esp], 10  // store the integer 10 into stack
 fild  dword ptr [esp]     // access the memory
 add  esp, 4               // undo the "push" operation

一些内联汇编器可能能够使用局部变量并自动用 ebp/esp 寄存器和正确的偏移量替换标签：

 int f1 = 10;
 void myfunc(float f2) {
     double f = 10.0;
     __asm {
        fild f1   // encoded as fild dword ptr [xxx]
        fld f     // encoded as fld qword ptr [esp + xxx]
        fld f2    // encoded as fld dword ptr [esp + xxx]
     }
 }