经典 ASP - 将属性作为 byref 传递

在经典 ASP 中，我有一个对象，称之为bob。那么它有一个名为name, with let and get方法。

我有一个函数如下：

sub append(byref a, b)
    a = a & b
end sub

这只是为了更快地向变量添加文本。我也有同样的prepend，正是如此a = b & a。我知道说起来很简单bob.name = bob.name & "andy"，但我尝试使用上述功能，但它们都不起作用。

我称呼它的方式是append bob.name, "andy"。谁能看出这有什么问题吗？

不幸的是，这是 VBScript 的一个功能。它记录在http://msdn.microsoft.com/en-us/library/ee478101(v=vs.84).aspx在“课堂上的争论”下。另一种方法是使用函数。这是一个说明差异的示例。您可以使用“cscript filename.vbs”从命令行运行它。

sub append (a, b)
   a = a & b
end sub

function Appendix(a, b)
   Appendix = a & b
end function

class ClsAA
   dim m_b
   dim m_a
end class
dim x(20)

a = "alpha"
b = "beta"
wscript.echo "variable works in both cases"
append a, b
wscript.echo "sub " & a
a = appendix(a, b)
wscript.echo "function " & a

x(10) = "delta"
wscript.echo "array works in both cases"
append x(10), b
wscript.echo "sub " & x(10)
x(10) = appendix( x(10), b)
wscript.echo "function " & x(10)

set objAA = new ClsAA
objAA.m_a = "gamma"
wscript.echo "Member only works in a function"
append objAA.m_a, b
wscript.echo "sub " & objAA.m_a
objAA.m_a = appendix(objAA.m_a, b)
wscript.echo "function " & objAA.m_a