Antlr 外部输入

我有一个语法文件 BoardFile.g4，其中包含（仅相关部分）：

grammar Board;

//Tokens
GADGET : 'squareBumper' | 'circleBumper' | 'triangleBumper' | 'leftFlipper' | 'rightFlipper' | 'absorber' | 'portal' ;
NAME : [A-Za-z_][A-Za-z_0-9]* ;
INT : [0-9]+ ;
FLOAT : '-'?[0-9]+('.'[0-9]+)? ;
COMMENT : '#' ~( '\r' | '\n' )*;
WHITESPACE : [ \t\r\n]+ -> skip ;
KEY : [a-z] | [0-9] | 'shift' | 'ctrl' | 'alt' | 'meta' | 'space' | 'left' | 'right' | 'up' | 'down' | 'minus' | 'equals' | 'backspace' | 'openbracket' | 'closebracket' | 'backslash' | 'semicolon' | 'quote' | 'enter' | 'comma' | 'period' | 'slash' ;
KEYPRESS : 'keyup' | 'keydown' ;

//Rules
file : define+ EOF ;
define : board | ball | gadget | fire | COMMENT | key ;
board : 'board' 'name' '=' name ('gravity' '=' gravity)? ('friction1' '=' friction1)? ('friction2' '=' friction2)? ;
ball : 'ball' 'name' '=' name 'x' '=' xfloat 'y' '=' yfloat 'xVelocity' '=' xvel 'yVelocity' '=' yvel ;
gadget : gadgettype 'name' '=' name 'x' '=' xint 'y' '=' yint ('width' '=' width 'height' '=' height)? ('orientation' '=' orientation)? ('otherBoard' '=' name 'otherPortal' '=' name)? ;
fire : 'fire' 'trigger' '=' trigger 'action' '=' action ;
key : keytype 'key' '=' KEY 'action' '=' name ;

name : NAME ;
gadgettype : GADGET ;
keytype : KEYPRESS ;
gravity : FLOAT ;
friction1 : FLOAT ;
friction2 : FLOAT ;
trigger : NAME ;
action : NAME ;
yfloat : FLOAT ;
xfloat : FLOAT ;
yint : INT ;
xint : INT ;
xvel : FLOAT ;
yvel : FLOAT ;
orientation : INT ;
width : INT ;
height : INT ;

这会生成词法分析器和解析器。但是，当我对以下文件使用它时，会出现以下错误：

line 12:0 extraneous input 'keyup' expecting {<EOF>, KEYPRESS}

要解析的文件：

板名称=按键板重力=5.0 摩擦力1=0.0 摩擦力2=0.0

# define a ball
ball name=Ball x=0.5 y=0.5 xVelocity=2.5 yVelocity=2.5

# add some flippers
leftFlipper name=FlipL1 x=16 y=2 orientation=0
leftFlipper name=FlipL2 x=16 y=9 orientation=0

# add keys. lots of keys.
keyup key=space action=apple
keydown key=a action=ball
keyup key=backslash action=cat
keydown key=period action=dog

我在 SO 中遇到了有关此错误的其他问题，但没有一个对我有帮助。我不知道出了什么问题。为什么我会收到此错误？

字符串"keyup"正在被标记为NAME令牌：这就是问题所在。

您必须意识到词法分析器独立于解析器运行。如果解析器试图匹配KEYPRESStoken，词法分析器不会“监听”它，而只是按照规则构造一个 token：

1. 匹配消耗最多字符的规则
2. 如果有多个规则匹配相同数量的字符，则选择第一个定义的规则

考虑到这些规则以及规则的顺序：

NAME : [A-Za-z_][A-Za-z_0-9]* ;

INT : [0-9]+ ;

KEY : [a-z] | [0-9] | 'shift' | 'ctrl' | 'alt' | 'meta' | 'space' | 'left' | 'right' | 'up' | 'down' | 'minus' | 'equals' | 'backspace' | 'openbracket' | 'closebracket' | 'backslash' | 'semicolon' | 'quote' | 'enter' | 'comma' | 'period' | 'slash' ;

KEYPRESS : 'keyup' | 'keydown' ;

a NAME令牌将在大多数之前创建KEY替代方案，以及所有KEYPRESS将创建替代方案。

并且自从INT匹配一位或多位数字并在之前定义KEY它也有一个单位数字的替代，很明显，词法分析器永远不会产生一个KEY or KEYPRESS token.

如果您移动NAME and INT规则低于KEY and KEYPRESS规则，那么大多数令牌将按照您的预期构建，这是我的猜测。

EDIT

一个可能的解决方案如下：

KEY : [a-z] | 'shift' | 'ctrl' | 'alt' | 'meta' | 'space' | 'left' | 'right' | 'up' | 'down' | 'minus' | 'equals' | 'backspace' | 'openbracket' | 'closebracket' | 'backslash' | 'semicolon' | 'quote' | 'enter' | 'comma' | 'period' | 'slash' ;

KEYPRESS : 'keyup' | 'keydown' ;

NAME : [A-Za-z_][A-Za-z_0-9]* ;

SINGLE_DIGIT : [0-9] ;

INT : [0-9]+ ;

IE。我删除了[0-9]替代方案KEY并介绍了一个SINGLE_DIGIT规则（放置在before the INT rule!).

现在创建一些额外的解析器规则：

integer : INT | SINGLE_DIGIT ;

key : KEY | SINGLE_DIGIT ;

并更改所有出现的INT内部解析器规则integer（不要称你的规则为int：这是一个保留字）并更改所有KEY to key.

你可能还想做类似的事情NAME和[a-z]替代方案KEY（即单个小写字符现在永远不会被标记为NAME，始终作为KEY).