我刚刚开始研究一下 IL,我很好奇我从编译器输出中删除多余代码的尝试(如下所示)是否会产生任何意想不到的副作用。
关于结果的几个问题:
- 原文中nop操作的目的是什么?
- 原始方法末尾的 br.s 的目的是什么?
- 重写的版本有什么不合适的地方吗?
原始C#代码:
class Program {
public static int Main() {
return Add(1, 2);
}
public static int Add(int a, int b) {
return a + b;
}
}
编译为csc.exe
并将其拆解为ildasm.exe
(原来的):
.method public hidebysig static int32 Main() cil managed
{
.entrypoint
.maxstack 2
.locals init (int32 V_0)
IL_0000: nop
IL_0001: ldc.i4.1
IL_0002: ldc.i4.2
IL_0003: call int32 Program::Add(int32, int32)
IL_0008: stloc.0
IL_0009: br.s IL_000b
IL_000b: ldloc.0
IL_000c: ret
}
.method public hidebysig static int32 Add(int32 a,
int32 b) cil managed
{
.maxstack 2
.locals init (int32 V_0)
IL_0000: nop
IL_0001: ldarg.0
IL_0002: ldarg.1
IL_0003: add
IL_0004: stloc.0
IL_0005: br.s IL_0007
IL_0007: ldloc.0
IL_0008: ret
}
重写(产生相同的输出):
.method public hidebysig static int32 Main() cil managed
{
.entrypoint
.maxstack 2
ldc.i4.1
ldc.i4.2
call int32 Program::Add(int32, int32)
ret
}
.method public hidebysig static int32 Add(int32 a, int32 b) cil managed
{
.maxstack 2
ldarg.0
ldarg.1
add
ret
}
您看到的所有“多余”代码都是特定于调试版本的(通常会针对发布版本进行优化),并允许您执行在发布版本中通常无法执行的操作。
调试构建代码允许在调试会话期间设置断点和更改/检查堆栈值方面具有最大的独立性。此外,IL 代码应尽可能模仿更高级别的代码,以便每个“原因”和“结果”都可以映射到更高级别的代码行。
现在具体回答您的问题:
原文中nop操作的目的是什么?
NOP 允许您在未“执行”的地方设置断点。例如方法、循环或 if 语句的左大括号。在这些不可执行的指令中,在左大括号处中断允许您在块开始之前修改/检查堆栈(尽管不可否认,您可以通过在块的第一行执行处中断而不是左大括号来轻松实现这一点,但它仍然允许您独立地在左大括号处断开)
原始方法末尾的 br.s 的目的是什么?
查看原始代码,您可能会发现“跳”到下一行而不是让代码自然“落”到下一行是荒谬的。但读作:
“在调试版本中,每当一个方法需要返回时,跳转到该方法的末尾,从堆栈中读取返回值,然后返回该值”
那么它对调试有什么好处呢?
如果代码中有多个 return 语句,则在从堆栈读取返回值之前,它们都会“跳转”到代码末尾。这允许您在一个地方(方法的右大括号)放置断点并在返回值实际返回到调用方法之前修改它。很有帮助不是吗?
重写的版本有什么不合适的地方吗?
您的代码中没有任何不正确的地方。事实上,如果您在发布模式下构建原始版本并检查生成的 CIL,您会发现它与您的大部分相同。
本文内容由网友自发贡献,版权归原作者所有,本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容,请联系:hwhale#tublm.com(使用前将#替换为@)