LDR和ADR

转自：https://www.douban.com/note/331036776/

ARM汇编有ldr指令以及ldr、adr伪指令，他门都可以将标号表达式作为操作数，下面通过分析一段代码以及对应的反汇编结果来说明它们的区别。
     ldr r0, _start
     adr r0, _start
     ldr r0, =_start
_start:
        b _start
        
编译的时候设置 RO 为 0x30000000(运行地址，runaddress)，下面是反汇编的结果：

   0x00000000: e59f0004 ldr r0, [pc, #4] ; 0xc
   0x00000004: e28f0000 add r0, pc, #0 ; 0x0
   0x00000008: e59f0000 ldr r0, [pc, #0] ; 0x10
   0x0000000c: eafffffe b 0xc
   0x00000010: 3000000c andcc r0, r0, ip

－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－

1.ldr r0, _start:

简单的说就是把 _start地址存放的值读出来。


汇编程序计算出当前位置执行到_start（这里是一个标号，相对程序的位置表达式）位置pc所要增加的数值＃4，然后由当前pc（其实是当前地址＋2个指令字节长）加上偏移量＃4，得到_start所在内存地址，然后将内存地址的值去出来放在r0中。只要此指令和标号_start的相对位置不变，R0的值相同 0xeafffffe




2.adr r0, _start

简单的说就是把 _start地址读出来，而且这个地址是相对当前pc的，所以和当前程序运行地址相关，如果在0x30000000运行，r0 = pc(0x30000004 + 0x08) + #0 = 0x3000000C;如果在0x00000000运行, r0 = pc(0x00000004 + 0x08) + #0 = 0x0000000C,所以在不同的位置运行，r0所得到的结果是不一样的，唯一确定的相对偏移量。

U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中，下面进行简要分析。
--------------------------------------------------------------------------------
relocate: /* 把U-Boot重新定位到RAM */
    adr r0, _start /* r0是代码的当前位置 */
/* adr伪指令，汇编器自动通过当前PC的值算出 如果执行到_start时PC的值，放到r0中：
当此段在flash中执行时r0 = _start = 0；当此段在RAM中执行时_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值为0x30000000，即u-boot在把代码拷贝到RAM中去执行的代码段的开始) */
    ldr r1, TEXT_BA_SE /* 测试判断是从Flash启动，还是RAM */
/* 此句执行的结果r1始终是0x30000000，因为此值是又编译器指定的(ads中设置，或-D设置编译器参数) */
    cmp r0, r1 /* 比较r0和r1，调试的时候不要执行重定位 */
--------------------------------------------------------------------------------

3. ldr, r0, =_start

这是一条伪指令，取得得是_start的绝对地址，不管在身地方运行，r0 = 0x3000000C
//
看《嵌入式linux应用开发》第六章实例中看到个句：

adrl r2,men_cfg_val

最初对adr1相当不解，后来发现，那个不是数字1，而是字母l（认真看头部，有点区别的）

 

这里记录下ADRL的用法：

功能：将相对于程序或相对于寄存器的地址载入寄存器中。 与 ADR 指令相似。ADRL 生成两个数据处理指令，因此它比 ADR 加载的地址范围要宽。

语法
ADRL{cond} Rd,label
其中：

cond：是一个可选的条件代码。Rd：是要加载的寄存器。label：是相对于程序或寄存器的表达式。
上面给出的范围是相对于位于当前指令地址后的、距离当前指令四个字节（在 Thumb 代码中）或两个字（在 ARM 代码中）远的点而言的。如果对齐为 16 字节，或与此点的相关性更高，则远程地址的范围可更大。
查看ADRL的同时，看到篇讲述ldr与adr的区别的博文，感觉写的很好，摘录下来。

http://coon.blogbus.com/logs/2738861.html

        ldr r0, _start
        adr r0, _start
        ldr r0, =_start
        nop
        mov pc, lr

_start:
        nop
        
编译的时候设置 RO 为 0x0c008000

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

0c008000 <_start-0x14>:
c008000: e59f000c ldr r0, [pc, #12] ; c008014 <_start>
c008004: e28f0008 add r0, pc, #8 ; 0x8
c008008: e59f0008 ldr r0, [pc, #8] ; c008018 <_start+0x4>
c00800c: e1a00000 nop (mov r0,r0)
c008010: e1a0f00e mov pc, lr

0c008014 <_start>:
c008014: e1a00000 nop (mov r0,r0)
c008018: 0c008014 stceq 0, cr8, [r0], -#80

分析：

ldr r0, _start

从内存地址 _start 的地方把值读入。执行这个后，r0 = 0xe1a00000

adr r0, _start

取得 _start 的地址到 r0，但是请看反编译的结果，它是与位置无关的。其实取得的时相对的位置。例如这段代码在 0x0c008000 运行，那么 adr r0, _start 得到 r0 = 0x0c008014；如果在地址 0 运行，就是 0x00000014 了。

ldr r0, =_start

这个取得标号 _start 的绝对地址。这个绝对地址是在 link 的时候确定的。看上去这只是一个指令，但是它要占用 2 个 32bit 的空间，一条是指令，另一条是 _start 的数据（因为在编译的时候不能确定 _start 的值，而且也不能用 mov 指令来给 r0 赋一个 32bit 的常量，所以需要多出一个空间存放 _start 的真正数据，在这里就是 0x0c008014）。
因此可以看出，这个是绝对的寻址，不管这段代码在什么地方运行，它的结果都是 r0 = 0x0c008014

 

 

看此文最大的收获不在于说懂了这几个命令的用法，关键却在于反汇编的运用，有反汇编看出不同用法的具体差别。

注：反汇编用arm—linux_objdump就可以实现了。