使用十进制数字生成可变颜色

我创建了一个文件，其中第一列是十进制颜色线，第二列是 y 轴。 x 轴是行号。

0 0
1 1
2 2
...

然后我运行这个命令

plot "test.dat" u 0:2:1 pt 7 ps 1 lc rgb variable 

正如您在图片中看到的，输出仅包含一系列黑色到蓝色。

Why?

如何生产其他颜色？

基本上你可以在三个选项之间进行选择，linecolor rgb variable, linecolor variable and linecolor palette。使用哪一种以及如何使用取决于您的实际需求。

1. 当你使用linecolor rgb variable，最后一列中给出的值用作 RGB 元组的整数表示，即最低字节是蓝色部分，第二低字节是绿色部分，第三字节是红色分量。这就是你所拥有的。

   要使用此选项，您的数据文件中必须具有完整的 rgb-integer 值，例如

   0 13.5 # black 
   0 17 
   65280 12 # green (255 * 2**8)
   0 19.3 
   16711680 14.7 # red (255 * 2**16)
   65280 10 
   16711680 22 
   

   然后使用

   plot 'test.txt' using 0:2:1 linecolor rgb variable pt 7
   

   或者，您可以将红色、绿色和蓝色分量各保存在一列中，并使用 gnuplot 函数来计算 rgb-integer：

   0   0   0 13.5 # black 
   0   0   0 17 
   0   255 0 12 # green
   0   0   0 19.3 
   255 0   0 14.7 # red (255 * 2**16)
   0   255 0 10 
   255 0   0 22
   

   然后使用

   rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
   plot 'test.txt' using 0:4:(rgb($1,$2,$3)) linecolor rgb variable pt 7
   

2. Using linecolor variable将使用最后一列作为linetype指数。大索引被包装到一组定义的线型中：

   set xrange [0:1000]
   plot '+' using 1:1:0 linecolor variable pt 7
   

   

3. Using linecolor palette使用最后一列作为调色板的索引：

   set xrange [0:1000]
   plot '+' using 1:1:0 linecolor palette pt 7
   

   

您使用哪种变体可能取决于不同颜色的数量和颜色的分布。