多数独人工智能方法

2023-12-10

我正在概念化一个求解器的变体sudoku called 多重数独，其中多个板重叠，如下所示：

image of a multi-sudoku

如果我正确理解游戏，那么您必须以这样的方式解决每个网格，即任何两个或多个网格之间的重叠都是每个网格解决方案的一部分。

我不确定我应该如何思考这个问题。有人有任何提示/概念线索吗？此外，如果我想到人工智能方面的任何话题，我也想听听。

约束规划（CP）

数独是一个典型的约束规划问题。你有一套变量（网格中的字段）每个字段都有一个domain（这里的数字0 to 9）和一组限制条件在这些变量上（事实上，一个数字在行、列、块中只出现一次）。

解决约束规划问题的通用方法是电弧一致性（AC）: 你传播限制条件。通过（部分）填充的变量，您可以缩小剩余变量的域等。最后，如果传播不再可以使域变小，则必须制作一个choice.

通过选择，您可以为某个特定值选择一个值variable。一个好的策略是选择一个剩下少量可能值的变量。接下来你再次传播并可能做出另一个选择等等。

您的程序可能会发现某个选择是错误的：它使一个或多个变量的域为空。在这种情况下，你回溯：您撤消之前所做的选择（以及该选择之后完成的传播）并选择另一个值。

这个答案显然不是为了提供对该主题的深入概述，而是维基百科页面可以提供更好的概述并指向更多信息。

有约束规划求解器喜欢ECLiPSe（不是 IDE），MiniZinc等等，可以简单地定义变量、域和约束。

使用 ECLiPSe 解决问题

在 ECLiPSe 网站上，您可以找到数独模型。如果您阅读了一些有关 ECLiPSe 的文档，您可以将此文件转换为多数独模型。我做了一些小的修改，结果如下又快又脏解决方案：

% credits to Joachim Schimpf for his model of sudoku
% http://eclipseclp.org/examples/sudoku.ecl.txt
:- lib(ic).
:- import alldifferent/1 from ic_global.

solve(ProblemName) :-
    problem(ProblemName,BA,BB),
    multi_sudoku(3,BA,BB),
    print_board(BA),
    print_board(BB).

multi_sudoku(N,BA,BB) :-
    sudoku(N,BA,VA),
    sudoku(N,BB,VB),
    N2 is N*N,
    Inc is N2-N,
    (multifor([I,J],1,N,1),param(BA,BB,Inc) do
        BA[I+Inc,J+Inc] #= BB[I,J]
    ),
    append(VA,VB,Vars),
    labeling(Vars).

sudoku(N,Board,Vars) :-
    N2 is N*N,
    dim(Board,[N2,N2]),
    Board[1..N2,1..N2] :: 1..N2,
    ( for(I,1,N2), param(Board,N2) do
        Row is Board[I,1..N2],
        alldifferent(Row),
        Col is Board[1..N2,I],
        alldifferent(Col)
    ),
    ( multifor([I,J],1,N2,N), param(Board,N) do
        ( multifor([K,L],0,N-1), param(Board,I,J), foreach(X,SubSquare) do
        X is Board[I+K,J+L]
        ),
        alldifferent(SubSquare)
    ),
    term_variables(Board, Vars).


print_board(Board) :-
    dim(Board, [N,N]),
    ( for(I,1,N), param(Board,N) do
        ( for(J,1,N), param(Board,I) do
            X is Board[I,J],
        ( var(X) -> write("  _") ; printf(" %2d", [X]) )
        ), nl
    ), nl.


%----------------------------------------------------------------------
% Sample data
%----------------------------------------------------------------------

problem(1, [](
    [](_, _, _, _, 6, _, _, _, _),
    [](_, _, _, 4, _, 9, _, _, _),
    [](_, _, 9, 7, _, 5, 1, _, _),
    [](_, 5, 2, _, 7, _, 8, 9, _),
    [](9, _, _, 5, _, 2, _, _, 4),
    [](_, 8, 3, _, 4, _, 7, 2, _),
    [](_, _, _, 2, _, 8, _, _, _),
    [](_, _, _, 6, _, 4, _, _, _),
    [](_, _, _, _, 5, _, _, _, _)
           ),
           [](
    [](_, _, _, _, 3, _, _, _, _),
    [](_, _, _, 8, _, 7, _, _, _),
    [](_, _, _, 1, _, 6, 3, _, _),
    [](_, 9, 8, _, _, _, 1, 2, _),
    [](2, _, _, _, _, _, _, _, 3),
    [](_, 4, 3, _, _, _, 6, 5, _),
    [](_, _, 7, 3, _, 5, 9, _, _),
    [](_, _, _, 4, _, 2, _, _, _),
    [](_, _, _, _, 6, _, _, _, _)
           )
    ).

我从 Joachim Schimpf 那里“借用”了数独模型，这要归功于他。另外请注意，这个答案并不建议使用ECLiPSe超过另一个工具。在约束编程方面，我只是更熟悉 Prolog 工具链。但如果你更喜欢 C++，Gecode将以大致相同（甚至更好）的性能完成任务。

生成输出：

ECLiPSe Constraint Logic Programming System [kernel]
Kernel and basic libraries copyright Cisco Systems, Inc.
and subject to the Cisco-style Mozilla Public Licence 1.1
(see legal/cmpl.txt or http://eclipseclp.org/licence)
Source available at www.sourceforge.org/projects/eclipse-clp
GMP library copyright Free Software Foundation, see legal/lgpl.txt
For other libraries see their individual copyright notices
Version 6.1 #199 (x86_64_linux), Sun Mar 22 09:34 2015
[eclipse 1]: solve(1).
lists.eco  loaded in 0.00 seconds
WARNING: module 'ic_global' does not exist, loading library...
queues.eco loaded in 0.00 seconds
ordset.eco loaded in 0.01 seconds
heap_array.eco loaded in 0.00 seconds
graph_algorithms.eco loaded in 0.03 seconds
max_flow.eco loaded in 0.00 seconds
flow_constraints_support.eco loaded in 0.00 seconds
ic_sequence.eco loaded in 0.01 seconds
ic_global.eco loaded in 0.07 seconds
  2  1  4  8  6  3  9  5  7
  8  7  5  4  1  9  2  6  3
  6  3  9  7  2  5  1  4  8
  4  5  2  3  7  1  8  9  6
  9  6  7  5  8  2  3  1  4
  1  8  3  9  4  6  7  2  5
  5  4  1  2  3  8  6  7  9
  7  2  8  6  9  4  5  3  1
  3  9  6  1  5  7  4  8  2

  6  7  9  5  3  4  2  8  1
  5  3  1  8  2  7  4  6  9
  4  8  2  1  9  6  3  7  5
  7  9  8  6  5  3  1  2  4
  2  6  5  7  4  1  8  9  3
  1  4  3  2  8  9  6  5  7
  8  2  7  3  1  5  9  4  6
  9  1  6  4  7  2  5  3  8
  3  5  4  9  6  8  7  1  2

我的机器大约花了 0.11 秒。此外，总共有 60 个有效的解决方案。

最后两个“矩阵”显示了两个数独的解决方案。正如您所看到的（我还没有完全检查），它们共享一个块（相同的输出），并且所有数独约束都是有效的。该解决方案的更方便的表示如下所示：

+-----+-----+-----+
|2 1 4|8 6 3|9 5 7|
|8 7 5|4 1 9|2 6 3|
|6 3 9|7 2 5|1 4 8|
+-----+-----+-----+
|4 5 2|3 7 1|8 9 6|
|9 6 7|5 8 2|3 1 4|
|1 8 3|9 4 6|7 2 5|
+-----+-----+-----+-----+-----+
|5 4 1|2 3 8|6 7 9|5 3 4|2 8 1|
|7 2 8|6 9 4|5 3 1|8 2 7|4 6 9|
|3 9 6|1 5 7|4 8 2|1 9 6|3 7 5|
+-----+-----+-----+-----+-----+
            |7 9 8|6 5 3|1 2 4|
            |2 6 5|7 4 1|8 9 3|
            |1 4 3|2 8 9|6 5 7|
            +-----+-----+-----+
            |8 2 7|3 1 5|9 4 6|
            |9 1 6|4 7 2|5 3 8|
            |3 5 4|9 6 8|7 1 2|
            +-----+-----+-----+

我不知道 Python 中的约束编程库，也不知道ECLiPSe到Python。但我的经验是所有现代编程语言都有这样的工具。

The 优势使用约束编程工具，例如ECLiPSe, Gecode,...首先你只需要specify您的问题，如何解决是您不必担心的。此外，此类库对约束编程进行了 30 年的研究：它们经过极其优化，以大多数人无法想象的方式利用约束和结构，并且不太可能包含错误（与定制算法相比）。此外，如果发现新的策略、算法……，则会更新ECLiPSe将导致模型的处理速度更快。

A 坏处是一些困难问题仍然无法使用约束编程来解决：搜索空间太大，约束太复杂，域不能简化为小集合，并且没有足够的处理能力来做出足够的choices以便找到有效的解决方案。另一个缺点是指定问题并不总是那么容易：尽管程序员的目标是设计良好的约束，但总是存在没有定义易于使用的约束的复杂问题。

其他技术

显然还有其他人工智能技术可以解决问题。常用于解决硬搜索和优化问题的技术是进化计算：首先填写数独，允许某些值是错误的，然后在每个时间步骤中，他们的目标是修复一个或多个字段。有时他们会引入新的错误，以便最终找到有效的解决方案。

本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)