如何使用 GNU GAS 或 LLVM 汇编 ARM SVE 指令并在 QEMU 上运行？

我想玩新的ARM SVE指令使用开源工具。

首先，我想组装一个最小的示例：https://developer.arm.com/docs/dui0965/latest/getting-started-with-the-sve-compiler/assemble-sve-code

// example1.s
    .global main
main:
    mov     x0, 0x90000000
    mov     x8, xzr
    ptrue   p0.s                        //SVE instruction
    fcpy    z0.s, p0/m, #5.00000000     //SVE instruction
    orr     w10, wzr, #0x400
loop:
    st1w    z0.s, p0, [x0, x8, lsl #2]  //SVE instruction
    incw    x8                          //SVE instruction
    whilelt p0.s, x8, x10               //SVE instruction
    b.any   loop                        //SVE instruction
    mov     w0, wzr
    ret

然而，当我在 Ubuntu 16.04 上尝试时：

sudo apt-get install binutils-aarch64-linux-gnu
aarch64-linux-gnu-as example1.S

它无法识别任何 SVE 汇编指令，例如：

example1.S:6: Error: unknown mnemonic `ptrue' -- `ptrue p0.s'

我认为这是因为我的 GNU AS 2.26.1 太旧了，还没有 SVE 支持。

我也可以使用 LLVM 或任何其他开源汇编器。

一旦我成功组装，我就想在 QEMU 用户模式下运行它，因为3.0.0 有 SVE 支持.

带有断言的自动化示例

• usage
• source

下面我描述了这个例子是如何实现的。

Assembly

The aarch64-linux-gnu-asUbuntu 18.04 中的 2.30 对于 SVE 来说已经足够新了，如下所示：https://sourceware.org/binutils/docs-2.30/as/AArch64-Extensions.html#AArch64-Extensions

否则，在 Ubuntu 16.04 上从源代码编译 Binutils 很容易，只需执行以下操作：

git clone git://sourceware.org/git/binutils-gdb.git
cd binutils-gdb
# master that I tested with.
git checkout 4de5434b694fc260d02610e8e7fec21b2923600a
./configure --target aarch64-elf --prefix "$(pwd)/ble"
make -j `nproc`
make install

我没有检查标签，因为最后一个标签已经有几个月了，而且我不想在引入 SVE 时 grep 日志消息;-)

然后使用编译好的as并链接到 Ubuntu 16.04 上打包的 GCC：

./binutils-gdb/ble/bin/aarch64-elf-as -c -march=armv8.5-a+sve \
    -o example1.o example1.S
aarch64-linux-gnu-gcc -march=armv8.5-a -nostdlib -o example1 example1.o

在 Ubuntu 16.04 上，aarch64-linux-gnu-gcc5.4 没有-march=armv8.5-a，所以只需使用-march=armv8-a应该没问题。无论如何，Ubuntu 16.04 和 18.04 都没有-march=armv8-a+sve当它到达时，这将是最好的选择。

或者，不要通过-march=armv8.5-a+sve，您还可以将以下内容添加到开头.S源代码：

.arch armv8.5-a+sve

在Ubuntu 19.04 Binutils 2.32上，我还了解并测试了：

aarch64-linux-gnu-as -march=all

这也适用于 SVE，我想我将来会更多地使用它，因为它似乎一次性启用了所有功能，而不仅仅是 SVE！

QEMU 模拟

在 QEMU 上进行单步调试的过程解释如下：如何在 QEMU 上的 GDB 中单步执行 ARM 汇编？

首先，我将示例制作成一个最小的自包含 Linux 可执行文件：

.data
    x: .double        1.5,  2.5,  3.5,  4.5
    y: .double        5.0,  6.0,  7.0,  8.0
    y_expect: .double 8.0, 11.0, 14.0, 17.0
    a: .double        2.0
    n: .word          4

.text
.global _start
_start:
    ldr x0, =x
    ldr x1, =y
    ldr x2, =a
    ldr x3, =n
    bl daxpy

    /* exit */
    mov x0, #0
    mov x8, #93
    svc #0


/* Multiply by a scalar and add.
 *
 * Operation:
 *
 *      Y += a * X
 *
 * C signature:
 *
 *      void daxpy(double *x, double *y, double *a, int *n)
 *
 * The name "daxpy" comes from LAPACK:
 * http://www.netlib.org/lapack/explore-html/de/da4/group__double__blas__level1_ga8f99d6a644d3396aa32db472e0cfc91c.html
 *
 * Adapted from: https://alastairreid.github.io/papers/sve-ieee-micro-2017.pdf
 */
daxpy:
    ldrsw x3, [x3]
    mov x4, #0
    whilelt p0.d, x4, x3
    ld1rd z0.d, p0/z, [x2]
.loop:
    ld1d z1.d, p0/z, [x0, x4, lsl #3]
    ld1d z2.d, p0/z, [x1, x4, lsl #3]
    fmla z2.d, p0/m, z1.d, z0.d
    st1d z2.d, p0, [x1, x4, lsl #3]
    incd x4
    whilelt p0.d, x4, x3
    b.first .loop
    ret

您可以使用以下命令运行它：

qemu-aarch64 -L /usr/aarch64-linux-gnu -E LD_BIND_NOW=1 ./example1

然后它就很好地退出了。

接下来，我们可以进行调试以确认总和确实已完成：

qemu-aarch64 -g 1234 -L /usr/aarch64-linux-gnu -E LD_BIND_NOW=1 ./example1

and:

./binutils-gdb/ble/bin/aarch64-elf-gdb -ex 'file example1' \
  -ex 'target remote localhost:1234' -ex 'set sysroot /usr/aarch64-linux-gnu'

现在，紧随其后bl daxpy，然后运行：

>>> p (double[4])y_expect
$1 = {[0] = 8, [1] = 11, [2] = 14, [3] = 17}
>>> p (double[4])y
$2 = {[0] = 8, [1] = 11, [2] = 14, [3] = 17}

这证实了这笔款项实际上是按预期完成的。

观察 SVE 寄存器似乎未实现，因为我在以下位置找不到任何内容：https://github.com/qemu/qemu/tree/v3.0.0/gdb-xml但是通过复制其他FP寄存器来实现应该不会太难吧？询问于：http://lists.nongnu.org/archive/html/qemu-discuss/2018-10/msg00020.html

您目前已经可以通过执行以下操作来部分和间接地观察它：

i r d0 d1 d2

因为SVE寄存器的第一个条目zX与长者共享vXFP 注册了，但我们看不到p at all.