制作嵌套在其他显示对象中的显示对象的视觉克隆，并将克隆添加到相同位置、旋转等的舞台层中

我希望能够获取嵌套在其他对象中的 DisplayObject 的副本转变的DisplayObjects（旋转、缩放、拉伸的对象），并能够将其标记回相同的视觉位置，但在舞台层上。本质上，能够创建嵌套 DisplayObject 的克隆，但能够将克隆添加到舞台层，同时使其与原始对象完美对齐（视觉上）（相同的位置、比例、旋转）

我一直在从事以下工作：

// draw the pixels of a displayobject into a new bitmap object
var bitmapData:BitmapData = new BitmapData(nestedSprite.width, nestedSprite.height, true, 0xFFFFFF);
var bitmap:Bitmap = new Bitmap(bitmapData);
bitmapData.draw(nestedSprite);

// put the copy on the top most layer
stage.addChild(bitmap);

// position the copy to perfectly overlay the original, but on the top stage layer
var point:Point = nestedSprite.localToGlobal(new Point(0, 0));
bitmap.x = point.x;
bitmap.y = point.y;

但这仅适用于其父对象未转换的显示对象；对于完全位于(0,0)起源。对于居中对齐的对象或缩放的父对象等，它会崩溃。

我知道我可以添加一个矩阵参数.draw()方法，以及剪切矩形，然后缩放我的位图，或者将一个对象的变换设置为另一个对象，或者使用.transform.concatenatedMatrix，或使用nestedObject.getBounds(null), or nestedSprite.getBounds(nestedSprite)等等，但不幸的是我陷入了这样做试错编程就这一点而言，并且存在许多变量，这绝不是解决编程问题的好方法。

我相信这个函数应该可以工作，唯一的额外步骤是偏移连接矩阵，以便目标将在位图上的左上角 (0, 0) 处绘制，即使它的原点在其他地方。希望其余的内容是不言自明的，但如果有任何不合理的地方，我可以添加更多评论。

function createBitmapClone(target:DisplayObject):Bitmap {
    var targetTransform:Matrix = target.transform.concatenatedMatrix;
    var targetGlobalBounds:Rectangle = target.getBounds(target.stage);
    var targetGlobalPos:Point = target.localToGlobal(new Point());

    // Calculate difference between target origin and top left.
    var targetOriginOffset:Point = new Point(targetGlobalPos.x - targetGlobalBounds.left, targetGlobalPos.y - targetGlobalBounds.top);

    // Move transform matrix so that top left of target will be at (0, 0).
    targetTransform.tx = targetOriginOffset.x;
    targetTransform.ty = targetOriginOffset.y;

    var cloneData:BitmapData = new BitmapData(targetGlobalBounds.width, targetGlobalBounds.height, true, 0x00000000);
    cloneData.draw(target, targetTransform);
    var clone:Bitmap = new Bitmap(cloneData);

    // Move clone to target's global position, minus the origin offset.
    clone.x = targetGlobalPos.x - targetOriginOffset.x;
    clone.y = targetGlobalPos.y - targetOriginOffset.y;

    return clone;
}

不幸的是，如果 DisplayObjects 上有任何过滤器，pixelBounds 似乎会返回 (0, 0) 的原点，这显然会破坏事物。

Edit:已更换target.transform.pixelBounds with target.getBounds(target.stage)作为一个轻微的改进。如果有过滤器，这可以保持位置正确，但是父 DisplayObject 上的过滤器仍然不会被包含在内, and 目标上的滤镜可以与位图的边缘重叠。我不确定是否有一种简单的方法可以解决这个问题。

Update:Jimmi Heiserman 发现如果缩放 swf，此功能就会被破坏。没有stage.scaleMode = StageScaleMode.NO_SCALE;不过，stageWidth and stageHeight参数似乎保持不变，所以我发现的唯一（相当hacky）的解决方法是添加一个“未缩放的”测试精灵并使用its concatenatedMatrix调整克隆的位置和比例：

function createScaledBitmapClone(target:DisplayObject):Bitmap {
    var targetTransform:Matrix = target.transform.concatenatedMatrix;
    var targetGlobalBounds:Rectangle = target.getBounds(target.stage);
    var targetGlobalPos:Point = target.localToGlobal(new Point());

    // Calculate difference between target origin and top left.
    var targetOriginOffset:Point = new Point(targetGlobalPos.x - targetGlobalBounds.left, targetGlobalPos.y - targetGlobalBounds.top);

    // Create a test Sprite to check if the stage is scaled.
    var testSprite:Sprite = new Sprite();
    target.stage.addChild(testSprite);
    var testMatrix:Matrix = testSprite.transform.concatenatedMatrix;
    target.stage.removeChild(testSprite);

    // Move transform matrix so that top left of target will be at (0, 0).
    targetTransform.tx = targetOriginOffset.x * testMatrix.a;
    targetTransform.ty = targetOriginOffset.y * testMatrix.d;

    var cloneData:BitmapData = new BitmapData(targetGlobalBounds.width * testMatrix.a, targetGlobalBounds.height * testMatrix.d, true, 0x00000000);
    cloneData.draw(target, targetTransform);
    var clone:Bitmap = new Bitmap(cloneData);

    // Move clone to target's global position, minus the origin offset, and cancel out stage scaling.
    clone.x = targetGlobalPos.x - targetOriginOffset.x;
    clone.y = targetGlobalPos.y - targetOriginOffset.y;
    clone.scaleX = 1 / testMatrix.a;
    clone.scaleY = 1 / testMatrix.d;

    return clone;
}