了解 Haskell callCC 示例

我无法理解之前的答案question https://stackoverflow.com/questions/20451022/how-to-interpret-callcc-in-haskell。我希望以下的解释能够澄清一些事情。下面的例子来自完整的 https://www.fpcomplete.com/user/jwiegley/understanding-continuations

import Control.Monad.Trans.Class
import Control.Monad.Trans.Cont

main = flip runContT return $ do
    lift $ putStrLn "alpha"
    (k, num) <- callCC $ \k -> let f x = k (f, x)
                               in return (f, 0)
    lift $ putStrLn "beta"
    lift $ putStrLn "gamma"
    if num < 5
        then k (num + 1) >> return ()
        else lift $ print num

输出是

alpha
beta
gamma
beta
gamma
beta
gamma
beta
gamma
beta
gamma
beta
gamma
5

我想我明白这个例子是如何工作的，但是为什么有必要有一个let表达于callCC“返回”延续，以便以后可以使用。因此，我尝试通过以下更简单的示例并对其进行修改来直接返回延续。

import Control.Monad.Trans.Class
import Control.Monad.Trans.Cont

main = flip runContT return $ do
    lift $ putStrLn "alpha"
    callCC $ \k -> do
      k ()
      lift $ putStrLn "uh oh..."
    lift $ putStrLn "beta"
    lift $ putStrLn "gamma"

这打印

alpha
beta
gamma

我将其修改为以下内容

import Control.Monad.Trans.Class
import Control.Monad.Trans.Cont

main = flip runContT return $ do
    lift $ putStrLn "alpha"
    f <- callCC $ \k -> do
      lift $ putStrLn "uh oh..."
      return k
    lift $ putStrLn "beta"
    lift $ putStrLn "gamma"

这个想法是继续将被返回为f并在我希望打印的测试示例中未使用

uh oh...
beta
gamma

但是这个例子无法编译，为什么不能这样做呢？

Edit：考虑方案中的类似示例。据我所知Scheme不会有问题，这是正确的吗？但是为什么呢？

正如其他人所写的那样，由于无限类型，最后一个示例不会进行类型检查。

@augustss 提出了另一种解决这个问题的方法：

您还可以创建一个新类型，将无限（等）递归类型包装为（等）递归新类型。 – 2013 年 12 月 12 日 8 月 12:50

这是我的看法：

import Control.Monad.Trans.Cont
import Control.Monad.Trans.Class

data Mu t = In { out :: t (Mu t) }

newtype C' b a = C' { unC' :: a -> b }
type C b = Mu (C' b)

unfold = unC' . out
fold = In . C'

setjmp = callCC $ (\c -> return $ fold c)
jump l = unfold l l

test :: ContT () IO ()
test = do
    lift $ putStrLn "Start"
    l <- setjmp
    lift $ putStrLn "x"
    jump l

main = runContT test return

我想这就是@augustss 的想法。